用AspJpeg组件，按宽高比例，真正生成缩略图

Love The Way You Lie 2022-09-18 05:51 166阅读 0赞

在网站前台产品展示时，一般用缩略图，点击进入然后看到大图。  
缩略图带来了两个烦劳：  
1.如果后台只传一张大图，显示缩略图时只是将大图固定宽度和高度，这样不但造成缩略图变形，而且使得页面访问速度缓慢。  
2.如果后台每次上传时，都上传两张图片，一张大图，一张缩略图。这样的话，没有1中的问题，但是给后台人员造成很大麻烦。因为后台人员并不一定知道处理生成缩略图；即使知道并能快速处理，也浪费掉一些时间。

下面的代码可以帮您用AspJpeg组件，按宽高比例，真正生成缩略图  
AspJpeg组件下载：[http://www.aspjpeg.com/download.html][http_www.aspjpeg.com_download.html]  
AspJpeg组件使用：[http://www.mydw.cn/tech/1/766.html][http_www.mydw.cn_tech_1_766.html]  
<%  
Dim sOriginalPath  
sOriginalPath = "images/1.gif"  
'原图片路径一般上传完毕后获取，或者从[数据库][Link 1]获取

Dim sReturnInfo, sSmallPath '函数返回信息, 缩略图路径  
sReturnInfo = BuildSmallPic(sOriginalPath, "images", 100, 100)

Response.Write "返回信息:" & sReturnInfo & "<br/>"  
If InStr(sReturnInfo, "Error\_") <= 0 Then  
    sSmallPath = sReturnInfo '返回信息就是  
    '将sSmallPath写入数据库  
    '  
Else  
    Response.Write "详细错误:"  
    Select Case sReturnInfo  
    Case "Error\_01"  
        Response.Write "<font color='red'>创建AspJpeg组件失败,没有正确安装注册该组件</font>" & "<br/>"  
    Case "Error\_02"  
        Response.Write "<font color='red'>原图片不存在,检查s\_OriginalPath参数传入值</font>" & "<br/>"  
    Case "Error\_03"     
        Response.Write "<font color='red'>缩略图存盘失败.可能原因:缩略图保存基地址不存在,检查s\_OriginalPath参数传入值;对目录没有写权限;磁盘空间不足</font>" & "<br/>"  
    Case "Error\_Other"  
        Response.Write "<font color='red'>未知错误</font>" & "<br/>"  
    End Select  
    Response.End  
End If

%>  
原文件名：<%=sOriginalPath%><br/>  
缩略图文件名：<%=sSmallPath%><br/>  
原图片：<img src='<%=sOriginalPath%>' border=0><br/><br/>  
缩略图：<img src='<%=sSmallPath%>' border=0>

<%  
'================================================================  
'Author：laifangsong QQ:25313644  
'功能：按照指定图片生成缩略图  
'注意：以下提到的“路径”都是值相对于调用本函数的文件的相对路径  
'参数：  
'    s\_OriginalPath:        原图片路径 例:images/image1.gif  
'    s\_BuildBasePath:    生成图片的基路径,不论是否以“/”结尾均可 例:images或images/  
'    n\_MaxWidth:            生成图片最大宽度  
'                        如果在前台显示的缩略图是 100\*100,这里 n\_MaxWidth=100,n\_MaxHeight=100.  
'    n\_MaxHeight:        生成图片最大高度  
'返回值：  
'    返回生成后的缩略图的路径  
'错误处理：  
'    如果函数执行过程中出现错误,将返回错误代码,错误代码以 “Error”开头  
'        Error\_01:创建AspJpeg组件失败,没有正确安装注册该组件  
'        Error\_02:原图片不存在,检查s\_OriginalPath参数传入值  
'        Error\_03:缩略图存盘失败.可能原因:缩略图保存基地址不存在,检查s\_OriginalPath参数传入值;对目录没有写权限;磁盘空间不足  
'        Error\_Other:未知错误  
'调用例子:  
'    Dim sSmallPath '缩略图路径  
'    sSmallPath = BuildSmallPic("images/image1.gif", "images", 100, 100)     
'================================================================  
Function BuildSmallPic(s\_OriginalPath, s\_BuildBasePath, n\_MaxWidth, n\_MaxHeight)  
    Err.Clear  
    On Error Resume Next  
     
    '检查组件是否已经注册  
    Dim AspJpeg  
    Set AspJpeg = Server.Createobject("Persits.Jpeg")  
    If Err.Number <> 0 Then  
        Err.Clear  
        BuildSmallPic = "Error\_01"  
        Exit Function  
    End If

'检查原图片是否存在  
    Dim s\_MapOriginalPath  
    s\_MapOriginalPath = Server.MapPath(s\_OriginalPath)  
    AspJpeg.Open s\_MapOriginalPath '打开原图片  
    If Err.Number <> 0 Then  
        Err.Clear  
        BuildSmallPic = "Error\_02"  
        Exit Function  
    End If

'按比例取得缩略图宽度和高度  
    Dim n\_OriginalWidth, n\_OriginalHeight '原图片宽度、高度  
    Dim n\_BuildWidth, n\_BuildHeight '缩略图宽度、高度  
    Dim div1, div2  
    Dim n1, n2  
    n\_OriginalWidth = AspJpeg.Width  
    n\_OriginalHeight = AspJpeg.Height  
    div1 = n\_OriginalWidth / n\_OriginalHeight  
    div2 = n\_OriginalHeight / n\_OriginalWidth  
    n1 = 0  
    n2 = 0  
    If n\_OriginalWidth > n\_MaxWidth Then  
        n1 = n\_OriginalWidth / n\_MaxWidth  
    Else  
        n\_BuildWidth = n\_OriginalWidth  
    End If  
    If n\_OriginalHeight > n\_MaxHeight Then  
        n2 = n\_OriginalHeight / n\_MaxHeight  
    Else  
        n\_BuildHeight = n\_OriginalHeight  
    End If  
    If n1 <> 0 Or n2 <> 0 Then  
        If n1 > n2 Then  
            n\_BuildWidth = n\_MaxWidth  
            n\_BuildHeight = n\_MaxWidth \* div2  
        Else  
            n\_BuildWidth = n\_MaxHeight \* div1  
            n\_BuildHeight = n\_MaxHeight  
        End If  
    End If

'指定宽度和高度生成  
    AspJpeg.Width = n\_BuildWidth  
    AspJpeg.Height = n\_BuildHeight  
     
    '--将缩略图存盘开始--  
    Dim pos, s\_OriginalFileName, s\_OriginalFileExt '位置、原文件名、原文件扩展名  
    pos = InStrRev(s\_OriginalPath, "/") + 1  
    s\_OriginalFileName = Mid(s\_OriginalPath, pos)  
    pos = InStrRev(s\_OriginalFileName, ".")  
    s\_OriginalFileExt = Mid(s\_OriginalFileName, pos)

Dim s\_MapBuildBasePath, s\_MapBuildPath, s\_BuildFileName '缩略图绝对路径、缩略图文件名  
    Dim s\_EndFlag '小图片文件名结尾标识 例: 如果大图片文件名是“image1.gif”,结尾标识是“\_small”,那么小图片文件名就是“image1\_small.gif”  
    If Right(s\_BuildBasePath, 1) <> "/" Then s\_BuildBasePath = s\_BuildBasePath & "/"  
    s\_MapBuildBasePath = Server.MapPath(s\_BuildBasePath)  
    s\_EndFlag = "\_small" '可以自定义,只要能区别大小图片即可  
    s\_BuildFileName = Replace(s\_OriginalFileName, s\_OriginalFileExt, "") & s\_EndFlag & s\_OriginalFileExt  
    s\_MapBuildPath = s\_MapBuildBasePath & "/" & s\_BuildFileName  
     
    AspJpeg.Save s\_MapBuildPath '保存  
    If Err.Number <> 0 Then  
        Err.Clear  
        BuildSmallPic = "Error\_03"  
        Exit Function  
    End If  
    '--将缩略图存盘结束--

'注销实例  
    Set AspJpeg = Nothing  
    If Err.Number <> 0 Then  
        BuildSmallPic = "Error\_Other"  
        Err.Clear  
    End If  
    BuildSmallPic = s\_BuildBasePath & s\_BuildFileName  
End Function

转自：动态网站制作指南 | www.knowsky.com

from

**其他文章：**

[用ASPJPEG组件制作图片的缩略图和加水印][ASPJPEG]

[在VC中使用 Flash 美化你的程序][VC_ Flash]

[获得WebBrowser控件中的HTML源码][WebBrowser_HTML]

[使用IE控件的一些有趣方法][IE]

[为Pocket PC上的IE创建ActiveX控件][Pocket PC_IE_ActiveX]

[ASP服务器端组件编程实例1][ASP_1]

[aspjpeg组件高级使用方法介绍][aspjpeg]

[http_www.aspjpeg.com_download.html]: http://www.aspjpeg.com/download.html
[http_www.mydw.cn_tech_1_766.html]: http://www.mydw.cn/tech/1/766.html
[Link 1]: http://www.knowsky.com/sql.asp
[ASPJPEG]: http://blog.csdn.net/suprman/archive/2007/01/05/1474628.aspx
[VC_ Flash]: http://blog.csdn.net/suprman/archive/2007/01/04/1473607.aspx
[WebBrowser_HTML]: http://blog.csdn.net/suprman/archive/2007/01/04/1473579.aspx
[IE]: http://blog.csdn.net/suprman/archive/2007/01/04/1473582.aspx
[Pocket PC_IE_ActiveX]: http://blog.csdn.net/suprman/archive/2007/01/04/1473575.aspx
[ASP_1]: http://blog.csdn.net/suprman/archive/2006/10/23/1346201.aspx
[aspjpeg]: http://blog.csdn.net/suprman/archive/2007/01/05/1474632.aspx