sas 检测到开型代码语句的递归_对SAS数据集变量名的操作

男娘i 2023-01-04 11:49 217阅读 0赞

![0a7921e25f20310c2e60c4006798b58b.png][]

通过前面几节的学习，我们可以将外部原始数据导入到SAS软件中生成SAS数据集了。如果你还对如何导入数据比较迷惑，可以看我之前的文章：

秋葵：SAS导入外部数据|菜单及proc步导入zhuanlan.zhihu.com

![5dec0092cb346d9a67c6553ca9ba52ac.png][]

秋葵：data步导入原始数据zhuanlan.zhihu.com

![5dec0092cb346d9a67c6553ca9ba52ac.png][]

对于导入的SAS数据集，我们一般要对其变量和观测进行一连串的操作，使得SAS数据集成为我们想要的样子，便于后续分析，比如，更改变量名称，只保留某几个变量，选择符合条件的观测，等等。这一节，我们对SAS数据集变量名操作相关的选项和语句进行介绍。

1.  **认识SAS数据集**

首先，我们要认识一下SAS数据集，以SAS软件中自带的sashelp逻辑库中的class数据集为例

![7040a74f565972d7ccc2b26fd7aed0a5.png][]

sashelp.class

在SAS数据集中，每一行，我们称之为观测，每一列，我们称之为变量，sashelp.class中，每一个观测表示一个人的样本，一共有五个变量，姓名，性别，年龄，身高和体重，我们知道SAS变量名必须以字母和下划线(\_)开头，只能含有字母数字下划线，SAS数据集展示给我们看到的是SAS变量的标签（label），以告诉我们变量名的真实含义。鼠标双击某一个变量，我们可以看到：

![5e66bb8923815408ed222ca7f53180b1.png][]

变量属性

展示给我们的是变量的属性，我们可以看到这些属性包括SAS变量名，变量的标签，变量的长度，输入格式（informat）和输出格式（format）

**2. SAS数据集中仅保留特定的变量**

有时候导入的SAS数据集中的变量并不都是我们所需要的，或者在进行某些分析时，我们只需要某几个特定的变量，这时候我们就要去除或者保留SAS数据集中的某些变量。

SAS数据集中keep=选项，则告诉SAS只保留=后面的变量，例如sashelp.class数据集中含有name，sex，age，height和weight，我们只想数据集中保留name，sex，age，则可通过下面代码实现：

data class;
      set sashelp.class(keep=name sex age);
    run;

set语句是读取SAS数据集，数据集后面紧跟的括号中指定SAS数据集的选项，keep后面可以指定多个变量名，且中间用空格隔开。除了使用keep选项外，我们也可以使用keep语句，即：

data class;
      set sashelp.class;
      keep name sex age;
    run;

该语句实现与上述同样的功能，keep选项和keep语句的区别在于，后者只能用于data步中，而前者只要用在SAS数据集后面即可，不管是在data步还是proc步中。

当keep选项后面保留数据集中不存在的变量名时，SAS会报错，什么都不会输出到数据集中。但是当keep语句中保留不存在的变量时，只会出现warning，当keep语句后保留多个变量，其中只有一个是不存在变量时，则另外变量仍然是keep到输出数据集中的；当keep语句保留的变量均不存在时，此时未保留任何数据到输出数据集中，输出数据集中是空的，什么都没有。比如下面程序：

data class;
      set sashelp.class;
      keep height_new weight_new;
    run;

由于height\_new和weight\_new不存在，class是空数据集。

除了使用keep外，也可以使用drop实现上述功能，用SAS数据集的drop选项：

data class;
      set sashelp.class(drop=height weight);
    run;

使用drop语句：

data class;
      set sashelp.class;
      drop height weight;
    run;

跟keep语句一样，drop语句也只能在data步中使用，而drop选项只要放在SAS数据集后面即可，既可用在data步，也可用在proc步。

keep语句和drop语句放在data步的任何地方都具有相同的功能。

**现在**，大家思考一个问题，如果用drop语句去除掉一个变量，那这个变量在该程序中还能不能使用吗，例如我们创建一个新的变量a，其值为体重加上身高，例如下面程序：

data class;
      set sashelp.class;
      drop height weight;
      a=height+weight;
    run;

既然height和weight我们已经drop掉了，这个程序可以得到我们想要的结果吗？

答案是可以的。我们将新的数据集class输出：

proc print data=class;
    run;

得到

![86e3e12adf2688e450ebcec8ec696b02.png][]

通过这个例子，我们知道虽然drop语句后面规定的变量不在SAS数据集中了，但这些变量还是可以在程序中使用的。

那么，我们使用drop选项时，能否也可以像上面一样，创建新变量a，a的值为身高加上体重呢：

data class;
      set sashelp.class(drop=height weight);
      a=height+weight;
    run;

class数据集如下：

![55f460072ce43cb6ca5b745e9e0f034c.png][]

变量weight，height和a均为缺失，同时，日志显示

![442caaf29ecbd6d356f2dce02fbe9edd.png][]

显示weight和height未初始化，即不存在。

这说明在set后面数据集后添加drop选项去除某些变量时，后续的程序中是不能使用drop后面的变量进行操作的，因为它们已经被去除了。

如果非要想用drop语句，可以使用下面的程序：

data class(drop=height weight);
      set sashelp.class;
      a=height+weight;
    run;

即我们在新创建的class数据集中进行去除height和weight变量的操作。

同样，对于keep选项，如果在set语句后面的数据集中使用keep保留某些变量，则后续的程序只能使用keep选项后面的变量。

而keep语句和drop语句指定的变量，只在新创建的SAS数据集中生效，整个程序中都可以使用任何变量。这是因为keep语句和drop语句是不可执行语句。

**3. 更改SAS变量名**

有的时候我们需要更改SAS变量名称，我们可以用rename语句以及SAS数据集rename选项。例如，我们想把height变量改名为height\_new，用rename选项：

data class;
      set sashelp.class(rename=(height=height_new));
    run;

rename=后面需要加上括号，括号中进行变量名称的更改，括号中等号前面为当前的旧变量名，等号后面为更新的变量名。

我们可以同时更改多个变量的变量名，例如：

data class;
      set sashelp.class(rename=(height=height_new weight=weight_new));
    run;

只需要在括号中继续添加即可。

除了使用rename选项，我们也可以使用rename语句执行相同的操作：

data class;
      set sashelp.class;
      rename height=height_new weight=weight_new;
    run;

与keep和drop语句类似，rename语句也只能用于data步中，而rename选项可以使用的更加灵活，既可以用于data步，也可以使用proc步中。

当在set语句后的数据集中使用rename选项更改变量名时，后续的data步操作得使用更改过后的变量名。例如，要创建一个新变量a，其值为身高加上体重：

data class;
      set sashelp.class(rename=(height=height_new weight=weight_new));
      a=height_new+weight_new;
    run;

当使用rename语句时，更改的变量只在输出的数据集中生效，在当前程序中必须使用老名字，例如：

data class;
      set sashelp.class;
      rename height=height_new weight=weight_new;
      a=height+weight;
    run;

当rename语句与keep或者drop语句一起使用时，则keep语句和drop语句会首先起作用，例如下面这个程序：

data class;
      set sashelp.class;
      rename height=height_new weight=weight_new;
      keep height_new weight_new;
    run;

则会报错，日志如下：

![7e19d4b7373176878e9b6b7fca27fa4c.png][]

这是因为keep语句比rename语句先执行，而此时height\_new和weight\_new不存在，由于keep语句后面的变量均不存在，则未保留任何变量，数据集是空的，所以也就没有height和weight变量。

当rename数据集选项和keep或者drop选项一起使用时，也是首先执行keep或者drop选项。

[0a7921e25f20310c2e60c4006798b58b.png]: /images/20221119/b5c9f9d7746e4a0ea2c9626e7866de20.png
[5dec0092cb346d9a67c6553ca9ba52ac.png]: /images/20221119/013918cdfaa545c5a9d0f41bea405895.png
[7040a74f565972d7ccc2b26fd7aed0a5.png]: /images/20221119/7ea64b74d3f9406db5020f24f6ad995f.png
[5e66bb8923815408ed222ca7f53180b1.png]: https://img-blog.csdnimg.cn/img_convert/5e66bb8923815408ed222ca7f53180b1.png
[86e3e12adf2688e450ebcec8ec696b02.png]: https://img-blog.csdnimg.cn/img_convert/86e3e12adf2688e450ebcec8ec696b02.png
[55f460072ce43cb6ca5b745e9e0f034c.png]: https://img-blog.csdnimg.cn/img_convert/55f460072ce43cb6ca5b745e9e0f034c.png
[442caaf29ecbd6d356f2dce02fbe9edd.png]: https://img-blog.csdnimg.cn/img_convert/442caaf29ecbd6d356f2dce02fbe9edd.png
[7e19d4b7373176878e9b6b7fca27fa4c.png]: https://img-blog.csdnimg.cn/img_convert/7e19d4b7373176878e9b6b7fca27fa4c.png