STM32启动文件代码解析

浅浅的花香味﹌ 2022-12-29 15:30 202阅读 0赞

### 目录 ###

*  启动流程
 *  代码详解
 *  启动文件使用的 ARM 汇编指令汇总
 *  关于与启动文件有关的一些问题思考

下面是F1固件库V3.5.0的启动文件startup\_stm32f10x\_hd.s，以此为例做解析，其余的型号的启动文件都差不多，主要区别在于因片上外设不同，支持的中断就不一样，所以在启动文件的中断向量表不同型号会有差别。

# 启动流程 #

启动文件由汇编编写，是系统上电复位后第一个执行的程序。主要做了以下工作：  
1、初始化堆栈指针 SP=\_initial\_sp  
2、初始化 PC指针=Reset\_Handler  
3、初始化中断向量表  
4、配置系统时钟  
5、调用 C库函数\_main 初始化用户堆栈，从而最终调用 main 函数去到 C的世界

# 代码详解 #

下面是用于KEIL中启动文件，加入了较详细的注释：

; 分配给堆栈的内存量(以字节为单位)
    ; 根据应用程序的需要定制此值
    ; <h> Stack Configuration 栈配置
    ;   <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
    ; </h>
    Stack_Size      EQU     0x00000400   ;类似于：#define Stack_Size 0x00000400
    
                    AREA    STACK, NOINIT, READWRITE, ALIGN=3  ;伪指令AREA，表示名字为 STACK，NOINIT 即不初始化，可读可写，8（2^3）字节对齐。
    Stack_Mem       SPACE   Stack_Size   ;开辟一段大小为Stack_Size的内存空间作为栈，Stack_Size已经定义为了0x00000400（1KB）
    __initial_sp    ;标号__initial_sp紧挨着SPACE语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。
                                                      
    ; <h> Heap Configuration 堆配置
    ;   <o>  Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
    ; </h>
    
    Heap_Size       EQU     0x00000200  ;类似于：#define Heap_Size 0x00000200
    
                    AREA    HEAP, NOINIT, READWRITE, ALIGN=3  ;伪指令AREA，表示名字为 HEAP，NOINIT即不初始化，可读可写，8（2^3）字节对齐
    __heap_base     ; __heap_base 表示对的起始地址
    Heap_Mem        SPACE   Heap_Size  ;开辟堆的大小为 0X00000200（512字节）
    __heap_limit    ; __heap_limit 表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反
    
                    PRESERVE8  ; 指定当前文件的堆栈按照 8字节对齐
                    THUMB      ; 表示后面指令兼容 THUMB 指令，THUBM 是 ARM 以前的指令集， 16bit，现在 Cortex-M 系列的都使用 THUMB-2 指令集， THUMB-2 是 32 位的，兼容 16 位和 32 位的指令，是 THUMB 的超集。
    
    
    ; Vector Table Mapped to Address 0 at Reset
                    AREA    RESET, DATA, READONLY ;定义一个数据段，名字为 RESET，可读。
                    EXPORT  __Vectors   ;声明 __Vectors、__Vectors_End 和__Vectors_Size这三个标号具有全局属性，可供外部的文件调用。
                    EXPORT  __Vectors_End  ;EXPORT ：声明一个标号可被外部的文件使用，使标号具有全局属性。
                    EXPORT  __Vectors_Size
    
    	;__Vectors 为向量表起始地址   DCD: 以字为单位分配内存，要求 4字节对齐，并要求初始化这些内存
    __Vectors       DCD     __initial_sp               ; Top of Stack 栈顶地址MSP
                    DCD     Reset_Handler              ; Reset Handler 复位程序地址
                    DCD     NMI_Handler                ; NMI Handler
                    DCD     HardFault_Handler          ; Hard Fault Handler
                    DCD     MemManage_Handler          ; MPU Fault Handler
                    DCD     BusFault_Handler           ; Bus Fault Handler
                    DCD     UsageFault_Handler         ; Usage Fault Handler
                    DCD     0                          ; Reserved  0表示保留
                    DCD     0                          ; Reserved
                    DCD     0                          ; Reserved
                    DCD     0                          ; Reserved
                    DCD     SVC_Handler                ; SVCall Handler
                    DCD     DebugMon_Handler           ; Debug Monitor Handler
                    DCD     0                          ; Reserved
                    DCD     PendSV_Handler             ; PendSV Handler
                    DCD     SysTick_Handler            ; SysTick Handler
    
                    ; External Interrupts 以下是外部中断
                    DCD     WWDG_IRQHandler            ; Window Watchdog
                    DCD     PVD_IRQHandler             ; PVD through EXTI Line detect
                    DCD     TAMPER_IRQHandler          ; Tamper
                    DCD     RTC_IRQHandler             ; RTC
                    DCD     FLASH_IRQHandler           ; Flash
                    DCD     RCC_IRQHandler             ; RCC
                    DCD     EXTI0_IRQHandler           ; EXTI Line 0
                    DCD     EXTI1_IRQHandler           ; EXTI Line 1
                    DCD     EXTI2_IRQHandler           ; EXTI Line 2
                    DCD     EXTI3_IRQHandler           ; EXTI Line 3
                    DCD     EXTI4_IRQHandler           ; EXTI Line 4
                    DCD     DMA1_Channel1_IRQHandler   ; DMA1 Channel 1
                    DCD     DMA1_Channel2_IRQHandler   ; DMA1 Channel 2
                    DCD     DMA1_Channel3_IRQHandler   ; DMA1 Channel 3
                    DCD     DMA1_Channel4_IRQHandler   ; DMA1 Channel 4
                    DCD     DMA1_Channel5_IRQHandler   ; DMA1 Channel 5
                    DCD     DMA1_Channel6_IRQHandler   ; DMA1 Channel 6
                    DCD     DMA1_Channel7_IRQHandler   ; DMA1 Channel 7
                    DCD     ADC1_2_IRQHandler          ; ADC1 & ADC2
                    DCD     USB_HP_CAN1_TX_IRQHandler  ; USB High Priority or CAN1 TX
                    DCD     USB_LP_CAN1_RX0_IRQHandler ; USB Low  Priority or CAN1 RX0
                    DCD     CAN1_RX1_IRQHandler        ; CAN1 RX1
                    DCD     CAN1_SCE_IRQHandler        ; CAN1 SCE
                    DCD     EXTI9_5_IRQHandler         ; EXTI Line 9..5
                    DCD     TIM1_BRK_IRQHandler        ; TIM1 Break
                    DCD     TIM1_UP_IRQHandler         ; TIM1 Update
                    DCD     TIM1_TRG_COM_IRQHandler    ; TIM1 Trigger and Commutation
                    DCD     TIM1_CC_IRQHandler         ; TIM1 Capture Compare
                    DCD     TIM2_IRQHandler            ; TIM2
                    DCD     TIM3_IRQHandler            ; TIM3
                    DCD     TIM4_IRQHandler            ; TIM4
                    DCD     I2C1_EV_IRQHandler         ; I2C1 Event
                    DCD     I2C1_ER_IRQHandler         ; I2C1 Error
                    DCD     I2C2_EV_IRQHandler         ; I2C2 Event
                    DCD     I2C2_ER_IRQHandler         ; I2C2 Error
                    DCD     SPI1_IRQHandler            ; SPI1
                    DCD     SPI2_IRQHandler            ; SPI2
                    DCD     USART1_IRQHandler          ; USART1
                    DCD     USART2_IRQHandler          ; USART2
                    DCD     USART3_IRQHandler          ; USART3
                    DCD     EXTI15_10_IRQHandler       ; EXTI Line 15..10
                    DCD     RTCAlarm_IRQHandler        ; RTC Alarm through EXTI Line
                    DCD     USBWakeUp_IRQHandler       ; USB Wakeup from suspend
                    DCD     TIM8_BRK_IRQHandler        ; TIM8 Break
                    DCD     TIM8_UP_IRQHandler         ; TIM8 Update
                    DCD     TIM8_TRG_COM_IRQHandler    ; TIM8 Trigger and Commutation
                    DCD     TIM8_CC_IRQHandler         ; TIM8 Capture Compare
                    DCD     ADC3_IRQHandler            ; ADC3
                    DCD     FSMC_IRQHandler            ; FSMC
                    DCD     SDIO_IRQHandler            ; SDIO
                    DCD     TIM5_IRQHandler            ; TIM5
                    DCD     SPI3_IRQHandler            ; SPI3
                    DCD     UART4_IRQHandler           ; UART4
                    DCD     UART5_IRQHandler           ; UART5
                    DCD     TIM6_IRQHandler            ; TIM6
                    DCD     TIM7_IRQHandler            ; TIM7
                    DCD     DMA2_Channel1_IRQHandler   ; DMA2 Channel1
                    DCD     DMA2_Channel2_IRQHandler   ; DMA2 Channel2
                    DCD     DMA2_Channel3_IRQHandler   ; DMA2 Channel3
                    DCD     DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
    __Vectors_End  ; __Vectors_End 为向量表结束地址
    
    __Vectors_Size  EQU  __Vectors_End - __Vectors  ;__Vectors 为向量表起始地址， __Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。
    
                    AREA    |.text|, CODE, READONLY  ;定义一个名称为.text 的代码段，可读
                    
    ; Reset handler复位程序
    Reset_Handler   PROC   ;PROC 定义子程序，与 ENDP 成对使用，表示子程序结束
                    EXPORT  Reset_Handler             [WEAK]  ;WEAK表示弱定义
                    IMPORT  __main   ;IMPORT类似于extern，表示__main和SystemInit都来自外部文件，__main 是一个标准的 C 库函数，主要作用是初始化用户堆栈，并在函数的最后调用main 函数去到 C 的世界
                    IMPORT  SystemInit ;SystemInit()是一个标准的库函数，在system_stm32f10x.c这个库文件中定义。主要作用是配置系统时钟
                    LDR     R0, =SystemInit
                    BLX     R0               
                    LDR     R0, =__main
                    BX      R0
                    ENDP
                    
    ; Dummy Exception Handlers (infinite loops which can be modified无限循环可以被修改)
    
    NMI_Handler     PROC
                    EXPORT  NMI_Handler                [WEAK]
                    B       .        ;跳转到一个标号。这里跳转到一个‘.’，即表示无线循环
                    ENDP
    HardFault_Handler\
                    PROC
                    EXPORT  HardFault_Handler          [WEAK]
                    B       .
                    ENDP
    MemManage_Handler\
                    PROC
                    EXPORT  MemManage_Handler          [WEAK]
                    B       .
                    ENDP
    BusFault_Handler\
                    PROC
                    EXPORT  BusFault_Handler           [WEAK]
                    B       .
                    ENDP
    UsageFault_Handler\
                    PROC
                    EXPORT  UsageFault_Handler         [WEAK]
                    B       .
                    ENDP
    SVC_Handler     PROC
                    EXPORT  SVC_Handler                [WEAK]
                    B       .
                    ENDP
    DebugMon_Handler\
                    PROC
                    EXPORT  DebugMon_Handler           [WEAK]
                    B       .
                    ENDP
    PendSV_Handler  PROC
                    EXPORT  PendSV_Handler             [WEAK]
                    B       .
                    ENDP
    SysTick_Handler PROC
                    EXPORT  SysTick_Handler            [WEAK]
                    B       .
                    ENDP
    
    Default_Handler PROC
    
                    EXPORT  WWDG_IRQHandler            [WEAK]
                    EXPORT  PVD_IRQHandler             [WEAK]
                    EXPORT  TAMPER_IRQHandler          [WEAK]
                    EXPORT  RTC_IRQHandler             [WEAK]
                    EXPORT  FLASH_IRQHandler           [WEAK]
                    EXPORT  RCC_IRQHandler             [WEAK]
                    EXPORT  EXTI0_IRQHandler           [WEAK]
                    EXPORT  EXTI1_IRQHandler           [WEAK]
                    EXPORT  EXTI2_IRQHandler           [WEAK]
                    EXPORT  EXTI3_IRQHandler           [WEAK]
                    EXPORT  EXTI4_IRQHandler           [WEAK]
                    EXPORT  DMA1_Channel1_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel2_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel3_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel4_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel5_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel6_IRQHandler   [WEAK]
                    EXPORT  DMA1_Channel7_IRQHandler   [WEAK]
                    EXPORT  ADC1_2_IRQHandler          [WEAK]
                    EXPORT  USB_HP_CAN1_TX_IRQHandler  [WEAK]
                    EXPORT  USB_LP_CAN1_RX0_IRQHandler [WEAK]
                    EXPORT  CAN1_RX1_IRQHandler        [WEAK]
                    EXPORT  CAN1_SCE_IRQHandler        [WEAK]
                    EXPORT  EXTI9_5_IRQHandler         [WEAK]
                    EXPORT  TIM1_BRK_IRQHandler        [WEAK]
                    EXPORT  TIM1_UP_IRQHandler         [WEAK]
                    EXPORT  TIM1_TRG_COM_IRQHandler    [WEAK]
                    EXPORT  TIM1_CC_IRQHandler         [WEAK]
                    EXPORT  TIM2_IRQHandler            [WEAK]
                    EXPORT  TIM3_IRQHandler            [WEAK]
                    EXPORT  TIM4_IRQHandler            [WEAK]
                    EXPORT  I2C1_EV_IRQHandler         [WEAK]
                    EXPORT  I2C1_ER_IRQHandler         [WEAK]
                    EXPORT  I2C2_EV_IRQHandler         [WEAK]
                    EXPORT  I2C2_ER_IRQHandler         [WEAK]
                    EXPORT  SPI1_IRQHandler            [WEAK]
                    EXPORT  SPI2_IRQHandler            [WEAK]
                    EXPORT  USART1_IRQHandler          [WEAK]
                    EXPORT  USART2_IRQHandler          [WEAK]
                    EXPORT  USART3_IRQHandler          [WEAK]
                    EXPORT  EXTI15_10_IRQHandler       [WEAK]
                    EXPORT  RTCAlarm_IRQHandler        [WEAK]
                    EXPORT  USBWakeUp_IRQHandler       [WEAK]
                    EXPORT  TIM8_BRK_IRQHandler        [WEAK]
                    EXPORT  TIM8_UP_IRQHandler         [WEAK]
                    EXPORT  TIM8_TRG_COM_IRQHandler    [WEAK]
                    EXPORT  TIM8_CC_IRQHandler         [WEAK]
                    EXPORT  ADC3_IRQHandler            [WEAK]
                    EXPORT  FSMC_IRQHandler            [WEAK]
                    EXPORT  SDIO_IRQHandler            [WEAK]
                    EXPORT  TIM5_IRQHandler            [WEAK]
                    EXPORT  SPI3_IRQHandler            [WEAK]
                    EXPORT  UART4_IRQHandler           [WEAK]
                    EXPORT  UART5_IRQHandler           [WEAK]
                    EXPORT  TIM6_IRQHandler            [WEAK]
                    EXPORT  TIM7_IRQHandler            [WEAK]
                    EXPORT  DMA2_Channel1_IRQHandler   [WEAK]
                    EXPORT  DMA2_Channel2_IRQHandler   [WEAK]
                    EXPORT  DMA2_Channel3_IRQHandler   [WEAK]
                    EXPORT  DMA2_Channel4_5_IRQHandler [WEAK]
    
    WWDG_IRQHandler
    PVD_IRQHandler
    TAMPER_IRQHandler
    RTC_IRQHandler
    FLASH_IRQHandler
    RCC_IRQHandler
    EXTI0_IRQHandler
    EXTI1_IRQHandler
    EXTI2_IRQHandler
    EXTI3_IRQHandler
    EXTI4_IRQHandler
    DMA1_Channel1_IRQHandler
    DMA1_Channel2_IRQHandler
    DMA1_Channel3_IRQHandler
    DMA1_Channel4_IRQHandler
    DMA1_Channel5_IRQHandler
    DMA1_Channel6_IRQHandler
    DMA1_Channel7_IRQHandler
    ADC1_2_IRQHandler
    USB_HP_CAN1_TX_IRQHandler
    USB_LP_CAN1_RX0_IRQHandler
    CAN1_RX1_IRQHandler
    CAN1_SCE_IRQHandler
    EXTI9_5_IRQHandler
    TIM1_BRK_IRQHandler
    TIM1_UP_IRQHandler
    TIM1_TRG_COM_IRQHandler
    TIM1_CC_IRQHandler
    TIM2_IRQHandler
    TIM3_IRQHandler
    TIM4_IRQHandler
    I2C1_EV_IRQHandler
    I2C1_ER_IRQHandler
    I2C2_EV_IRQHandler
    I2C2_ER_IRQHandler
    SPI1_IRQHandler
    SPI2_IRQHandler
    USART1_IRQHandler
    USART2_IRQHandler
    USART3_IRQHandler
    EXTI15_10_IRQHandler
    RTCAlarm_IRQHandler
    USBWakeUp_IRQHandler
    TIM8_BRK_IRQHandler
    TIM8_UP_IRQHandler
    TIM8_TRG_COM_IRQHandler
    TIM8_CC_IRQHandler
    ADC3_IRQHandler
    FSMC_IRQHandler
    SDIO_IRQHandler
    TIM5_IRQHandler
    SPI3_IRQHandler
    UART4_IRQHandler
    UART5_IRQHandler
    TIM6_IRQHandler
    TIM7_IRQHandler
    DMA2_Channel1_IRQHandler
    DMA2_Channel2_IRQHandler
    DMA2_Channel3_IRQHandler
    DMA2_Channel4_5_IRQHandler
                    B       .
    
                    ENDP
    
                    ALIGN
    
    ;*******************************************************************************
    ; User Stack and Heap initialization  用户堆栈初始化
    ;*******************************************************************************
                     IF      :DEF:__MICROLIB ;判断是否定义了__MICROLIB
                    
                     EXPORT  __initial_sp;如果定义了这个宏则赋予标号__initial_sp（栈顶地址）、__heap_base（堆起始地址）、__heap_limit（堆结束地址）全局属性，可供外部文件调用。
                     EXPORT  __heap_base
                     EXPORT  __heap_limit
                    
                     ELSE  ;如果没有定义__MICROLIB，则插入标号__use_two_region_memory，这个函数需要用户自己实现
                    
                     IMPORT  __use_two_region_memory
                     EXPORT  __user_initial_stackheap ;声明标号__user_initial_stackheap 具有全局属性，可供外部文件调用，下面实现这个标号的内容。
                     
    __user_initial_stackheap
    
                     LDR     R0, =  Heap_Mem
                     LDR     R1, =(Stack_Mem + Stack_Size)
                     LDR     R2, = (Heap_Mem +  Heap_Size)
                     LDR     R3, = Stack_Mem
                     BX      LR
    
                     ALIGN
    
                     ENDIF
    
                     END  ;文件结束

# 启动文件使用的 ARM 汇编指令汇总 #

【EQU】 给数字常量取一个符号名，相当于 C语言中的 define  
【AREA】 汇编一个新的代码段或者数据段  
【SPACE】 分配内存空间  
【PRESERVE8 】当前文件堆栈需按照 8字节对齐  
【EXPORT】声明一个标号具有全局属性，可被外部的文件使用  
【DCD 】以字为单位分配内存，要求 4字节对齐，并要求初始化这些内存  
【PROC 】定义子程序，与 ENDP 成对使用，表示子程序结束  
【WEAK 】弱定义，如果外部文件声明了一个标号，则优先使用外部文件定义的标号，如果外部文件没有定义也不出错。要注意的是：这个不是ARM的指令，是编译器的，这里放在一起只是为了方便。  
【IMPORT】声明标号来自外部文件，跟 C 语言中的 EXTERN关键字类似  
【B】 跳转到一个标号  
【ALIGN】 编译器对指令或者数据的存放地址进行对齐，一般需要跟一个立即数，缺省表示 4字节对齐。要注意的是：这个不是 ARM的指令，是编译器的，这里放在一起只是为了方便。  
【END】 到达文件的末尾，文件结束  
【IF,ELSE,ENDIF】汇编的条件分支语句，跟 C 语言的 if ,else 类似  
LDR、BLX、BX 是 CM4 内核的指令，可在《CM3 权威指南 CnR2》第四章-指令集里面查询到  
【LDR】 从存储器中加载字到一个寄存器中  
【BL】 跳转到由寄存器/标号给出的地址，并把跳转前的下条指令地址保存到 LR  
【BLX】 跳转到由寄存器给出的地址，并根据寄存器的 LSE 确定处理器的状态，还要把跳转前的下条指令地址保存到 LR  
【BX】 跳转到由寄存器/标号给出的地址，不用返回

# 关于与启动文件有关的一些问题思考 #

1.  在启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的，真正的中断复服务程序需要我们在外部的 C 文件里面重新实现，这里只是提前占了一个位置而已。  
    如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时，程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。  
    B：跳转到一个标号。这里跳转到一个‘.’，即表示无限循环  
    如果你在调试程序时发现死在了启动文件中的B .这个位置，大概率是你使能了某个中断但没有编写中断函数。
2.  栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部SRAM 的大小。如果编写的程序比较大，定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了硬 fault 的时候，这时你就要考虑下是不是栈不够大，溢出了。  
    修改启动文件中的Stack\_Size EQU 0x00000400可以修改栈大小  
    修改启动文件中的Heap\_Size EQU 0x00000200可以修改堆大小
3.  在3.5版F1标准库中的启动文件还调用了在system\_stm32f10x.c文件中的  
    SystemInit（）函数配置系统时钟，在旧版本的工程中要用户进入main函数自己调用SystemInit（）函数。
4.  无论性能高下，结构简繁，价格贵贱，每一种微控制器（处理器）都必须有启动文件，启动文件的作用便是负责执行微控制器从“复位”到“开始执行main函数”中间这段时间（称为启动过程）所必须进行的工作。最为常见的51，AVR或MSP430等微控制器当然也有对应的启动文件，但开发环境往往自动完整地提供了这个启动文件，不需要开发人员再行干预启动过程，只需要从main函数开始进行应用程序的设计即可。
5.  Cortex-M3内核规定，起始地址必须存放堆顶指针，而第二个地址则必须存放复位中断入口向量地址，这样在Cortex-M3内核复位后，会自动从起始地址的下一个32位空间取出复位中断入口向量，跳转执行复位中断服务程序。
6.  Cortex-M3内核可通过boot引脚设置中断向量表的位置（即可以设置从不同位置启动），有3种情况:  
    1、 通过boot引脚设置可以将中断向量表定位于SRAM区，即起始地址为0x2000000，同时复位后PC指针位于0x2000000处；  
    2、 通过boot引脚设置可以将中断向量表定位于FLASH区，即起始地址为0x8000000，同时复位后PC指针位于0x8000000处；  
    3、 通过boot引脚设置可以将中断向量表定位于内置Bootloader区

参考鸣谢  
[https://www.cnblogs.com/wenshinlee/p/8859227.html][https_www.cnblogs.com_wenshinlee_p_8859227.html]  
[https://www.cnblogs.com/amanlikethis/p/3719529.html][https_www.cnblogs.com_amanlikethis_p_3719529.html]

[https_www.cnblogs.com_wenshinlee_p_8859227.html]: https://www.cnblogs.com/wenshinlee/p/8859227.html
[https_www.cnblogs.com_amanlikethis_p_3719529.html]: https://www.cnblogs.com/amanlikethis/p/3719529.html