【操作系统真象还原系列】1. 利用MBR在显示器上输出Hello World!

╰半夏微凉° 2022-12-27 07:49 247阅读 0赞

### 目录 ###

*  实模式下的内存布局
 *  文本模式下的显存
 *  文本模式下的光标控制
 *   *  索引寄存器和数据寄存器
     *  获取当前光标位置
     *  设置当前光标位置
 *  实模式下在光标处输出字符
 *  实模式下的字符串打印函数
 *  实验结果
 *   *  实验代码
     *  测试效果

# 实模式下的内存布局 #

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]

# 文本模式下的显存 #

从上图中我们可以看到实模式下与显存相关的内存布局。单独将其摘录如下所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]  
从上表可以看出，显卡支持三种模式：文本模式、黑白图形模式、彩色图形模式。万事开头难，所以我们就先使用最简单的文本模式。

显卡上电之后，默认处于80*25的文本模式。其实文本模式也是分为很多种的，用“列数*行数”来表示，如80*25、40*25、80*43、80*50等等。

从起始地址0xB8000到0xBFFFF一共32KB的区域就是用于文本模式的显存。其中，一个字符需要占用两个字节的显存。这两个字节当中，低字节是该字符的ASCII码，高字节是字符的属性元信息。具体内容如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]  
我们知道，RGB三原色如果以任意比例混合，就可以调配出其他颜色。但是在文本模式下，RGB三者的比例要么是1，要么就是没有。故其可以组合出来的颜色如下表所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]

# 文本模式下的光标控制 #

光标是当显卡工作在文本模式下时，在屏幕上有规律地闪动的一条小横线，用于指示下一个要显示的字符位置。光标在屏幕上的位置保存在显卡内部的两个光标寄存器中，每个寄存器有8位，合起来形成一个16位的数值。

在标准VGA文本模式下，一屏共有25行，一行80个字符。故有效值域为\[0, 1999\]，对应屏幕上可以显示的2000个字符（25行 x 80列）。当光标在屏幕右下角的时候，该值为25x80-1=1999。光标寄存器是可读可写的。通过写入，我们可以设置光标的显示位置。

## 索引寄存器和数据寄存器 ##

显卡中用于控制光标显示的是一对寄存器：索引寄存器（0x3D4）和数据寄存器（0x3D5）。由于显卡的操作非常复杂，为了不过多地占用I/O地址空间，很多寄存器只能通过索引寄存器间接访问。

索引寄存器的端口号是0x3D4，可以向他写入一个值，用来指定内部的某个寄存器。比如，两个8位的光标寄存器，其索引值分别是0xE和0xF，分别用于提供光标位置的高8位和低8位。

为此，我们定义如下宏方便操作：

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF

## 获取当前光标位置 ##

注意，由于现在所有代码都在同一个段中，所以我们采用的函数调用方式是 实模式下的相对近调用。所以函数返回时需要使用ret，而不是retf。以下所有函数的返回方式都是这样。

;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret

## 设置当前光标位置 ##

;输入参数是光标索引，放在寄存器ax中
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret

# 实模式下在光标处输出字符 #

;视频显示缓冲区物理地址   
    video_ram_segment   equ  0xB8000 
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, video_ram_segment
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, video_ram_segment_sel
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	mov ax, di
    	shr ax, 1
    	call kernel_routine_segment_sel:setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret

# 实模式下的字符串打印函数 #

;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret

# 实验结果 #

## 实验代码 ##

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    video_ram_segment   equ  0xB800
    
    mbr_ram_segment equ 0x7C0
    
    [bits 16]
    
    ;设置实模式下的堆栈
    segment mbrLoader align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov ds, ax
    	mov sp, 0x7c00
    
    	
    ;关中断
    	cli
    	mov eax, message
    	call printString
    	jmp $
    	
    ;返回值是光标索引，放在寄存器ax中           
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    	
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    
    
    ; 打印一个字符，入参存放在寄存器al中
    printCharacter:
    	push es
    	push ds
    	push eax
    	push edi
    	push ebx
    	push ecx
    	
    	; save character to register bl
    	mov bl, al
    	
    	;set video buffer
    	mov eax, video_ram_segment
       	mov es, eax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;just return if the screen is full
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push edi
    	mov ax, video_ram_segment
    	mov ds, ax
    	mov es, ax
    	cld
    	mov ecx, 1920
    	mov edi, 0
    	mov esi, 160
    	rep movsw
    	;clear screen last line
    	mov ebx, 3840                     
    	mov ecx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop edi
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	xor eax, eax
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop ecx
    	pop ebx
    	pop edi
    	pop eax
    	pop ds
    	pop es
    	ret
    	
    ;字符串打印函数，首地址存储在寄存器eax中
    printString:
    	push eax
    	push esi
    	
    	;save string start address to si
    	mov esi, eax
    	
    @1: mov al, [esi]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc esi
    	jmp @1
    	
    @2:
    	pop esi
    	pop eax
    	
    	ret	
    	
    message: db 'Hello World.', 0xA, 0xD, 0
    
    times 510-($-$$) db 0
    db 0x55,0xaa

## 测试效果 ##

> $ nasm -f bin mbr\_helloworld.s -o mbr\_helloworld.bin  
> $ ll mbr\_helloworld.bin  
> \-rw-rw-r-- 1 macrofun macrofun 512 12月 10 23:02 mbr\_helloworld.bin

我们使用nasm来编译汇编mbr\_helloworld.s这个汇编文件，之后将生成的bin文件写入我们所采用的固定大小的VHD虚拟硬盘文件中，如下所示：

> $ dd if=mbr\_helloworld.bin of=MBR\_Stage1.vhd bs=512 count=1 conv=notrunc  
> 1+0 records in  
> 1+0 records out  
> 512 bytes copied, 0.000218429 s, 2.3 MB/s

实验动态效果图如下所示：  
![在这里插入图片描述][20201210231021395.gif_pic_center]

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center]: /images/20221120/57c1b3e1d9464c1392902de0344d3b22.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 1]: /images/20221120/0951fdabe8834e4ea2c108d72b47ab4a.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 2]: https://img-blog.csdnimg.cn/20201209001209397.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70_pic_center 3]: https://img-blog.csdnimg.cn/20201209002306194.jpg?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ=,size_16,color_FFFFFF,t_70#pic_center
[20201210231021395.gif_pic_center]: https://img-blog.csdnimg.cn/20201210231021395.gif#pic_center