Cmake构建工程设计——Cmake编写规则

骑猪看日落 2022-10-18 11:23 432阅读 0赞

**Cmake的命令不区分打下写，例如message，set等命令；但Cmake的变量区分大小写。  
为统一风格，本次的Cmake命令全部采用小写，变量全部采用大写加下划线组合**。

# Cmake变量 #

Cmake变量可用关键字set赋值，可以将变量赋值为开关，数字，字符串，列表形式，在之后的Cmake中会多次用到。  
option为开关选项，通常作编译开关。

示例代码

option(OPEN_TEST "open test" ON)
    set(FALSE_TEST FALSE)
    set(NUMBER_TEST 3.14)
    set(STRING_TEST "Cmake Test")
    set(SOURCE_LIST_TEST main.cpp module1.cpp module2.cpp)
    if (OPEN_TEST)
    	message(STATUS "open test: ${OPEN_TEST}")
    endif()
    
    if (NOT FALSE_TEST)
    	message(STATUS "false test: ${FALSE_TEST}")
    endif()
    
    message(STATUS "number test: ${NUMBER_TEST}")
    message(STATUS "string test: ${STRING_TEST}")
    message(STATUS "code list test: ${SOURCE_LIST_TEST}")

执行结果

-- open test: ON
    -- false test: FALSE
    -- number test: 3.14
    -- string test: Cmake Test
    -- code list test: main.cpp;module1.cpp;module2.cpp

变量的集合会以“;”隔开

# Cmake传参 #

执行cmake命令时，Cmake可以针对变量传参，例如：

1.  针对变量CMAKE\_TOOLCHAIN\_FILE 传参：  
    \-DCMAKE\_TOOLCHAIN\_FILE=…/config.cmake
2.  针对变量CMAKE\_BUILD\_TYPE传参：  
    \-DCMAKE\_BUILD\_TYPE=“Debug”

# 读取配置文件.cmake #

一些公共的Cmake配置，不需要在cmake工程中再次配置，可以通过不同的cmake工程进行导入，该文件的后缀为.cmake，读取配置文件可通过传参导入，也可以通过CmakeLists关键字加载导入

通过cmake命令传参导入

cmake -G "$CMAKE_TYPE" ../ -DCMAKE_TOOLCHAIN_FILE=../config.cmake

通过关键字导入

include(${PROJECT_SOURCE_DIR}/common_config.cmake)

# 设置工程：project #

当前版本的描述中对project的设置参数为

project(<PROJECT-NAME> [<language-name>...])
    project(<PROJECT-NAME>
            [VERSION <major>[.<minor>[.<patch>[.<tweak>]]]]
            [DESCRIPTION <project-description-string>]
            [HOMEPAGE_URL <url-string>]
            [LANGUAGES <language-name>...])

LANGUAGES为指定语言，如果工程有多种语言混搭可以不设置该值

简单版直接就设置个工程名

set(MAIN_NAME CmakeTest)
    project(${MAIN_NAME})

详细版即可添加对应的描述

set(MAIN_NAME CmakeTest)
    project(${MAIN_NAME}
        VERSION 1.2.3.4
        DESCRIPTION "CmekTest"
        HOMEPAGE_URL "https://cmake.org/cmake/help/v3.15/command/project.html")

打印工程变量

message("PROJECT_NAME ${PROJECT_NAME}")
    message("PROJECT_VERSION ${PROJECT_VERSION}")
    message("PROJECT_DESCRIPTION ${PROJECT_DESCRIPTION}")
    message("PROJECT_HOMEPAGE_URL ${PROJECT_HOMEPAGE_URL}")
    # 若项目存在多工程，即可使用对应的工程名
    message("MAIN_NAME ${MAIN_NAME}")
    message("${MAIN_NAME}_VERSION ${${MAIN_NAME}_VERSION}")
    message("${MAIN_NAME}_DESCRIPTION ${${MAIN_NAME}_DESCRIPTION}")
    message("${MAIN_NAME}_HOMEPAGE_URL ${${MAIN_NAME}_HOMEPAGE_URL}")

打印结果

PROJECT_NAME CmakeTest
    PROJECT_VERSION 1.2.3.4
    PROJECT_DESCRIPTION CmekTest
    PROJECT_HOMEPAGE_URL https://cmake.org/cmake/help/v3.15/command/project.html
    MAIN_NAME CmakeTest
    CmakeTest_VERSION 1.2.3.4
    CmakeTest_DESCRIPTION CmekTest
    CmakeTest_HOMEPAGE_URL https://cmake.org/cmake/help/v3.15/command/project.html

# 注释 #

Cmake采用“\#”进行注释

# 条件判断：if #

和C/C++一样，通过if、elseif、endif关键字进行条件判断。

if(<condition>)
      <commands>
    elseif(<condition>) # optional block, can be repeated
      <commands>
    else()              # optional block
      <commands>
    endif()

官方说明：

> https://cmake.org/cmake/help/v3.15/command/if.html?highlight=\#command:if

if(NOT <condition>)
    条件非
    
    if(<cond1> AND <cond2>)
    条件与
    
    if(<cond1> OR <cond2>)
    条件或
    
    if(<variable|string> LESS <variable|string>)
    如果给定的字符串或变量的值为有效值，并且小于右边的值，则为 True。
    
    if(<variable|string> GREATER <variable|string>)
    如果给定的字符串或变量的值为有效值且大于右边的值，则为 True。
    
    if(<variable|string> EQUAL <variable|string>)
    如果给定的字符串或变量的值为有效值，并且等于右边的值，则为 True。
    
    if(<variable|string> LESS_EQUAL <variable|string>)
    如果给定的字符串或变量的值为有效值，并且小于或等于右边的值，则为 True。
    if(<variable|string> GREATER_EQUAL <variable|string>)
    如果给定的字符串或变量的值为有效值，并且大于或等于右边的值，则为 True。

# 循环：foreach、while #

## foreach ##

foreach(<loop_var> <items>)
      <commands>
    endforeach()

其中foreach可引申出以下形式

foreach(<loop_var> RANGE <stop>)
    从0开始，stop填充数字为0、1、2、……的非负整数
    
    foreach(<loop_var> RANGE <start> <stop> [<step>])
    start stop step填充数字为0、1、2、……的非负整数，若step未指定，默认步长为1，stop不得小于start
    
    foreach(loop_var IN [LISTS [<lists>]] [ITEMS [<items>]])
    传入列表或项目

官方详细说明：

> https://cmake.org/cmake/help/v3.15/command/foreach.html?highlight=foreach

关键字continue与break逻辑同样适用

示例

message(STATUS "foreach(getValue 2 3 5 7 11 13 17 19)")
    foreach(getValue 2 3 5 7 11 13 17 19)
    	if(getValue LESS 5)
    		continue()
    	endif()
    	message(STATUS "foreach1 getValue: ${getValue}")	
    endforeach()
    
    message(STATUS "getValue RANGE 5")
    foreach(getValue RANGE 5)
    	if(getValue GREATER 3)
    		break()
    	endif()
    	message(STATUS "foreach2 getValue: ${getValue}")
    endforeach()
    
    message(STATUS "foreach(getValue RANGE 2 20 4)")
    foreach(getValue RANGE 2 20 4)
    	message(STATUS "foreach3 getValue: ${getValue}")
    endforeach()
    
    # 采用官方的示例
    set(A 0;1)
    set(B 2 3)
    set(C "4 5")
    set(D 6;7 8)
    set(E "")
    message(STATUS "foreach(X IN LISTS A B C D E)")
    foreach(X IN LISTS A B C D E)
        message(STATUS "X=${X}")
    endforeach()

执行结果

-- foreach(getValue 2 3 5 7 11 13 17 19)
    -- foreach1 getValue: 5
    -- foreach1 getValue: 7
    -- foreach1 getValue: 11
    -- foreach1 getValue: 13
    -- foreach1 getValue: 17
    -- foreach1 getValue: 19
    -- getValue RANGE 5
    -- foreach2 getValue: 0
    -- foreach2 getValue: 1
    -- foreach2 getValue: 2
    -- foreach2 getValue: 3
    -- foreach(getValue RANGE 2 20 4)
    -- foreach3 getValue: 2
    -- foreach3 getValue: 6
    -- foreach3 getValue: 10
    -- foreach3 getValue: 14
    -- foreach3 getValue: 18
    -- foreach(X IN LISTS A B C D E)
    -- X=0
    -- X=1
    -- X=2
    -- X=3
    -- X=4 5
    -- X=6
    -- X=7
    -- X=8

## while ##

while(<condition>)
      <commands>
    endwhile()

其中condition变量需要自増或自减

示例

set(getValue 2) 
    while(getValue LESS 6)
    	message(STATUS "while getValue : ${getValue}")
    	math(EXPR getValue "${getValue} + 1")
    endwhile()

执行结果

-- while getValue : 2
    -- while getValue : 3
    -- while getValue : 4
    -- while getValue : 5

# 判断当前系统名 #

可通过系统宏进行判断

if(WIN32)
        message("PC Windows ${CMAKE_BUILD_TYPE}")
    elseif(UNIX)
        message("PC UNIX ${CMAKE_BUILD_TYPE}")
        add_definitions(-D USE_LINUX)   
    endif(WIN32)
    
    if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
    	message ("PC Linux")
    elseif (${CMAKE_SYSTEM_NAME} MATCHES "Windows")
    	message ("PC Windows")
    else ()
    	message ("other system: ${CMAKE_SYSTEM_NAME}")
    endif ()

也可以直接通过默认变量CMAKE\_SYSTEM\_NAME进行判断

Windows效果

PC Windows Debug
    PC Windows

Linux效果

PC UNIX Debug
    PC Linux

# 显示编译信息 #

Cmake构建出工程后，使用make编译会默认显示Cmake编译进度，但没有显示出完整的编译信息

[  3%] Building C object src/lib/TestLib/CMakeFiles/test_lib.dir/src/open_module1.c.o
    [  7%] Building CXX object src/app/AlgorithmTest/CMakeFiles/algorithmTest.dir/src/BinaryTree.cpp.o
    [ 10%] Building C object src/lib/TestLib/CMakeFiles/test_lib.dir/src/open_module2.c.o

需要显示完整的编译信息，可通过三种方法  
1、CmakeLists.txt设置变量

set(CMAKE_VERBOSE_MAKEFILE ON)

2、cmake执行时通过cmake传参传入变量

-DCMAKE_VERBOSE_MAKEFILE=ON

3、make时添加传参

make VERBOSE=1

执行效果

[3%] Building C object src/lib/TestLib/CMakeFiles/test_lib.dir/src/open_module1.c.o
    cd /home/ghost/test_Makefile/project_cache/src/lib/TestLib && /usr/bin/gcc -Dtest_lib_EXPORTS -I/home/ghost/test_Makefile/src/include -I/home/ghost/test_Makefile/src/lib/TestLib/inc  -O3 -DNDEBUG -fPIC   -D USE_LINUX -o CMakeFiles/test_lib.dir/src/open_module1.c.o   -c /home/ghost/test_Makefile/src/lib/TestLib/src/open_module1.c
    [7%] Building CXX object src/app/AlgorithmTest/CMakeFiles/algorithmTest.dir/src/BinaryTree.cpp.o
    [10%] Building CXX object src/app/AlgorithmTest/CMakeFiles/algorithmTest.dir/src/ClassicalAlgorithm.cpp.o
    cd /home/ghost/test_Makefile/project_cache/src/app/AlgorithmTest && /usr/bin/g++   -I/home/ghost/test_Makefile/src/include -I/home/ghost/test_Makefile/src/app/AlgorithmTest/inc  -std=c++11 -std=c++11 -O3 -DNDEBUG   -D USE_LINUX -o CMakeFiles/algorithmTest.dir/src/BinaryTree.cpp.o -c /home/ghost/test_Makefile/src/app/AlgorithmTest/src/BinaryTree.cpp
    cd /home/ghost/test_Makefile/project_cache/src/app/AlgorithmTest && /usr/bin/g++   -I/home/ghost/test_Makefile/src/include -I/home/ghost/test_Makefile/src/app/AlgorithmTest/inc  -std=c++11 -std=c++11 -O3 -DNDEBUG   -D USE_LINUX -o CMakeFiles/algorithmTest.dir/src/ClassicalAlgorithm.cpp.o -c /home/ghost/test_Makefile/src/app/AlgorithmTest/src/ClassicalAlgorithm.cpp

# 预定义宏：add\_definitions #

在代码中遇到宏定义判断，例如

#ifdef USE_LINUX
    std::cout << "use linux" << std::endl;
    #endif

可在Cmake中传入该定义

if(WIN32)
    message("PC Windows ${CMAKE_BUILD_TYPE}")
    elseif(UNIX)
    message("PC UNIX ${CMAKE_BUILD_TYPE}")
    add_definitions(-D USE_LINUX)	
    endif(WIN32)

此处定义的宏为公共宏，若需要指定目标的宏，需要用到target约束

target_compile_definitions(${PROJECT_APP} 
    	PRIVATE -D DEFINE_TEST)

# 函数：function #

function(<name> [<arg1> ...])
      <commands>
    endfunction()

父目录中定义的函数可以被子目录调用，函数可放在.cmake配置文件中

示例

function (PrintPCName arg1 arg2 arg3)
    		message(STATUS "function ARGC: ${ARGC}")
    		message(STATUS "function ARGV: ${ARGV}")
    		message(STATUS "function ARGV0: ${ARGV0}")
    		message(STATUS "function ARGV1: ${ARGV1}")
    message(STATUS "function ARGV2: ${ARGV2}")
        	message(STATUS "function ARGN: ${ARGN}")
        
        	message(STATUS "System Name : ${CMAKE_SYSTEM_NAME}")
    endfunction()
    
    PrintPCName(1 ${PROJECT_APP} 2 3 4)

执行结果

-- function ARGC: 5
    -- function ARGV: 1;project_app;2;3;4
    -- function ARGV0: 1
    -- function ARGV1: project_app
    -- function ARGV2: 2
    -- function ARGN: 3;4
    -- System Name : Linux

函数参数说明

<table> 
 <thead> 
  <tr> 
   <th>变量名</th> 
   <th>说明</th> 
  </tr> 
 </thead> 
 <tbody> 
  <tr> 
   <td>ARGC</td> 
   <td>参数个数</td> 
  </tr> 
  <tr> 
   <td>ARGV</td> 
   <td>参数列表</td> 
  </tr> 
  <tr> 
   <td>ARGV0</td> 
   <td>参数0</td> 
  </tr> 
  <tr> 
   <td>ARGV1</td> 
   <td>参数1</td> 
  </tr> 
  <tr> 
   <td>ARGV2</td> 
   <td>参数2</td> 
  </tr> 
  <tr> 
   <td>…</td> 
   <td>…</td> 
  </tr> 
  <tr> 
   <td>ARGN</td> 
   <td>超出传参个数多出的参数列表</td> 
  </tr> 
 </tbody> 
</table>

循环获取变量  
示例

function (PrintPCName arg1 arg2 arg3)
        message(STATUS "ARGC : ${ARGC}")
        
        foreach(getValue ${ARGV})
            message(STATUS "argv: ${getValue}")
        endforeach()
    
        message(STATUS "System Name : ${CMAKE_SYSTEM_NAME}")
    
    endfunction()
    
    PrintPCName(1 ${PROJECT_APP} 2 3 4)

执行结果

-- ARGC : 5
    -- argv: 1
    -- argv: project_app
    -- argv: 2
    -- argv: 3
    -- argv: 4
    -- System Name : Linux