java字节码层面逐行分析，解释i++和++i的区别

古城微笑少年丶 2023-09-29 15:48 9阅读 0赞

### 源码 ###

public  void testAdd(){
    
            int a = 10;
            a =  a++;
            System.out.println(a);
    
        }
    
    
        public void testAddAdd(){
    
            int a = 10;
            a =  ++a;
            System.out.println(a);
    
        }

### 编译后生成的字节码 ###

testAdd()

public void testAdd();
        Code:
           0: bipush        10
           2: istore_1
           3: iload_1
           4: iinc          1, 1
           7: istore_1
           8: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
          11: iload_1
          12: invokevirtual #3                  // Method java/io/PrintStream.println:(I)V
          15: return

### a++执行流程 ###

*  bipush 10：将10赋值给变量a，将10推送至操作数栈栈顶
 *  istore\_1：将操作数栈中的10取出，存入局部变量表1号位置(0号位置放的是this)
 *  iload\_1：将局部变量中的1号元素，即10推送至操作数栈栈顶
 *  iinc 1, 1：将局部变量中下标为1的元素+1，局部变量表中的a变为了11
 *  istore\_1：将栈顶的元素，即10取出，存入局部变量表1号位置，此时之前的11被覆盖了
 *  getstatic：获取System.out对象
 *  iload\_1：将局部变量中的1号元素，即刚刚由11改成的10推送至操作数栈栈顶
 *  invokevirtual：执行输出，输出结果为10
 *  return：方法调用结束。

### \++a执行流程 ###

testAddAdd()

public void testAddAdd();
        Code:
           0: bipush        10
           2: istore_1
           3: iinc          1, 1
           6: iload_1
           7: istore_1
           8: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
          11: iload_1
          12: invokevirtual #3                  // Method java/io/PrintStream.println:(I)V
          15: return

*  bipush 10:将10赋值给a，并将10推送至栈顶
 *  istore\_1：将栈顶的元素，即10取出，存入局部变量表1号位置
 *  iinc 1, 1：将局部变量中下标为1的元素+1，局部变量表中的a变为了11
 *  iload\_1：将局部变量中的1号元素，即11推送至操作数栈栈顶
 *  istore\_1：将栈顶的元素，即11取出，存入局部变量表1号位置
 *  getstatic：获取System.out对象
 *  iload\_1：将局部变量中的1号元素，即11推送至操作数栈栈顶
 *  invokevirtual：执行输出，输出结果为11
 *  return：方法调用结束。