测试Oracle存储过程中遍历游标的三种方式(For,Fetch,While)及区别

今天药忘吃喽~ 2023-10-08 09:27 35阅读 0赞

--测试库为oracle自带示例HR数据库
    create or replace procedure MyProc is
          Cursor CUR_TEST IS --声明显式游标
           SELECT FIRST_NAME,JOB_ID,SALARY  FROM EMPLOYEES WHERE SALARY>4000 ORDER BY SALARY DESC; 
          CUR CUR_TEST%ROWTYPE; --定义游标变量，该变量的类型为基于游标CUR_TEST的记录
         
        BEGIN 
          --For 循环
          FOR CUR IN CUR_TEST LOOP
              --循环体
            DBMS_OUTPUT.PUT_LINE('JOB_ID：'||CUR.JOB_ID ||'  FIRST_NAME：'|| CUR.FIRST_NAME||'  SALARY：'|| CUR.SALARY);
          END LOOP;
          
          --Fetch 循环
          OPEN CUR_TEST;--必须要明确的打开和关闭游标
          LOOP 
            FETCH CUR_TEST INTO CUR;
            EXIT WHEN CUR_TEST%NOTFOUND;
            --循环体
             DBMS_OUTPUT.PUT_LINE('JOB_ID：'||CUR.JOB_ID ||'  FIRST_NAME：'|| CUR.FIRST_NAME||'  SALARY：'|| CUR.SALARY);
          END LOOP;
          CLOSE CUR_TEST;
     
          --While 循环
          OPEN CUR_TEST;--必须要明确的打开和关闭游标
            FETCH CUR_TEST INTO CUR;
            WHILE CUR_TEST%FOUND LOOP  
              --循环体
              DBMS_OUTPUT.PUT_LINE('JOB_ID：'||CUR.JOB_ID ||'  FIRST_NAME：'|| CUR.FIRST_NAME||'  SALARY：'|| CUR.SALARY);
              
              FETCH CUR_TEST INTO CUR;
            END LOOP;
          CLOSE CUR_TEST;
     
     END MyProc;

调用方法：

begin
      MyProc();
    end;

DBMS输出结果，工资大于4000的人员降序显示如下：

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3doNDQ1MzA2_size_16_color_FFFFFF_t_70][]

从上面代码中可以看出：

1、使用for循环不需要关注游标是否打开或关闭。

2、for循环会自动将数据fetch到记录型变量

3、for循环不需要关注何时要退出，也就是不需要写退出满足条件。遍历完成就会退出。

综合：for循环是用来循环游标的最好方法。高效，简洁，安全。

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3doNDQ1MzA2_size_16_color_FFFFFF_t_70]: https://img-blog.csdnimg.cn/20191109033602319.png?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3doNDQ1MzA2,size_16,color_FFFFFF,t_70