Lingo中集与数据的设置

淡淡的烟草味﹌ 2022-08-20 07:21 139阅读 0赞

1.什么是集  
集是一群相联系的对象，这些对象也称为集的成员。一个集可能是一系列产品、卡车或雇员。每个集成员可能有一个或多个与之有关联的特征，我们把这些特征称为属性。属性值可以预先给定，也可以是未知的，有待于 LINGO 求解。例如，产品集中的每个产品可以有一个价格属性；卡车集中的每辆卡车可以有一个牵引力属性；雇员集中的每位雇员可以有一个薪水属性，也可以有一个生日属性等等。  
LINGO中的集分为两种，原始集和派生集，原始集由一些基本的对象组成，派生集是由一个或多个原始集定义的。

2.定义集的方式  
集部分以关键词“sets：”开始，以“endsets”结束，一个模型可以没有集部分或只有一个简单的集部分。  
定义原始集：  
包含三个内容：集的名字，集的成员，集的属性。其语法为：setname\[/member\_list/\]\[:attribute\_list\];其中setname是集的名字，member\_list是集成员列表，attribute\_list是集成员的属性列表。对于集成员列表，涉及到罗列方式的问题：若是显式罗列，必须逐个列出成员，中间以逗号或空格隔开，允许混合使用；若是隐式罗列，可采用相应语法：setname/member1..memberN/\[: attribute\_list\];member1是第一个成员名，memberN是最末一个成员名，LINGO将自动产生中间的所有成员名，示例程序如下：

sets:
    warehouses/wh1..wh6/:capacity;
    vendors/v1..v8/:demand;
    endsets

定义派生集：  
包含四个内容：集的名字，**父集的名字**，集的成员，集的属性。其语法为：setname(parent\_set\_list)\[/member\_list/\]\[:attribute\_list\];其中parent\_set\_list是已定义的集的列表，多个时可用逗号隔开。其余内容与初始集基本类似，示例程序如下：

sets:
    product/A B/;
    machine/M N/;
    week/1..2/;
    allowed(product,machine,week):x;
    endsets

3.过滤器  
LINGO中用竖线（|）来标记过滤条件，竖线后接着过滤条件，在定义集中的作用一般是定义稀疏集，用在模型部分则大多是为了设置约束条件，示例程序如下：

sets:
    !学生集：性别属性 sex，1 表示男性， 0 表示女性；年龄属性 age ;
    students/John,Jill,Rose,Mike/:sex,age;
    !男学生和女学生的联系集：友好程度属性 friend，[0，1]之间的数;
    linkmf(students,students)|sex(&1) #eq# 1 #and# sex(&2) #eq# 0: friend;
    !男学生和女学生的友好程度大于 0.5 的集;
    linkmf2(linkmf) | friend(&1,&2) #ge# 0.5 : x;
    endsets
    data:
    sex,age = 1 16
    0 14
    0 17
    0 13;
    friend = 0.3 0.5 0.6;
    enddata

4.模型的数据部分  
数据部分以关键字“data:”开始，以关键字“enddata”结束。其语法为：object\_list = value\_list;其中object\_list为对象列，value\_list为数值列，两种赋值方式程序如下：

sets:
    set1/A,B,C/: X,Y;
    endsets
    data:
    X=1,2,3;
    Y=4,5,6;
    enddata

sets:
    set1/A,B,C/: X,Y;
    endsets
    data:
    X,Y=1 4
    2 5
    3 6;
    enddata

此外，这部分还可以设定某些标量参数的值：

data:
    interest_rate = .085;
    enddata

进行实时数据处理：

data:
    interest_rate,inflation_rate = .085 ?;
    enddata

指定属性为一个值：

sets:
    days /MO,TU,WE,TH,FR,SA,SU/:needs,cost;
    endsets
    data:
    needs cost = 20 100;
    enddata

指定属性中的部分值，让其余的未知，以便让LINGO求出它们的最优值，在数据声明中输入两个相连的逗号表示该位置对应的集成员的属性值未知，两个逗号间可以有空格。

sets:
    years/1..5/: capacity;
    endsets
    data:
    capacity = ,34,20,,;
    enddata
    ！属性 capacity 的第 2 个和第 3 个值分别为 34 和 20，其余的未知。

5.模型的初始部分：  
初始部分是 LINGO 提供的另一个可选部分。在初始部分中，可以输入初始声明（initialization statement），和数据部分中的数据声明相同。对实际问题的建模时，初始部分并不起到描述模型的作用，在初始部分输入的值仅被 LINGO 求解器当作初始点来用，并且仅仅对非线性模型有用。

init:
    X, Y = 0, .1;
    endinit
    Y=@log(X);
    X^2+Y^2<=1;

好的初始点会减少模型的求解时间。