74. 面向对象的LotusScript（十六）之Html报表

灰太狼 2022-09-19 12:07 160阅读 0赞

**需求与总体思路**

在[37. 面向对象的LotusScript（九）之导出Excel（一）][37. _LotusScript_Excel]、[38. 面向对象的LotusScript（九）之导出Excel（二）][38. _LotusScript_Excel]到[39. 面向对象的LotusScript（十一）之导出Excel（三）][39. _LotusScript_Excel]几篇文章里，笔者谈了将MS Excel作为目标格式创建报表。虽然大部分情况下这都是不错的选择，也有些时候“报表”用其它格式展现更方便或适宜，包括网页甚至动态的Notes表格。理由可能有很多种，从没有安装Excel软件，想将结果嵌入在Html邮件中，到直接在Notes客户端里展现，不一而足。笔者对网页和Notes表格这两种格式就都使用过。

现在想把网页作为目标格式创建报表的框架整理出来，希望对工作中可能遇上这样需求的或者仅仅是有兴趣的朋友有些帮助。说是整理，其实是按照现在的思路重写，就像考古学家根据文献资料复制历史上的马车盔甲一样，因为当年那些代码都没有保留下来。

为了利用[36. 面向对象的LotusScript（八）之继承][36. _LotusScript]所述的思想，笔者先抽象出一个基本的创建表格的类，之后以Html或Notes富文本域的动态表格为目标的具体实现都继承这个类。

Public Class TableWriter
    	%REM
    		Description: Comments for Function
    	%END REM
    	Public Function WriteHeader(headers As Variant)
    			
    	End Function 
    	
    	%REM
    		Description: Comments for Function
    	%END REM
    	Public Function WriteLine(values As Variant)
    		
    	End Function
    
    	%REM
    		Description: Comments for Function
    	%END REM
    	Public Function EndTable()	
    		
    	End Function	
    
    	%REM
    		Description: Finishes the report and shows it.
    	%END REM
    	Public Function Show()
    
    	End Function
    
    End Class

四个空函数分别是写表格的头，写表格一行，结束表格和结束并显示报表。然后我们来看写HTML表格的类。这样做会遇上两个前置问题，第一个是HTML的转义字符，第二个是HTML文件创建到哪里并且如何自动打开它。

**HTML转义字符**

先看第一个问题，HTML的文本节点里，也就是<>标签之外的内容，需要转义的字符有<、>和&三个，<>标签内需转义的字符有'和"。对这五个字符，可以写出如下的转义函数。

Public Function HtmlEscape(source As String) As String
    	Dim find(4) As String
    	find(0)="&"
    	find(1)=""""
    	find(2)="'"
    	find(3)="<"
    	find(4)=">"
    	Dim replacement(4) As String
    	replacement(0)="&"
    	replacement(1)="""
    	replacement(2)="'"
    	replacement(3)="<"
    	replacement(4)=">"
    	HtmlEscape=Replace(source, find, replacement)
    End Function

**报表文件的位置与自动打开**

第二个问题涉及到两点。HTML文件的保存位置应当是可以由调用的程序指定的，同时也允许不指定而使用默认的位置，比如在Windows的环境下就可采用Temp环境变量设定的路径。文件的名称为了保证唯一性以免新报表覆盖旧报表可以利用当前时间。创建完HTML报表后，有些场合等用户主动去看或者将文件发送出去，譬如作为附件发邮件给某些用户，有些场合适合立即打开给用户看。如何用浏览器打开这些网页呢？LotusScript提供的调用外部进程的Shell函数正好派上用场。可以直接传入IE浏览器的安装路径加上HTML文件路径，如"C:\\Program Files\\Internet Explorer\\iexplore.exe C:\\temp\\report1.html"，如果IE的安装路径不确定，或者想使用系统默认的浏览器，还可以使用Windows的文件管理器进程："explorer.exe C:\\temp\\report1.html"，因为explorer.exe位于Windows的自动搜索位置上，还省去了输入程序所在的路径。

**样例与代码**

我们来看看调用这样一个HTML的表格报表的测试程序和结果。

Sub Initialize
    	Dim htw As New HtmlTableWriter("e:")
    	Dim headers
    	headers=Split("First^Second^Third^Fourth^Fifth^Sixth^Seventh", "^")
    	Call htw.WriteHeader(headers)
    	Dim i As Integer, j As Integer, data(6) As Long 
    	For i=0 To 6
    		For j=0 To 6
    			data(j)=(j+1)*10^i
    		Next
    		Call htw.WriteLine(data)
    	Next
    	Dim characters
    	characters=Split("~!@^#$%^&*(^)_+^<>?^'"";^:,.", "^")
    	Call htw.WriteLine(characters)
    	Call htw.EndTable()
    	Call htw.Show()
    End Sub

在上面的代码里，HTML文件被创建在E:盘符下；表格有七列，分别以First、Second至Seventh作标题；一到七行的数据为循环产生的数字，最后一行写入各种符号测试转义的效果；末尾调用报表的Show()方法即时显示。

![SouthEast][]

*指定文件夹下的多个报表文*

*![SouthEast 1][]*

*一个打开的HTML报表*

最后来看看这个HTML报表类的代码，主要的方法都有注释。

Public Class HtmlTableWriter As TableWriter
    	Private ns As NotesStream
    	Private path As String
     	
    	%REM
    		Description: Create a new html file in the specified folder.
    		The file name consists of the current date and time.
    	%END REM
    	Public Sub New(folder As String )
    		Dim s As New NotesSession
    		Set ns=s.CreateStream()
    		If folder="" Then
    			path=Environ("Temp") & "\"
    		Else
    			Dim tmp
    			tmp=Dir(folder) 'Check if the given directory exists
    			path=folder
    			If Right(path, 1)><"\" Then
    				path=path & "\"
    			End If
    		End If
    		path=path & Format(Today(), "yyyy-mm-dd") & " " & CDbl(Time())*86400
    		path=path & ".html"
    		Call ns.Open(path)
    		
    		Dim html As String
    		html={<!doctype html><HTML><HEAD><meta http-equiv="Content-Type" content="text/html; charset=UTF-8"><TITLE> New Document </TITLE></HEAD><BODY>}
    		Call ns.WriteText(html, 3)
    	End Sub
    	
    	%REM
    		Description: Write the header of the table with the given titles.
    		Params: headers is a variant containing an array of titles.
    	%END REM
    	Public Function WriteHeader(headers As Variant)
    		If Not IsArray(headers) Then Exit Function 
    		Call ns.Writetext("<table border=1 cellspacing=0 style=''><thead><tr>", 3)
    		ForAll h In headers
    			Call ns.Writetext("<th>" & HtmlEscape(CStr(h)) & "</th>", 3)
    		End ForAll
    		Call ns.Writetext("</tr></thead>", 3)
    	End Function
    	
    	%REM
    		Description: Append a line to the table with the given values.
    		Use HtmlEscape() to escape html charaters.
    		Params: values is a variant containing an array of values to be written to the table.
    	%END REM
    	Public Function WriteLine(values As Variant)
    		If Not IsArray(values) Then Exit Function 
    		Call ns.Writetext("<tr>", 3)
    		ForAll v In values
    			Call ns.Writetext("<td>" & HtmlEscape(CStr(v)) & "</td>", 3)
    		End ForAll
    		Call ns.Writetext("</tr>", 3)
    	End Function
    	
    	%REM
    		Description: Closes the table.
    	%END REM
    	Public Function EndTable()
    		Call ns.Writetext("</table>", 3)		
    	End Function
    	
    	%REM
    		Description: Finishes the HTML page that the table resides in.
    		Use Shell() to open the page.
    	%END REM
    	Public Function Show()
    		Call ns.Writetext("</BODY></HTML>")
    		Call ns.Close()
    		Dim result
    		result=Shell("explorer.exe " & path)
    	End Function
    	
    	%REM
    		Description: Append some html snippets to the table.
    	%END REM
    	Public Function WriteHtml(html As String)
    		Call ns.Writetext(html, 3)		
    	End Function
    	
    End Class

**Notes富文本域里的动态表格**

要在Notes文档的富文本域里创建表格来展现报表，可以利用NotesRichTextItem、NotesRichTextNavigator和NotesRichTextTable这些类的方法，基本过程是在NotesRichTextItem内创建一个NotesRichTextTable，用这个NotesRichTextTable来动态添加新行，再用NotesRichTextNavigator依次定位到某个单元格，然后调用NotesRichTextItem.AppendText()写入值。很明显，这个表格API笨拙，实际运行速度也不快。优点在于不需要第三方软件，完全在Lotus Notes平台内完成；报表可以很方便地以文档的形式保存。读者朋友如有兴趣或者实际真有需求，可以采纳这种方法。因为和HtmlTableWriter同样继承自TableWriter，公共方法都相同，调用方可以声明TableWriter的变量，依需求创建特定的子类，之后在调用方法上都没有区别。

[37. _LotusScript_Excel]: http://blog.csdn.net/starrow/article/details/9263977
[38. _LotusScript_Excel]: http://blog.csdn.net/starrow/article/details/9274711
[39. _LotusScript_Excel]: http://blog.csdn.net/starrow/article/details/9315235
[36. _LotusScript]: http://blog.csdn.net/starrow/article/details/9257527
[SouthEast]: /images/20220828/02ca3621625b4829a739689cc1de2091.png
[SouthEast 1]: /images/20220828/4f745699570a462585e0255e5a889bba.png