51单片机汇编编程：BCD 码与 BIN 数据的转换程序

布满荆棘的人生 2022-08-20 01:21 449阅读 0赞

把二进制数转换成 BCD 码，是很常见的，做而论道以前也发表过这样的程序。

但是，过去都是用寄存器，如果要求用片内RAM单元，就少见了。

当然，也可以把片内RAM单元的数据，先传送到寄存器，再利用以前写的程序进行转换。转换完毕后，再把结果传送到片内RAM单元。

如果直接用片内RAM单元来进行转换呢？

这也是可以的，只是速度会慢一些。

以前，从来没有见过有谁编写出来直接使用片内RAM转换的程序。

没有人编写，大概就是速度的原因吧。

做而论道现在就编写一个，大家看看，和使用寄存器相比，速度有多少降低。

下面就是这样的题目。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

编写一段程序，将存放于片内RAM 40H、41H单元中的 16 位二进制数转化为压缩BCD码存放到 38H~3AH 中。

题目链接：[http://zhidao.baidu.com/question/2009741878589616028.html][http_zhidao.baidu.com_question_2009741878589616028.html]

做而论道的回答如下：

;

TO\_BCD:

MOV   R2, \#16     ;转换16位

CLR   A

MOV   38H, A      ;先清零

MOV   39H, A

MOV   3AH, A

LOOP:

MOV   A, 41H      ;取被转换二进制数

RLC   A

MOV   41H, A

MOV   A, 40H

RLC   A           ;最高位移动到C

MOV   40H, A

;---------------------

MOV   A, 3AH      ;取数

ADDC  A, 3AH      ;左移并加上C

DA    A           ;转为BCD码

MOV   3AH, A      ;保存

MOV   A, 39H

ADDC  A, 39H

DA    A

MOV   39H, A

MOV   A, 38H

ADDC  A, 38H

MOV   38H, A

DJNZ  R2, LOOP    ;循环16次

RET

本程序已经经过试验，保证正确。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

下面，是另外一个问题，问的就是相反转换的问题。

这样的程序，做而论道以前就编写出来，并且使用过很多年了。

只是在网上、书上，从来也没有见过这样的转换程序。

－－－－

编写一段程序，将存放于片内 RAM 30H~32H 单元中的5位压缩BCD数(小于65536)转化为二进制数存放到 40H、41H 单元中。

题目链接：[http://zhidao.baidu.com/question/1238025267333028579.html][http_zhidao.baidu.com_question_1238025267333028579.html]

做而论道的回答如下：

TO\_BIN:

MOV   A, 32H

SWAP  A

ANL   A, \#0FH     ;得到十位数字

MOV   B, \#10

MUL   AB

MOV   B, 32H

ANL   B, \#0FH     ;得到个位数字

ADD   A, B

MOV   41H, A      ;(41H)=十位\*10+个位

;---------------------

MOV   A, 31H

SWAP  A

ANL   A, \#0FH     ;得到千位数字

MOV   B, \#10

MUL   AB

MOV   B, 31H

ANL   B, \#0FH     ;得到百位数字

ADD   A, B        ;(A)=千位\*10+百位

MOV   B, \#100

MUL   AB          ;(B A)=千位\*1000+百位\*100

;---------------------

ADD   A, 41H

MOV   41H, A

CLR   A

ADDC  A, B

MOV   40H, A  ;(40H 41H)=千位\*1000+百位\*100+十位\*10+个位

;---------------------

MOV   A, \#10H     ;2710H=1万

MOV   B, 30H      ;万位

MUL   AB

MOV   R2, B

MOV   R3, A

MOV   A, \#27H

MOV   B, 30H      ;万位

MUL   AB

ADD   A, R2

MOV   R2, A       ;R2 R3=万位\*10000

;---------------------

MOV   A, R3

ADD   A, 41H

MOV   41H, A

MOV   A, R2

ADDC  A, 40H

MOV   40H, A

RET

本程序已经通过了试验验证，保证正确。

后记：

**针对这个问题，提问者采纳了一个错误的程序。**

这个错误程序，不仅有错，长度还差不多达到本程序的两倍。

做而论道编写的程序，不仅正确，基本上就是最精简的，大家可以比较看一下。

其实，做而论道还有更为精简的，仅仅才 35 行指令，可以说是世上最精练转换程序。只是技巧太高，不易理解，就不公布了。

用 C 语言编程，不太合乎题目的要求。

但是，也有人编写的很好，收录在下面：

viod BcdHex(viod)

unsigned short int \*OutAdd, \*SrcAdd, x;

SrcAdd = 0x30;

OutAdd = 0x40;

\*OutAdd = 0;    x = 1;

\*OutAdd += (SrcAdd\[0\] & 0x0F) \* x; x \*= 10;

\*OutAdd += (SrcAdd\[0\]  >>  4) \* x; x \*= 10;

\*OutAdd += (SrcAdd\[1\] & 0x0F) \* x; x \*= 10;

\*OutAdd += (SrcAdd\[1\]  >>  4) \* x; x \*= 10;

\*OutAdd += (SrcAdd\[2\] & 0x0F) \* x;

[http_zhidao.baidu.com_question_2009741878589616028.html]: http://zhidao.baidu.com/question/2009741878589616028.html
[http_zhidao.baidu.com_question_1238025267333028579.html]: http://zhidao.baidu.com/question/1238025267333028579.html

51单片机汇编编程：BCD 码与 BIN 数据的转换程序

发表评论取消回复

还没有评论，来说两句吧...

相关阅读

相关 BIN,BCD,ASCII码的区别

相关 BCD码与十六进制值转换

相关 BCD 码与 unsigned char 转换

相关 51单片机汇编编程－－16位拉幕灯

相关 51单片机汇编编程：BCD 码与 BIN 数据的转换程序

相关 51 单片机汇编编程：记录按键

相关 51 汇编编程：一种单片机抢答器

相关数字电路：设计《BIN 到 BCD 码的转换电路》

相关 C51单片机的压缩BCD码相加程序

相关 BCD码与10进制转换