MCS-51单片机中断测试系统设计

港控/mmm° 2022-08-19 15:25 249阅读 0赞

;========================================================  
;设计要求  
;  
;1、硬件设计要求  
;使用AT89C51单片机，时钟12MHz，设计时钟电路和上电复位电路，  
;P0口、P1口、P2口分别驱动3个LED七段数码管显示器，  
;P3口的外部中断0和外部中断1分别连接按键K1和按键K2。  
;  
;2、软件设计要求  
;从0000H单元地址开始编制主程序；  
;1秒钟定时由单片机内部定时器完成，定时器0完成50毫秒定时，定时器1完成20的计数。  
;软件要在Proteus仿真环境下可以运行，并实现下列的功能要求。  
;正常状态下，第一个数码显示器每隔1秒循环显示0到9数字；  
;当按键K1按下时，产生中断，第二个数码显示器每隔1秒分别显示0到9数字后，返回到第一个数码显示器继续每隔1秒循环显示0到9数字；  
;当按键K2按下时，可以中断前面的显示程序，第三个数码管显示器每隔1秒分别显示0到9数字后，返回中断前状态继续运行。  
;  
;悬赏分：100 - 解决时间：2010-7-5 21:39  
;========================================================  
;从题目中要求出现的现象来看，很明显是要求反映出两个开关按下时，中断程序和主程序之间的优先级别的关系。  
;51单片机只有两个中断优先级，应该把它们设置给外部中断X1和X0，其它中断源如T1和T0，只能采用查询方式。  
;原要求用T1计数20次，本程序对此进行了简化，在软件查询T0定时期间，用软件计数，效果相同。  
;程序如下：  
;----------------------------------------------  
        ORG   0000H  
        SJMP START  
        ORG   0003H  
        LJMP X0\_INT          ;转到X0中断入口  
        ORG   0013H  
        LJMP X1\_INT          ;转到X1中断入口  
;----------------------------------------------  
START:  
        MOV   TMOD, \#01H      ;T0定时方式1  
        MOV   TH0, \#HIGH(65536 - 50000) ;定时  
        MOV   TL0, \#LOW(65536 - 50000) ;定时50ms  
        SETB TR0  
        SETB IT0             ;下降沿触发外部中断  
        SETB IT1  
        MOV   SP, \#60H  
        MOV   IE, \#10000101B ;只是允许X1,X0申请中断  
        MOV   IP, \#00000100B  
        MOV   30H, \#0  
        MOV   31H, \#0  
        MOV   32H, \#0  
MOV   33H, \#20  
        MOV   P0, \#0C0H      ;数码管显示0  
        MOV   P1, \#0C0H      ;显示0  
        MOV   P2, \#0C0H      ;显示0  
;----------------------------------------------  
M\_LOOP:  
        MOV   A, 30H         ;主程序显示0~9的计数单元  
        MOV   DPTR, \#NUMTAB   ;指定查表地址  
        MOVC A, @A+DPTR     ;查七段码  
        MOV   P0, A          ;送出去显示  
        CALL WAIT1S          ;等上1秒钟  
        MOV   A, 30H  
        ADD   A, \#1  
        DA    A  
        ANL   A, \#0FH  
        MOV   30H, A  
        SJMP M\_LOOP          ;无限循环  
;----------------------------------------------  
X0\_INT:  
        PUSH ACC             ;保护现场  
        PUSH PSW  
        SETB RS0             ;换工作区1  
        MOV   31H, \#0         ;T0中断程序显示0~9的计数单元  
X0\_LOOP:  
        MOV   A, 31H          ;取来T0的计数值  
        MOV   DPTR, \#NUMTAB   ;指定查表地址  
        MOVC A, @A+DPTR     ;查七段码  
        MOV   P2, A          ;送出去显示  
        CALL WAIT1S          ;等上1秒钟  
        MOV   A, 31H  
        ADD   A, \#1  
        DA    A  
        ANL   A, \#0FH  
        MOV   31H, A  
        JNZ   X0\_LOOP         ;不为0，就循环  
        MOV   P2, \#0C0H  
        POP   PSW  
        POP   ACC             ;恢复现场  
        RETI  
;----------------------------------------------  
X1\_INT:  
        PUSH ACC             ;保护现场  
        PUSH PSW  
        SETB RS0             ;换工作区1  
        SETB RS1             ;换工作区3  
        MOV   32H, \#0         ;T1中断程序显示0~9的计数单元  
X1\_LOOP:  
        MOV   A, 32H          ;取来T1的计数值  
        MOV   DPTR, \#NUMTAB   ;指定查表地址  
        MOVC A, @A+DPTR     ;查七段码  
        MOV   P1, A          ;送出去显示  
        CALL WAIT1S          ;等上1秒钟  
        MOV   A, 32H  
        ADD   A, \#1  
        DA    A  
        ANL   A, \#0FH  
        MOV   32H, A  
        JNZ   X1\_LOOP         ;不为0，就循环  
        MOV   P1, \#0C0H  
        POP   PSW  
        POP   ACC             ;恢复现场  
        RETI  
;----------------------------------------------  
NUMTAB:  
        DB    0C0H, 0F9H, 0A4H, 0B0H, 099H  
        DB    092H, 082H, 0F8H, 080H, 090H  
;----------------------------------------------  
WAIT1S:  
        JNB   TF0, $          ;等待50ms  
        MOV   TL0, \#LOW(65536 - 50000) ;定时50ms  
        MOV   TH0, \#HIGH(65536 - 50000) ;定时50ms  
        CLR   TF0  
        DJNZ 33H, WAIT1S     ;继续等待20次  
        MOV   33H, \#20        ;终于等到了1s  
        RET  
;----------------------------------------------  
END  
;----------------------------------------------  
;程序用PROTEUS运行，屏幕截图如下：

![MCS-51单片机中断测试系统设计 - 非著名博主 - 电子信息角落][MCS-51_ - _ -]  
;图片链接：[http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/f80a5e6f634f1ce580cb4ac8.html][http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_f80a5e6f634f1ce580cb4ac8.html]  
;回答者： 做而论道 - 十三级   2010-7-4 19:53  
;==================================================================  
;原题网址：[http://z.baidu.com/question/164654990.html][http_z.baidu.com_question_164654990.html]

[MCS-51_ - _ -]: /images/20220731/4cb2d3a50b6a4424a3a49726f4e653e5.png
[http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_f80a5e6f634f1ce580cb4ac8.html]: http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/f80a5e6f634f1ce580cb4ac8.html
[http_z.baidu.com_question_164654990.html]: http://z.baidu.com/question/164654990.html