Groovy Json解析

迈不过友情╰ 2023-02-12 05:58 17阅读 0赞

### 如何生成Json字符串 ###

`JsonBuilder`利用元编程的特性帮助我们快速生成一个`json`字符串

import groovy.json.JsonBuilder
    
    def json = new JsonBuilder()
    json.book {
        info {
            name = "Java入门到放弃"
            author = "XiaoMing"
        }
        version {
            mainVersion  "1.0"
        }
    }
    
    //漂亮的格式化输出json
    println(json.toPrettyString())
    //压缩的json
    println(json.toString())

输出：

{
        "book": {
            "info": {
                
            },
            "version": {
                "mainVersion": "1.0"
            }
        }
    }
    {"book":{"info":{},"version":{"mainVersion":"1.0"}}}

当然`JsonBuilder`构建的时候还可以传入一个Object对象，然后将对象转化为`json`

import groovy.json.JsonBuilder
    
    
    class Person {
        def name = "XiaoMing"
        def age = 23
    }
    
    def person = new Person()
    def json = new JsonBuilder(person)
    
    println(json.toString())

输出：

{"age":23,"name":"XiaoMing"}

*  JsonOutput类 同样可以帮助我们将类或Map转为json

import groovy.json.JsonBuilder
    import groovy.json.JsonOutput
    
    
    class Person {
        def name = "XiaoMing"
        def age = 23
    }
    
    def person = new Person()
    
    println(JsonOutput.toJson(person))

### Json转化为Bean ###

`JsonSlurper`可以将一个`json`解析为`Map`集合，然后我们可以将这个集合构造除对象.

首先在Groovy 一个Map会智能转化为对应Bean对象，并把map的key和Bean属性对应上，然后进行赋值。

class Person {
        def name = "XiaoMing"
        def age = 23
    }
    
    def myMap = [name: "ZhangSan", age: 23]
    
    Person myNewPerson = myMap
    
    println(myNewPerson.dump())

输出：  
`<Person@192b07fd name=ZhangSan age=23>`

我们回过头继续看Sluerper

import groovy.json.JsonBuilder
    import groovy.json.JsonOutput
    import groovy.json.JsonSlurper
    
    
    class Person {
        def name = "XiaoMing"
        def age = 23
    }
    
    
    def slurper = new JsonSlurper()
    
    def json = """{"age":123,"name":"ZhangSan"}"""
    
    
    def parseResult = slurper.parseText(json)
    
    println("result is map ${parseResult instanceof Map}")
    
    Person person = parseResult
    
    println("利用map构造的person ${person.dump()}")

输出：

result is map true
    利用map构造的person <Person@74650e52 name=ZhangSan age=123>