《x86汇编语言从实模式到保护模式》学习实验笔记【10】进入保护模式

àì夳堔傛蜴生んèń 2022-12-06 12:52 416阅读 0赞

### 目录 ###

*  全局描述符表
 *   *  段描述符
 *  安装全局段描述符并加载GDTR
 *   *  代码段
     *  数据段
     *  堆栈段
     *  显存段
     *  加载GDTR
 *  打开地址线A20
 *  关中断
 *  使能保护模式允许位
 *  清空流水线并串行化处理器
 *  完整代码如下所示：

# 全局描述符表 #

当进入保护模式之后，和一个段有关的信息需要使用8个字节来进行描述。这8个字节就被称为段描述符（Segment Descriptor）。所有的描述符在内存中连续存放，从而构成描述符表。

最主要的描述符是全局描述符表（Global Descriptor Table，GDT）。在进入保护模式之前，必须先定义全局描述符表。

全局描述符的起始地址被存储在全局描述符表寄存器GDTR中。该寄存器分为两个部分，分别是32位的线性地址和16位的边界值。  
![在这里插入图片描述][20200913154615105.jpg_pic_center]  
其中，全局描述符表边界即为全局描述符表界限值，大小是表内最后1字节的偏移量。第1个字节的偏移量是0，最后1字节的偏移量是表大小减1。

理论上，全局描述符表可以位于内存中的任意地址处，不必对齐。但是在进入保护模式之前我们就要设置好GDT，所以最开始GDT必须位于前1MB内存中。为简单起见，我们将GDT放在紧挨着主引导程序之后。因为主引导程序大小为512字节，起始物理地址是0x7C00，所以GDT的地址为0x7C00 + 512，即物理地址0x00007E00处，如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]

## 段描述符 ##

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]  
由上图可知，每一个段描述符大小是8个字节，64位。上图中下面是低4字节的内容，上面是高4字节的内容。  
描述符中指定了32位的段起始线性地址，以及20位的段边界。如果未开启分页功能，那么线性地址就是物理地址。

对于20位的段界限来说，如果是向上扩展的代码段或数据段，它决定了偏移量的最大值；如果是向下扩展的堆栈段，段界限决定了偏移量的最小值。

G代表段的粒度。若G=0，则表示段界限以字节为单位，此时20位的段界限可以表示从1字节到1MB的范围；若G=1，则表示段界限以4KB为单位，此时20位的段界限可以表示从4KB到4GB的范围。

S位用于表示描述符的类型。当S=0时，表示这是一个系统段；当S=1时，表示这是一个代码段或数据段。

DPL位表示描述符的特权级（Descriptor Privilege Level，DPL）。这两位用于指定对应段的特权级，即0、1、2、3。其中0级为最高特权级别，3级为最低特权级别。刚进入保护模式时执行的代码具有最高的特权级别。通常0级用于操作系统的代码，3级用于普通用户程序的代码。有些CPU指令只能由0特权级的程序来执行。

P表示段存在位（Segment Present）。P位用于指示描述符所对应的段是否存在。当P=0时，表示段位于硬盘中；当P=1时，表示段位于内存中。

D/B位表示默认操作设大小。当为0时表示是16位的，当为1时表示是32位的。

L位是64位代码段标志，为1表示是64位。

TYPE字段共有4位，用于指示描述符的子类型，具体含义如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]

由上图可知，当X位为1时，表示代码段；当X位为0时表示数据段。  
对于数据段，E位指示段的扩展方向。E=0表示向上扩展，即向高地址方向扩展；E=1时表示向下扩展，即向低地址方向扩展。W位表示是否可写。若W=0表示段是不允许被写入的，否则会触发CPU异常中断，若W=1则表示段是可以正常读写的。

对于代码段，C位表示该段是否是特权级依从。C=0表示非依从段，即该代码段只能从与它特权级相同的代码段调用，或者通过门调用；C=1则表示允许从低特权级的程序转移到该段执行。R位表示该代码段是否可读。

A位表示该段最近是否被访问过，每当该段被访问时，CPU会自动将该位置置1。

AVL位是用户自定义位，通常由操作系统来使用。

为方便起见，我写了一个段描述符编辑器，为后续解析段描述符和快速构造段描述符提供一些帮助，如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]  
该工具的源代码工程下载链接如下所示：  
https://download.csdn.net/download/BakerTheGreat/12839673

# 安装全局段描述符并加载GDTR #

为简单起见，本示例程序我们只使用主引导程序。在主引导程序中，我们使用4个段：

*  代码段
 *  数据段
 *  堆栈段
 *  显示内存段

同时，由于x86的CPU规定GDT中的第一个段描述符必须是空描述符，所以共有5个段。

## 代码段 ##

由于我们只使用了主引导程序，所以显然代码段的长度是512个字节。所以段的粒度位G=0，即以字节为单位。段界限是0x1FF。描述符类型S=1，表示是代码段或数据段。32位，所以DB=1，L=0。该段目前位于内存中，所以P=1。段的特权等级是0，代码段只可执行，不能读写。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]  
需要注意的一点是，x86的CPU都是小端序的，即低字节的数据在低地址，高字节的数据在高地址。  
所以，该描述符的值为：

*  低4字节： 0x7C0001FF
 *  高4字节： 0x00409800

## 数据段 ##

为方便起见，我们把整个4GB内存都设置为可读写的数据段。为此，粒度位G=1，段界限为0xFFFFF，所以段长度为1M x 4K = 4GB。  
段的线性基地址是0x00000000，属于存储器段S=1，DB=1，L=0，P=1，段特权级DPL=0  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]

所以，该描述符的值为：

*  低4字节： 0x0000FFFF
 *  高4字节：0x00CF9200

## 堆栈段 ##

按照之前的介绍，我们将栈区设置为0x7C00~0x7A00，共512字节。  
我们将esp的值初始化为0x7C00，将段的线性基地址设置为0x00000000，粒度为字节，特权级为0，TYPE=0b0110，即可读可写的、向下扩展的数据段。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]

所以，该描述符的值为：

*  低4字节： 0x00007a00
 *  高4字节：0x00409600

## 显存段 ##

和数据段很类似，不过段长度为64KB，段线性基地址是0x000B8000。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]  
所以，该描述符的值为：

*  低4字节： 0x8000FFFF
 *  高4字节：0x0040920B

## 加载GDTR ##

根据之前的描述，我们构造的GDT的线性物理地址是0x00007E00。CPU为了跟踪全局描述符表，处理器内部有一个48位的寄存器，称为全局描述符表寄存器（GDTR）。该寄存器分为两部分，即16位的边界和32位的线性物理地址。

全局描述符表的界限值是表内最后1字节的偏移量，首字节的偏移量是0，最后一个字节的偏移量是表的大小减1。因为GDT的界限值是16位的，所以表的最大值是216=64KB，又由于一个段描述符占8个字节，所以GDT中最多有8K（8192）个描述符。

我们首先定义一个6字节的内存区域，用于存储GDT的大小和线性物理基地址，如下所示：

gdt_size         dw 0
    gdt_base         dd 0x00007E00     ;GDT的物理入口地址

其中GDT的大小我们使用程序动态生成。之后，我们使用如下指令来加载GDTR

lgdt [cs: gdt_size+0x7c00]

之所以加上0x7c00，是因为主引导程序被加载至0x7C00处。

# 打开地址线A20 #

我们在上一篇博客中已经介绍了这一方面的内容，在此只列出代码：

in al,0x92          ;南桥芯片内的端口 
    or al,0000_0010B
    out 0x92,al         ;打开A20

# 关中断 #

当CPU进入保护模式之后，原有的中断向量表不再适用。因此在重新设置保护模式下的中断环境之前，必须关中断。关中断使用如下命令：

cli

# 使能保护模式允许位 #

CR0是CPU内部的控制寄存器，它是一个32位的寄存器，包含了一系列用于控制处理器操作模式和运行状态的标志位。其中第0位是保护模式允许位PE（Protection Enable），当置1时处理器进入保护模式。

# 清空流水线并串行化处理器 #

jmp dword 0x0008:flush      ;16位的描述符选择子：32位偏移
    							;清流水线并串行化处理器 
    [bits 32] 
    flush:

# 完整代码如下所示： #

;设置实模式下的堆栈
    ;栈基址设为0,栈指针设置为0x7C00
    xor ax, ax
    mov ss, ax
    mov sp, 0x7C00
    
    ;由于存储的是GDT的线性地址
    ;需要转换为实模式下的逻辑地址
    mov dx, [cs:gdt_size + 2 + 2 + 0x7C00]
    mov ax, [cs:gdt_size + 2 + 0x7C00]
    mov bx, 16
    div bx
    mov ds, ax
    mov bx, dx
    
    ;设置0号段描述符
    mov dword [bx], 0
    mov dword [bx + 4], 0
    
    ;设置代码段描述符
    mov dword [bx + 8], 0x7C0001FF
    mov dword [bx + 0xC], 0x00409800
    
    ;设置数据段
    mov dword [bx + 0x10], 0x0000FFFF 
    mov dword [bx + 0x14], 0x00CF9200 
    
    ;设置堆栈段
    mov dword [bx + 0x18], 0x00007A00
    mov dword [bx + 0x1C], 0x00409600
    
    ;设置显存段
    mov dword [bx + 0x20], 0x8000FFFF
    mov dword [bx + 0x24], 0x0040920B
    
    ;初始化GDT大小
    mov word [cs:gdt_size+0x7C00], 39
    
    ;加载GDT
    lgdt [cs:gdt_size+0x7C00]
    
    ;关中断
    cli
    
    ;打开A20
    in al, 0x92
    or al, 0x2
    out 0x92, al
    
    ;使能PE位
    mov eax, cr0
    or eax, 1
    mov cr0, eax
    
    ;现在CPU已经处于保护模式
    
    ;清空流水线，串行化处理器
    jmp dword 0x8:flush
    
    [bits 32]
    flush:
    mov cx, 0x10
    mov ds, cx
    mov cx, 0x20
    mov es, cx
    
    ;在屏幕上显示"Now in protection mode." 
    mov byte [es:0x00],'N' 
    mov byte [es:0x02],'o'  
    mov byte [es:0x04],'w'  
    mov byte [es:0x06],' '  
    mov byte [es:0x08],'i'  
    mov byte [es:0x0A],'n'  
    mov byte [es:0x0C],' '  
    mov byte [es:0x0E],'p'  
    mov byte [es:0x10],'r'  
    mov byte [es:0x12],'o'  
    mov byte [es:0x14],'t'  
    mov byte [es:0x16],'e'  
    mov byte [es:0x18],'c'  
    mov byte [es:0x1A],'t'  
    mov byte [es:0x1C],'i'  
    mov byte [es:0x1E],'o'  
    mov byte [es:0x20],'n'  
    mov byte [es:0x22],' '  
    mov byte [es:0x24],'m'  
    mov byte [es:0x26],'o'  
    mov byte [es:0x28],'d'  
    mov byte [es:0x2A],'e'  
    mov byte [es:0x2C],'.'   
    hlt
             
    
    gdt_size: dw 0x0
    gdt_base: dd 0x7E00
    
    
    times 510-($-$$) db 0
    db 0x55,0xaa

将上述汇编源程序编译并烧写到虚拟硬盘中，如下所示：

> $ nasm -f bin PMLoader.s -o PMLoader.bin  
> $ FixVhdWr -r PMLoader.bin -w ~/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd -a 0

最终效果图如下所示：  
![在这里插入图片描述][20200915232716833.gif_pic_center]

[20200913154615105.jpg_pic_center]: /images/20221123/686b09af9eae43debc11666c0481282f.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]: /images/20221123/cf954fdb05ee43f5a2887065ee030369.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]: /images/20221123/9f98e62ab22241bbb5d0543c67bd59a5.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]: /images/20221123/d423d83bbac2475cb6964da1c5d867b9.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]: /images/20221123/8f062dc323f94a3abb12a6e1ba0fd8aa.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 4]: /images/20221123/3c4ddc096ca2474f92a2e5524b5f9a4e.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 5]: /images/20221123/507235eeebf64454b5ce61884a59f6c0.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 6]: /images/20221123/c3b802eb6b0b4b8c85ff143b2b59ab5b.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 7]: /images/20221123/bfdfe561790c40b8a5458c7e77ae7fd9.png
[20200915232716833.gif_pic_center]: /images/20221123/f047a6d8092746ac84d088786113319e.png