基于 8086 汇编语言——减奇数法开平方

「爱情、让人受尽委屈。」 2022-08-20 01:10 187阅读 0赞

用减奇数法，可以求近似平方根。

例如：求根号S，就从 S 逐次减去1、3、5、7、.......，直到 S 不够减下一个应减的奇数为止；  
然后统计奇数的个数，这个数就是 S 的近似平方根。

那位大侠能给个汇编程序啊，感激不尽！  
;============================================  
最佳答案：

;程序如下：  
;-------------------------------------------  
DATA SEGMENT  
   NUM   DW  12345    ;被开方数：0~65535  
   MES\_I DB  ', SRQT is : $  ' ;用于提示.  
DATA ENDS  
;-------------------------------------------  
CODE SEGMENT  
      ASSUME  CS:CODE, DS:DATA  
START:  
      MOV  AX, DATA  
      MOV  DS, AX  
;------------------  
      MOV  AX, NUM    ;被开方数  
      CALL DISP\_AX    ;显示  
;------------------下面求平方根  
      MOV  BX, -1  
      MOV  CX, -1  
LLL:  
      ADD  BX, 2      ;奇数  
      INC  CX         ;根加一  
      SUB  AX, BX     ;减奇数  
      JNB  LLL        ;够减就继续减  
;------------------------------  
      MOV  DX, OFFSET MES\_I  
      MOV  AH, 9      ;9号功能调用，显示提示.  
      INT  21H  
;------------------  
      MOV  AX, CX     ;平方根  
      CALL DISP\_AX    ;显示  
;------------------  
EXIT:  
      MOV  AH, 4CH    ;结束程序  
      INT  21H  
;------------------------------  
DISP\_AX:  
      PUSH AX  
      PUSH BX  
      PUSH CX  
      PUSH DX  
;------------------  
      MOV  BX, 10  
      MOV  CX, 0  
DIS0:  
      MOV  DX, 0  
      DIV  BX  
      ADD  DL, 30H  
      PUSH DX  
      INC  CX  
      AND  AX, AX  
      JZ   DIS1  
      JMP  DIS0  
DIS1:  
      MOV  AH, 2  
      POP  DX  
      INT  21H  
      LOOP DIS1  
;------------------  
      POP  DX  
      POP  CX  
      POP  BX  
      POP  AX  
      RET  
;------------------------------  
CODE  ENDS  
      END  START  
;============================================  
本程序运行的结果如下：

C:\\MASM>SRQT\_1

12345, SRQT is : 111

C:\\MASM>  
;============================================  
回答者： 做而论道 | 十五级　采纳率：42% 名人 达人  
提问者对回答的评价：谢谢！  
原题网址：[http://zhidao.baidu.com/question/344233720.html][http_zhidao.baidu.com_question_344233720.html]  
;============================================

后记：

提问者已经给出了一个开方程序，但是能处理数据的仅有 8 位，且不能显示。

本文给出的程序中的被开方数，是 16 位二进制数。  
是按照题目要求，被开方数是写在程序中的，如果希望用键盘现场输入，可以参考做而论道其它的博文。

本文给出的显示程序，稍加修改就按照常用的进制显示数据。具有相当广泛的通用性。

;============================================

[http_zhidao.baidu.com_question_344233720.html]: http://zhidao.baidu.com/question/344233720.html