PowerDesigner一键导出数据库设计表结构

本是古典何须时尚 2022-11-09 01:28 311阅读 0赞

## 1、背景 ##

帮朋友弄下数据库设计，又用到PowerDesigner，因为还要数据库设计文档（word），还想着怎么把数据库结构导出呢，发现以前弄过，一键导出，很方便，分享下，祝好运！

## 2、解决方案 ##

### 2.1 执行窗口 ###

依次点击，Tools->Execute Commands ->Edit/Run Script

![16c526c143170fdda1ec8e408859c3c7.png][]

### 2.2 执行脚本 ###

第一次执行，复制脚本到空白编辑处，点击三角执行按钮就可以了，执行完成后可以保存脚本，以便下次用，下次直接打开文件执行就可以了。

![65e2cdf6ee1df826ea8407e265d3c0d0.png][]

### 2.3 执行效果 ###

（1）点击执行后，会首先生成临时excel文件。

![789114142c0568a806fbc2bb90ac63a1.png][]

（2）打开excel后，有两个sheet，一个sheet是表目录，内容为全部表名称及链接；一个sheet所有表结构信息；

![c11a09d1656a9f3735648c48be407ab1.png][]

![c16d9090fb034b87b2345264f9ab6af1.png][]

### 2.4 脚本 ###

'******************************************************************************
    Option Explicit
       Dim rowsNum
       rowsNum = 0
    '-----------------------------------------------------------------------------
    ' Main function
    '-----------------------------------------------------------------------------
    ' Get the current active model
        Dim Model
        Set Model = ActiveModel
        If (Model Is Nothing) Or (Not Model.IsKindOf(PdPDM.cls_Model)) Then
           MsgBox "The current model is not an PDM model."
        Else
          ' Get the tables collection
          '创建EXCEL APP
          dim beginrow
          DIM EXCEL, SHEET, SHEETLIST
          set EXCEL = CREATEOBJECT("Excel.Application")
          EXCEL.workbooks.add(-4167)'添加工作表
          EXCEL.workbooks(1).sheets(1).name ="表结构"
          set SHEET = EXCEL.workbooks(1).sheets("表结构")
          
          EXCEL.workbooks(1).sheets.add
          EXCEL.workbooks(1).sheets(1).name ="目录"
          set SHEETLIST = EXCEL.workbooks(1).sheets("目录")
          ShowTableList Model,SHEETLIST
    
          ShowProperties Model, SHEET,SHEETLIST
          
          
          EXCEL.workbooks(1).Sheets(2).Select
          EXCEL.visible = true
          '设置列宽和自动换行
          sheet.Columns(1).ColumnWidth = 20 
          sheet.Columns(2).ColumnWidth = 20 
          sheet.Columns(3).ColumnWidth = 20 
          sheet.Columns(4).ColumnWidth = 40 
          sheet.Columns(5).ColumnWidth = 10 
          sheet.Columns(6).ColumnWidth = 10 
          sheet.Columns(1).WrapText =true
          sheet.Columns(2).WrapText =true
          sheet.Columns(4).WrapText =true
          '不显示网格线
          EXCEL.ActiveWindow.DisplayGridlines = False
          
          
     End If
    '-----------------------------------------------------------------------------
    ' Show properties of tables
    '-----------------------------------------------------------------------------
    Sub ShowProperties(mdl, sheet,SheetList)
       ' Show tables of the current model/package
       rowsNum=0
       beginrow = rowsNum+1
       Dim rowIndex 
       rowIndex=3
       ' For each table
       output "begin"
       Dim tab
       For Each tab In mdl.tables
          ShowTable tab,sheet,rowIndex,sheetList
          rowIndex = rowIndex +1
       Next
       if mdl.tables.count > 0 then
            sheet.Range("A" & beginrow + 1 & ":A" & rowsNum).Rows.Group
       end if
       output "end"
    End Sub
    '-----------------------------------------------------------------------------
    ' Show table properties
    '-----------------------------------------------------------------------------
    Sub ShowTable(tab, sheet,rowIndex,sheetList)
       If IsObject(tab) Then
         Dim rangFlag
         rowsNum = rowsNum + 1
          ' Show properties
          Output "================================"
          sheet.cells(rowsNum, 1) =tab.name
          sheet.cells(rowsNum, 1).HorizontalAlignment=3
          sheet.cells(rowsNum, 2) = tab.code
          'sheet.cells(rowsNum, 5).HorizontalAlignment=3
          'sheet.cells(rowsNum, 6) = ""
          'sheet.cells(rowsNum, 7) = "表说明"
          sheet.cells(rowsNum, 3) = tab.comment
          'sheet.cells(rowsNum, 8).HorizontalAlignment=3
          sheet.Range(sheet.cells(rowsNum, 3),sheet.cells(rowsNum, 7)).Merge
          '设置超链接，从目录点击表名去查看表结构
          '字段中文名    字段英文名    字段类型    注释    是否主键    是否非空    默认值
          sheetList.Hyperlinks.Add sheetList.cells(rowIndex,2), "","表结构"&"!B"&rowsNum
          rowsNum = rowsNum + 1
          sheet.cells(rowsNum, 1) = "字段中文名"
          sheet.cells(rowsNum, 2) = "字段英文名"
          sheet.cells(rowsNum, 3) = "字段类型"
          sheet.cells(rowsNum, 4) = "注释"
          sheet.cells(rowsNum, 5) = "是否主键"
          sheet.cells(rowsNum, 6) = "是否非空"
          sheet.cells(rowsNum, 7) = "默认值"
          '设置边框
          sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Borders.LineStyle = "1"
          'sheet.Range(sheet.cells(rowsNum-1, 4),sheet.cells(rowsNum, 9)).Borders.LineStyle = "1"
          '字体为10号
          sheet.Range(sheet.cells(rowsNum-1, 1),sheet.cells(rowsNum, 7)).Font.Size=10
                Dim col ' running column
                Dim colsNum
                colsNum = 0
          for each col in tab.columns
            rowsNum = rowsNum + 1
            colsNum = colsNum + 1
              sheet.cells(rowsNum, 1) = col.name
            'sheet.cells(rowsNum, 3) = ""
              'sheet.cells(rowsNum, 4) = col.name
              sheet.cells(rowsNum, 2) = col.code
              sheet.cells(rowsNum, 3) = col.datatype
            sheet.cells(rowsNum, 4) = col.comment
              If col.Primary = true Then
            sheet.cells(rowsNum, 5) = "Y" 
            Else
            sheet.cells(rowsNum, 5) = " " 
            End If
            If col.Mandatory = true Then
            sheet.cells(rowsNum, 6) = "Y" 
            Else
            sheet.cells(rowsNum, 6) = " " 
            End If
            sheet.cells(rowsNum, 7) =  col.defaultvalue
          next
          sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Borders.LineStyle = "3"       
          'sheet.Range(sheet.cells(rowsNum-colsNum+1,4),sheet.cells(rowsNum,9)).Borders.LineStyle = "3"
          sheet.Range(sheet.cells(rowsNum-colsNum+1,1),sheet.cells(rowsNum,7)).Font.Size = 10
          rowsNum = rowsNum + 2
          
          Output "FullDescription: "       + tab.Name
       End If
       
    End Sub
    '-----------------------------------------------------------------------------
    ' Show List Of Table
    '-----------------------------------------------------------------------------
    Sub ShowTableList(mdl, SheetList)
       ' Show tables of the current model/package
       Dim rowsNo
       rowsNo=1
       ' For each table
       output "begin"
       SheetList.cells(rowsNo, 1) = "主题"
       SheetList.cells(rowsNo, 2) = "表中文名"
       SheetList.cells(rowsNo, 3) = "表英文名"
       SheetList.cells(rowsNo, 4) = "表说明"
       rowsNo = rowsNo + 1
       SheetList.cells(rowsNo, 1) = mdl.name
       Dim tab
       For Each tab In mdl.tables
         If IsObject(tab) Then
             rowsNo = rowsNo + 1
          SheetList.cells(rowsNo, 1) = ""
          SheetList.cells(rowsNo, 2) = tab.name
          SheetList.cells(rowsNo, 3) = tab.code
          SheetList.cells(rowsNo, 4) = tab.comment
         End If
       Next
        SheetList.Columns(1).ColumnWidth = 20 
          SheetList.Columns(2).ColumnWidth = 20 
          SheetList.Columns(3).ColumnWidth = 30 
         SheetList.Columns(4).ColumnWidth = 60 
       output "end"
    End Sub

--------------------

**更多信息请关注公众号：「软件老王」**，关注不迷路，软件老王和他的IT朋友们，分享一些他们的技术见解和生活故事。  
![dbd519886f170a3b7df0619710ee3835.png][]

[16c526c143170fdda1ec8e408859c3c7.png]: /images/20221023/f65fe8d7b882439da5e8bc689861ebe5.png
[65e2cdf6ee1df826ea8407e265d3c0d0.png]: /images/20221023/bf7d7ab6dc4e48098a13418888207610.png
[789114142c0568a806fbc2bb90ac63a1.png]: /images/20221023/7660f11e4f544e5e83f20452164214e3.png
[c11a09d1656a9f3735648c48be407ab1.png]: /images/20221023/56c1b24f81e94f90beb7f004f9909312.png
[c16d9090fb034b87b2345264f9ab6af1.png]: /images/20221023/e4e51240ce91419f9919d70fe9289ecf.png
[dbd519886f170a3b7df0619710ee3835.png]: /images/20221023/b85c696f486e447cac8feb12afd945a0.png