单片机汇编语言编程：按键、计数及显示

本是古典何须时尚 2022-08-19 15:22 212阅读 0赞

如图所示电路，要求完成实现按钮按压次数的计数及显示，按一次按钮，计数值加1（要求按十进制累加）。

![单片机汇编语言编程：按键、计数及显示 - 非著名博主 - 电子信息角落][- _ -]  
[http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/2f609f80899bcfe2bd3e1ec9.html][http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_2f609f80899bcfe2bd3e1ec9.html]  
计数及显示范围是：0~99，超过99则自动归零。  
要求对按钮的检测用中断实现，数码显示用动态扫描（数码管为共阴数码管）。  
请设计实现该功能的完整程序。  
悬赏分：50 - 解决时间：2010-5-12 17:51  
最佳答案：  
;----------------------------------------------------------------------  
;用PROTEUS仿真，显示器使用7SEG-MPX2-CC  
;===================================  
    ORG 0000H  
    AJMP START  
    ORG 0013H  
    AJMP X1\_INT  
START:  
    MOV SP, \#60H  
    MOV IE, \#84H  
    MOV R3, \#0  
;-------------------  
MAIN:  
    LCALL DISPLAY  
    SJMP MAIN  
;-----------------------------------  
X1\_INT:  
    MOV A, R3  
    ADD A, \#1  
    DA   A  
    MOV R3, A          ;R3 = 00~99H  
X1\_LOOP:  
    LCALL DISPLAY  
    JNB P3.3, X1\_LOOP  
    RETI  
;-----------------------------------  
DISPLAY:     
    MOV A, R3  
    ANL A, \#0FH       ;取出个位.  
    MOV DPTR, \#TAB  
    MOVC A, @A + DPTR  
    MOV P2, \#0FFH      ;关闭显示.  
    MOV P0, A          ;输出段码.  
    CLR P2.1           ;P2.1=0  
    LCALL DELAY  
;-------------------  
    MOV A, R3  
    SWAP A  
    ANL A, \#0FH       ;取出十位.  
    MOVC A, @A + DPTR  
    MOV P2, \#0FFH      ;关闭显示.  
    MOV P0, A          ;输出段码.  
    CLR P2.0           ;P2.0=0  
    LCALL DELAY  
    RET  
;-----------------------------------  
DELAY:  
    MOV R4, \#250  
    DJNZ R4, $  
    RET  
;-----------------------------------  
TAB:  
    DB 3FH, 06H, 5BH, 4FH, 66H  
    DB 6DH, 7DH, 07H, 7FH, 6FH  
end  
;===================================  
回答者：    做而论道 - 十三级   2010-5-8 00:23  
提问者对于答案的评价：good  
原题网址：[http://z.baidu.com/question/151649564.html][http_z.baidu.com_question_151649564.html]  
;----------------------------------------------------------------------

[- _ -]: /images/20220731/4132a48639ec4c12bf30d1285cb3edb6.png
[http_hi.baidu.com_D7_F6_B6_F8_C2_DB_B5_C0_album_item_2f609f80899bcfe2bd3e1ec9.html]: http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/2f609f80899bcfe2bd3e1ec9.html
[http_z.baidu.com_question_151649564.html]: http://z.baidu.com/question/151649564.html