《x86汇编语言从实模式到保护模式》学习实验笔记【07】

我不是女神ヾ 2023-03-01 08:40 30阅读 0赞

### 目录 ###

*  文本模式下的光标控制
 *   *  索引寄存器和数据寄存器
     *  读取光标位置
     *  设置光标位置
 *  为字符串打印函数增加回车和换行功能

# 文本模式下的光标控制 #

光标是当显卡工作在文本模式下时，在屏幕上有规律地闪动的一条小横线，用于指示下一个要显示的字符位置，如下动态图所示：  
![在这里插入图片描述][20200722235600941.gif]  
光标在屏幕上的位置保存在显卡内部的两个光标寄存器中，每个寄存器有8位，合起来形成一个16位的数值。有效值域为\[0, 1999\]，对应屏幕上可以显示的2000个字符（25行 x 80列）。当光标在屏幕右下角的时候，该值为25x80-1=1999。光标寄存器是可读可写的。通过写入，我们可以设置光标的显示位置。

## 索引寄存器和数据寄存器 ##

显卡中用于控制光标显示的是一对寄存器：索引寄存器（0x3D4）和数据寄存器（0x3D5）。由于显卡的操作非常复杂，为了不过多地占用I/O地址空间，很多寄存器只能通过索引寄存器间接访问。

索引寄存器的端口号是0x3D4，可以向他写入一个值，用来指定内部的某个寄存器。比如，两个8位的光标寄存器，其索引值分别是0xE和0xF，分别用于提供光标位置的高8位和低8位。

## 读取光标位置 ##

下面我们使用如下代码读取光标的当前位置，并在该位置开始输出一串字符Cursor is Here!。

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    
    SECTION bkf align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov sp, ax
    
    	mov ax, 0xb800
    	mov es, ax
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov di, ax
    
    	mov ax, cursorMsg
    	call print_string
    
    jmp $
    
    
    print_string:
    	push es
    	push ax
    	push si
    	mov si, ax
    
    	;set video buffer addr
    	mov ax,0xb800
       	mov es, ax
    	
    @1: mov al, [si]
    	cmp al, 0
    	jne @2
    
    	pop si
    	pop ax
    	pop es
    	
    	ret	
    @2:
    	mov byte [es:di], al	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	inc si
    	jmp @1
    
    
    cursorMsg: db 'Cursor is Here!', 0
    
    times 510-($-$$) db 0
    db 0x55, 0xAA

编译上述代码，并使用FixVhdWr工具将编译后的bin文件写入.vhd虚拟硬盘，如下所示：

> $ nasm -f bin ShowCursor.s -o ShowCursor.bin  
> $ FixVhdWr -r ShowCursor.bin -w ~/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd -a 0

程序运行结果如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70]

## 设置光标位置 ##

为方便后续使用，我们将读取光标当前位置和设置光标位置封装成两个函数getCursorPosition和setCursorPosition。getCursorPosition函数将返回值保存在ax寄存器中，setCursorPosition函数通过寄存器ax传入光标位置。

同时为了处理方便，我们引入字符打印函数printCharacter来辅助打印字符串。这样我们可以在打印完一个字符之后就立即更新光标的位置，代码如下所示：

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    
    SECTION bkf align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov sp, ax
    
    	mov ax, cursorMsg
    	call printString
    	
    	mov ax, cursorMsg2
    	call printString
    
    	jmp $
    
    
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    printString:
    	push ax
    	push si
    	
    	;save string start address to si
    	mov si, ax
    	
    @1: mov al, [si]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc si
    	jmp @1
    	
    @2:
    	pop si
    	pop ax
    	
    	ret	
    
    printCharacter:
    	push es
    	push ax
    	push di
    	push bx
    	
    	mov bx, ax
    	
    	;set video buffer addr
    	mov ax,0xb800
       	mov es, ax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	
    	;write new cursor pos to video card
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop bx
    	pop di
    	pop ax
    	pop es
    	ret
    
    cursorMsg: db 'Cursor is Here!', 0
    cursorMsg2: db 'Another line goes here.', 0
    times 510 - ($-$$) db 0
    db 0x55, 0xAA

运行结果如下所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 1]

# 为字符串打印函数增加回车和换行功能 #

回车和换行这两个概念起源于古老的打字机。在计算机还没有出现之前，打字使用的是一种叫做电传打字机（Teletype Model 33）的设备。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 2]  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 3]

该设备每秒钟可以打10个字符。当它打完一行需要换行时，打印头机械移动要用去0.2秒，对应的时间正好可以打印两个字符。如果在这0.2秒的时间里又有新的字符传过来，那么这个字符就丢失了。

当输满一行后，使用者就要把“字车”推到最左边，也就是行首，即“字车”归位，这就相当于“回车”（Carriage Return, CR）操作；同时需要将滚筒上卷一行，这样就可以开始输入下一行了，这相当于“换行”（Line Feed, LF）。

在ASCII码中，回车CR对应的值是0xD，换行LF对应的值是0xA。

为了对这两个ASCII码提供支持，需要我们在软件层面编写代码，以实现回车和换行的效果。硬件本身不直接对其提供支持。

当碰到回车CR符号时，因为每行是80个字符，所所以我们获取光标当前位置，并对其值进行模80取整，然后将光标值写回。  
当碰到换行LF符号时，需要分情况进行处理，如果当前光标所在行不是屏幕的最后一行，那么我们直接将光标当前位置加上80，并写回即可；如果当前行是最后一行，我们首先需要将屏幕向下滚动一行，即将第二行到最后一行的内容依次往前复制一行，之后保持光标位置不变即可。

编写的代码如下所示：

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    
    SECTION bkf align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov sp, ax
    
    	mov ax, cursorMsg
    	call printString
    	
    	mov ax, cursorMsg2
    	call printString
    	
    	mov ax, cursorMsg3
    	call printString
    
    	mov ax, cursorMsg4
    	call printString
    	
    	mov ax, cursorMsg5
    	call printString
    	
    	jmp $
    
    
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    printString:
    	push ax
    	push si
    	
    	;save string start address to si
    	mov si, ax
    	
    @1: mov al, [si]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc si
    	jmp @1
    	
    @2:
    	pop si
    	pop ax
    	
    	ret	
    
    printCharacter:
    	push es
    	push ds
    	push ax
    	push di
    	push bx
    	push cx
    	
    	mov bx, ax
    	
    	;set video buffer addr
    	mov ax,0xb800
       	mov es, ax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;test if the screen is full, if screen is full, just return
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push di
    	mov ax,0xb800
    	mov ds,ax
    	mov es,ax
    	cld
    	mov cx, 1920
    	mov di, 0
    	mov si, 160
    	rep movsw
    	;clear screen last line
    	mov bx, 3840                     
    	mov cx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop di
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop cx
    	pop bx
    	pop di
    	pop ax
    	pop ds
    	pop es
    	ret
    
    cursorMsg: db 'Cursor is Here!', 0
    cursorMsg2: db 'Still the same line goes here.', 0
    cursorMsg3: db 0xd, 'Start from Head.', 0
    cursorMsg4: db 0xd, 0xa,0xa,0xa,0xa,0xa,'After change line.', 0xa, 'Another line.', 0
    cursorMsg5: db 0xa, 'the 8th line.', 0xa, '9th', 0xa, '10th', 0xa, 0xa, 0xa, 0xa,0xa,0xa
    db 0xa, 0xa, 0xa, 0xa, 0xa, 0xa, 0xa, 0xa, 0xa, 'This is the last line.', 0
    
    times 510 - ($-$$) db 0
    db 0x55, 0xAA

测试效果如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 4]

[20200722235600941.gif]: /images/20230209/ee1d7035e9564df8b335aeb3464f6cd6.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70]: /images/20230209/79e58b5e764643e4a8bbdd3843a985c1.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 1]: /images/20230209/41023a5aa2ec426f94ddf49dc03c1204.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 2]: /images/20230209/cbb245b500b84114963f77ad66830ba6.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 3]: /images/20230209/b1eeb28cdb6e4e05971cd47466907b38.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 4]: /images/20230209/1a63a73987ce42d497048a3c1fdc926a.png