单片机89S51，4×4矩阵键盘，控制16个发光二极管

今天药忘吃喽~ 2022-08-19 15:26 147阅读 0赞

用单片机89S51，4×4矩阵键盘，控制16个发光二极管，程序有点错误哪位高手给指点一下。  
我所做的矩阵键盘控制的发光二极管只有8个亮8个不亮，和P2口连接的亮和P0口连接的不亮，高手给点意见。  
悬赏分：15                     2010-7-20 20:02  
===========================================================  
回答：

下列程序已经经过了 PROTEUS 验证，可以满足题目要求。

;----------------------------------------------------------  
       ORG  0000H  
START:  
       MOV  P0, \#0        ;显示初始化  
       MOV  P2, \#0        ;全亮  
;----------------------------------------------------------  
M\_LOOP:  
       CALL KEY\_SCAN  
       JB   ACC.4, M\_LOOP ;A=16, 就是没有按下键  
       CALL DISPLAY  
       SJMP M\_LOOP  
;----------------------------------------------------------  
KEY\_SCAN:                 ;用反转法扫描键盘  
       PUSH B  
       CLR  A             ;将用A保存按键信息  
       MOV  P3, \#0FH      ;列线置低电平,行线置高电平  
       MOV  B, P3  
       JNB  B.0, L\_J0     ;逐行扫描  
       JNB  B.1, L\_J1  
       JNB  B.2, L\_J2  
       JNB  B.3, L\_J3  
       MOV  A, \#16        ;没有按键，A=16  
       SJMP KEY\_END  
;------------------------------  
L\_J3:  INC  ACC           ;加行值  
L\_J2:  INC  ACC  
L\_J1:  INC  ACC  
L\_J0:  RL   A             ;行号×4  
       RL   A  
;------------------------------  
       MOV  P3, \#0F0H     ;行线列线电平互换  
       MOV  B, P3  
       JNB  B.4, R\_J0     ;逐列扫描  
       JNB  B.5, R\_J1  
       JNB  B.6, R\_J2  
       JNB  B.7, R\_J3  
       MOV  A, \#16  
       SJMP KEY\_END  
;------------------------------  
R\_J3:  INC  ACC           ;加列值  
R\_J2:  INC  ACC  
R\_J1:  INC  ACC  
R\_J0:                     ;A=0~F  
KEY\_END:  
       POP B  
       RET         
;----------------------------------------------------------  
DISPLAY:  
       MOV  P1, A         ;输出到数码显示器  
       RL   A             ;乘以2，因为每个键值要显示两个字节  
       MOV  B,  A         ;保存  
       MOV  DPTR, \#TABLE1 ;显示码表首地址  
       MOVC A, @A+DPTR    ;根据键值查显示码  
       MOV  P2, A         ;输出显示  
       MOV  A, B  
       INC  A             ;准备查第二字节  
       MOVC A, @A+DPTR    ;根据键值查显示码  
       MOV  P0, A  
       RET  
;----------------------------------------------------------  
TABLE1:  
       DB 00H, 01H, 00H, 02H, 00H, 04H, 00H, 08H  
       DB 00H, 10H, 00H, 20H, 00H, 40H, 00H, 80H  
       DB 01H, 00H, 02H, 00H, 04H, 00H, 08H, 00H  
       DB 10H, 00H, 20H, 00H, 40H, 00H, 80H, 00H  
END  
;----------------------------------------------------------  
用PROTEUS仿真图像如下：

![单片机89S51，4×4矩阵键盘，控制16个发光二极管 - 非著名博主 - 电子信息角落][89S51_4_4_16_ - _ -]

图片链接：[http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/88bfff32924082b91b4cff43.html][http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_88bfff32924082b91b4cff43.html]

原题网址：[http://zhidao.baidu.com/question/168457229.html][http_zhidao.baidu.com_question_168457229.html]

[89S51_4_4_16_ - _ -]: /images/20220731/9c91130421874ac09cff786f5d79c9d9.png
[http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_88bfff32924082b91b4cff43.html]: http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/88bfff32924082b91b4cff43.html
[http_zhidao.baidu.com_question_168457229.html]: http://zhidao.baidu.com/question/168457229.html