使用汇编语言编写程序，设计一个用8051单片机控制的循环彩灯控制系统

清疚 2022-08-19 15:24 170阅读 0赞

使用汇编语言编写程序，设计一个用8051单片机控制的循环彩灯控制系统  
要求：  
1、能输出4种花型，并能由人工进行花型的切换。可以使用按键，也可以使用拨动开关来实现切换，方法不限。  
2、循环彩灯的循环速度可调。  
3、按键要求：  
（1）启动/暂停。按动一次启动，再按一次暂停。是一个双态转换键。  
（2）花型变化。按一次，立即停止当前花型的显示，转换为下一种花型。4种花型可以循环切换。  
（3）速度+。按键一次，速度略加快一点。  
（4）速度-。按键一次，速度略减慢一点。  
4、在LED显示器上显示相应的花型号。

悬赏分：30 - 离问题结束还有 14 天 21 小时  
;==============================================================  
上次编写了一个“键控流水灯”，后来不断有网友来电，希望再编写些其它花样的。  
做而论道也有了一些设想，正巧有这位网友提出的要求，和做而论道的构思暗合，故此连夜调出个程序，也算是答题吧。  
用PROTEUS仿真的画面如下：

![使用汇编语言编写程序，设计一个用8051单片机控制的循环彩灯控制系统 - 非著名博主 - 电子信息角落][8051_ - _ -]  
  
图片链接：[http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/91d1fff221a004f50b46e0ef.html][http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_91d1fff221a004f50b46e0ef.html]  
;---------------------------------------------------  
控制程序如下：

ORG 0000H  
    JMP START  
    ORG 0003H  
    JMP X0\_INT  
    ORG 000BH  
    JMP T0\_INT  
    ORG 0013H  
    JMP X1\_INT  
;---------------------------------  
START:  
    MOV TMOD, \#51H       ;/\*01010001 T1计数,T0定时\*/  
    MOV TH0, \#HIGH(65536 - 50000) ;50ms@12MHz  
    MOV TL0, \#LOW (65536 - 50000)  
    MOV TH1, \#0  
    MOV TL1, \#0  
    SETB TR0  
    SETB TR1  
    SETB IT0  
    SETB IT1  
    MOV IE, \#10000111B  
    MOV IP, \#00000101B

MOV R7, \#20  
    MOV 30H, \#20  
    MOV 31H, \#0  
    MOV 32H, \#0

MOV P2, 31H  
    INC P2

SJMP $  
;---------------------------------  
T0\_INT:          ;50ms执行一次  
    MOV TL0, \#LOW (65536 - 50000) ;重新写入初始值  
    MOV TH0, \#HIGH(65536 - 50000) ;50ms@12MHz  
;------------------  
JIA:  
    JB   P3.0, JIAN  
    DEC 30H          ;加速  
    MOV A, 30H  
    JNZ XXX          ;不能让它为0  
    INC 30H  
XXX:  
;    JNB P3.0, $  
;------------------  
JIAN:  
    JB   P3.1, XIANSHI  
    INC 30H  
    MOV A, 30H  
    SUBB A, \#80  
    JC   CCC  
    MOV 30H, \#80  
CCC:  
;    JNB P3.1, $  
;------------------  
XIANSHI:  
    DJNZ R7, T0\_END  
    MOV R7, 30H  
    INC 32H  
    ANL 32H, \#7  
;------------------  
    MOV A, 31H  
    ANL A, \#3  
    RL   A  
    RL   A  
    RL   A  
    ADD A, 32H  
    MOV DPTR, \#HUA\_Y  
    MOVC A, @A+DPTR  
    CPL A  
    MOV P1, A  
;------------------  
T0\_END:  
    RETI  
;---------------------------------  
X0\_INT:          ;设置花型  
    INC 31H  
    ANL 31H, \#3  
    MOV P2, 31H  
    INC P2  
    RETI  
;---------------------------------  
X1\_INT:          ;启动/停止  
    CPL TR0  
    RETI  
;---------------------------------  
HUA\_Y:  
    DB 0x80,0x40,0x20,0x10,0x08,0x04,0x02,0x01  
    DB 0x01,0x02,0x04,0x08,0x10,0x20,0x40,0x80  
    DB 0x81,0x42,0x24,0x18,0x81,0x42,0x24,0x18  
    DB 0x18,0x24,0x42,0x81,0x18,0x24,0x42,0x81  
END

[8051_ - _ -]: /images/20220731/11c4785eb2ac46f5adb2cca1f4ff40d3.png
[http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_91d1fff221a004f50b46e0ef.html]: http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/91d1fff221a004f50b46e0ef.html