keil MDK启动文件分析---基于LPC2100系列(其实都是相通的)

你的名字 2022-07-12 15:57 174阅读 0赞

转用MDK有一段时间了，越来越觉得MDK的强大，因为我之前都是用ADS1.2开发产品，所以更能体会到MDK的强大与易用性。MDK编译出来的代码与ADS1.2相比，代码量减少了很多，我的一个工程用ADS1.2编译为25.4KB(都是bin格式)，但用MDK编译出来仅有19.5KB(采用默认优化级别,即L2优化级别)。根据我个人的经验，使用一个新的编译器，难点往往有三个，一个是建立一个新的工程，以及工程项目的配置；二是启动代码的编写；三是如何下载和单步调试。今天重点写一下MDK的启动代码。使用MDK版本为V4.01。

MDK编译器所追求的是要让arm 处理器像单片机那样简单使用，所以每个厂家的各种ARM，MDK都会有一个自带的启动代码，值得提出的是，这个启动代码可以用图形化界面来配置，这对刚入门的人来说绝对是一条捷径。

下面看一下MDK的启动代码以及图形化界面。

1.新建一个工程

单击Project ->New...->µVision Project菜单项，µVision 4将打开一个标准对话框，输入希望新建工程的名字即可创建一个新的工程，建议对每个新建工程使用独立的文件夹。

2.选择设备

在创建一个新的工程时，µVision要求为这个工程选择一款CPU。**选择设备**对话框显示了µVision的设备数据库，只需要选择用户所需的微控制器即可。例如，选择 Philips LPC2114微控制器，这个选择设置了LPC2114设备的必要工具选项、简化了工具的配置。

![0_1282906648YKwP.gif][]

当创建一个新的工程时，µVision会自动为所选择的CPU添加合适的启动代码。如下图，点击确定即可复制LPC2100的启动代码。

![0_12829067619aRz.gif][]

启动代码的正文如下所示：

![0_1282907058hmOe.gif][]

启动代码的图形配置界面：

µVision 4的配置向导通过菜单的方式对汇编程序、C程序或调试初始化文件进行配置。在配置文件中，对应这些配置菜单的是控制项(和html中的标签相似)，它们嵌入在配置文件的注释中。

![0_128290723262oD.gif][]

下面对启动代码做详细注释：

;/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/ 
;/\* STARTUP.S: Startup file for Philips LPC2000 \*/ 
;/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/ 
;/\* <<< Use Configuration Wizard in Context Menu >>> \*/ 
;/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/ 
;/\* This file is part of the uVision/ARM development tools. \*/ 
;/\* Copyright (c) 2005-2007 Keil Software. All rights reserved. \*/ 
;/\* This software may only be used under the terms of a valid, current, \*/ 
;/\* end user licence from KEIL for a compatible version of KEIL software \*/ 
;/\* development tools. Nothing else gives you the right to use this software. \*/ 
;/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

这段是一些说明，无非说些版权，时间信息等，注意红色标注出的语句必须在前100行文本中声明如下语句，这样编辑器将以配置向导视图的形式打开配置文件。

; Standard definitions of Mode bits and Interrupt (I & F) flags in PSRs

Mode\_USR EQU 0x10  
Mode\_FIQ EQU 0x11  
Mode\_IRQ EQU 0x12  
Mode\_SVC EQU 0x13  
Mode\_ABT EQU 0x17  
Mode\_UND EQU 0x1B  
Mode\_SYS EQU 0x1F

I\_Bit EQU 0x80 ; when I bit is set, IRQ is disabled  
F\_Bit EQU 0x40 ; when F bit is set, FIQ is disabled

这段代码用于定义一些模式，以及定义中断屏蔽位。

;// <h> Stack Configuration (Stack Sizes in Bytes) 
;// <o0> Undefined Mode <0x0-0xFFFFFFFF:8> 
;// <o1> Supervisor Mode <0x0-0xFFFFFFFF:8> 
;// <o2> Abort Mode <0x0-0xFFFFFFFF:8> 
;// <o3> Fast Interrupt Mode <0x0-0xFFFFFFFF:8> 
;// <o4> Interrupt Mode <0x0-0xFFFFFFFF:8> 
;// <o5> User/System Mode <0x0-0xFFFFFFFF:8> 
;// </h>

UND\_Stack\_Size EQU 0x00000000  
SVC\_Stack\_Size EQU 0x00000008  
ABT\_Stack\_Size EQU 0x00000000  
FIQ\_Stack\_Size EQU 0x00000000  
IRQ\_Stack\_Size EQU 0x00000080  
USR\_Stack\_Size EQU 0x00000400

ISR\_Stack\_Size EQU (UND\_Stack\_Size + SVC\_Stack\_Size + ABT\_Stack\_Size + /  
FIQ\_Stack\_Size + IRQ\_Stack\_Size)

AREA STACK, NOINIT, READWRITE, ALIGN=3

Stack\_Mem SPACE USR\_Stack\_Size  
\_\_initial\_sp SPACE ISR\_Stack\_Size

Stack\_Top

这一段配置堆栈空间，注意红色部分可以生成图形化的界面，

<h>－－Heading标题:表示以下选项在一个组中，直到遇到</h> ，表示Heading标题标题结束。

<ox>（x＝1，2，3...）－－表示可以指定一个值的范围

User/System Mode <0x0-0xFFFFFFFF:8>－－表示用户模式下堆栈范围为0～0xFFFFFFFF之间，数字“8”表示每次递增或递减的步长为8.

上面代码生成的图形化配置界面如下图：

![0_1282908696gEao.gif][]

若将上图的interrupt Mode的值该为0x0000 0100，则启动代码的“IRQ\_Stack\_Size EQU 0x00000080”自动变为“IRQ\_Stack\_Size EQU 0x00000100”

;// <h> Heap Configuration 
;// <o> Heap Size (in Bytes) <0x0-0xFFFFFFFF> 
;// </h>

Heap\_Size EQU 0x00000000

AREA HEAP, NOINIT, READWRITE, ALIGN=3  
\_\_heap\_base  
Heap\_Mem SPACE Heap\_Size  
\_\_heap\_limit

配置堆的大小，情况与配置堆栈十分相识。

;// <e> VPBDIV Setup 
;// Peripheral Bus Clock Rate 
;// <o1.0..1> VPBDIV: VPB Clock 
;// <0=> VPB Clock = CPU Clock / 4 
;// <1=> VPB Clock = CPU Clock 
;// <2=> VPB Clock = CPU Clock / 2 
;// <o1.4..5> XCLKDIV: XCLK Pin 
;// <0=> XCLK Pin = CPU Clock / 4 
;// <1=> XCLK Pin = CPU Clock 
;// <2=> XCLK Pin = CPU Clock / 2 
;// </e> 
VPBDIV\_SETUP EQU 1 
VPBDIV\_Val EQU 0x00000000

; Phase Locked Loop (PLL) definitions 
PLL\_BASE EQU 0xE01FC080 ; PLL Base Address 
PLLCON\_OFS EQU 0x00 ; PLL Control Offset 
PLLCFG\_OFS EQU 0x04 ; PLL Configuration Offset 
PLLSTAT\_OFS EQU 0x08 ; PLL Status Offset 
PLLFEED\_OFS EQU 0x0C ; PLL Feed Offset 
PLLCON\_PLLE EQU (1<<0) ; PLL Enable 
PLLCON\_PLLC EQU (1<<1) ; PLL Connect 
PLLCFG\_MSEL EQU (0x1F<<0) ; PLL Multiplier 
PLLCFG\_PSEL EQU (0x03<<5) ; PLL Divider 
PLLSTAT\_PLOCK EQU (1<<10) ; PLL Lock Status

配置VPBDIV

<e> －－Heading且Enable标题:表示以下选项在一个组中，选项可通过Checkbox使能

<o1.0..1>－－－修改数值的指定位

上面代码生成的图形化配置界面如下图：

![0_12829094955VeU.gif][]

;// <e> PLL Setup 
;// <o1.0..4> MSEL: PLL Multiplier Selection 
;// <1-32><\#-1> 
;// M Value 
;// <o1.5..6> PSEL: PLL Divider Selection 
;// <0=> 1 <1=> 2 <2=> 4 <3=> 8 
;// P Value 
;// </e> 
PLL\_SETUP EQU 1 
PLLCFG\_Val EQU 0x00000023

配置PLL。情况与配置VPBDIV十分相似。

; Memory Accelerator Module (MAM) definitions  
MAM\_BASE EQU 0xE01FC000 ; MAM Base Address  
MAMCR\_OFS EQU 0x00 ; MAM Control Offset  
MAMTIM\_OFS EQU 0x04 ; MAM Timing Offset

;// <e> MAM Setup 
;// <o1.0..1> MAM Control 
;// <0=> Disabled 
;// <1=> Partially Enabled 
;// <2=> Fully Enabled 
;// Mode 
;// <o2.0..2> MAM Timing 
;// <0=> Reserved <1=> 1 <2=> 2 <3=> 3 
;// <4=> 4 <5=> 5 <6=> 6 <7=> 7 
;// Fetch Cycles 
;// </e> 
MAM\_SETUP EQU 1 
MAMCR\_Val EQU 0x00000002 
MAMTIM\_Val EQU 0x00000004

配置存储器加速模块，情况与配置VPBDIV十分相似。

; External Memory Controller (EMC) definitions  
EMC\_BASE EQU 0xFFE00000 ; EMC Base Address  
BCFG0\_OFS EQU 0x00 ; BCFG0 Offset  
BCFG1\_OFS EQU 0x04 ; BCFG1 Offset  
BCFG2\_OFS EQU 0x08 ; BCFG2 Offset  
BCFG3\_OFS EQU 0x0C ; BCFG3 Offset

;// <e> External Memory Controller (EMC) 
EMC\_SETUP EQU 0

;// <e> Bank Configuration 0 (BCFG0) 
;// <o1.0..3> IDCY: Idle Cycles <0-15> 
;// <o1.5..9> WST1: Wait States 1 <0-31> 
;// <o1.11..15> WST2: Wait States 2 <0-31> 
;// <o1.10> RBLE: Read Byte Lane Enable 
;// <o1.26> WP: Write Protect 
;// <o1.27> BM: Burst ROM 
;// <o1.28..29> MW: Memory Width <0=> 8-bit <1=> 16-bit 
;// <2=> 32-bit <3=> Reserved 
;// </e> 
BCFG0\_SETUP EQU 0 
BCFG0\_Val EQU 0x0000FBEF

;// <e> Bank Configuration 1 (BCFG1) 
;// <o1.0..3> IDCY: Idle Cycles <0-15> 
;// <o1.5..9> WST1: Wait States 1 <0-31> 
;// <o1.11..15> WST2: Wait States 2 <0-31> 
;// <o1.10> RBLE: Read Byte Lane Enable 
;// <o1.26> WP: Write Protect 
;// <o1.27> BM: Burst ROM 
;// <o1.28..29> MW: Memory Width <0=> 8-bit <1=> 16-bit 
;// <2=> 32-bit <3=> Reserved 
;// </e> 
BCFG1\_SETUP EQU 0 
BCFG1\_Val EQU 0x0000FBEF

;// <e> Bank Configuration 2 (BCFG2) 
;// <o1.0..3> IDCY: Idle Cycles <0-15> 
;// <o1.5..9> WST1: Wait States 1 <0-31> 
;// <o1.11..15> WST2: Wait States 2 <0-31> 
;// <o1.10> RBLE: Read Byte Lane Enable 
;// <o1.26> WP: Write Protect 
;// <o1.27> BM: Burst ROM 
;// <o1.28..29> MW: Memory Width <0=> 8-bit <1=> 16-bit 
;// <2=> 32-bit <3=> Reserved 
;// </e> 
BCFG2\_SETUP EQU 0 
BCFG2\_Val EQU 0x0000FBEF

;// <e> Bank Configuration 3 (BCFG3) 
;// <o1.0..3> IDCY: Idle Cycles <0-15> 
;// <o1.5..9> WST1: Wait States 1 <0-31> 
;// <o1.11..15> WST2: Wait States 2 <0-31> 
;// <o1.10> RBLE: Read Byte Lane Enable 
;// <o1.26> WP: Write Protect 
;// <o1.27> BM: Burst ROM 
;// <o1.28..29> MW: Memory Width <0=> 8-bit <1=> 16-bit 
;// <2=> 32-bit <3=> Reserved 
;// </e> 
BCFG3\_SETUP EQU 0 
BCFG3\_Val EQU 0x0000FBEF

;// </e> End of EMC

配置外部存储器，情况和配置VPBDIV类似。

; External Memory Pins definitions  
PINSEL2 EQU 0xE002C014 ; PINSEL2 Address  
PINSEL2\_Val EQU 0x0E6149E4 ; CS0..3, OE, WE, BLS0..3,  
; D0..31, A2..23, JTAG Pins

定义外部存储器引脚。

PRESERVE8

; Area Definition and Entry Point  
; Startup Code must be linked first at Address at which it expects to run.

AREA RESET, CODE, READONLY  
ARM ;声明使用ARM模式  
默认连接下,启动代码必须放在RESET段内

; Exception Vectors  
; Mapped to Address 0.  
; Absolute addressing mode must be used.  
; Dummy Handlers are implemented as infinite loops which can be modified.

Vectors LDR PC, Reset\_Addr ;定义异常向量\-复位  
 LDR PC, Undef\_Addr ;未定义指令  
LDR PC, SWI\_Addr ;软件中中断  
 LDR PC, PAbt\_Addr ;预取指中止  
 LDR PC, DAbt\_Addr ;数据中止  
 NOP  ; Reserved Vector 保留  
; LDR PC, IRQ\_Addr ;IRQ中断,用下面的语句代替本句,这样能更快的进入中断  
 LDR PC, \[PC, \#-0x0FF0\] ; 从VicVectAddr寄存器读取中断向量地址. 当CPU执行这条指令还没有跳转时,  
; PC的值为0x0000 0020. 0x0000 0020减去0x0ff0为0xFFFF F030这是向量控制寄  
 ; 存器的特殊寄存器VicVectAddr,这个寄存器保存当前IRQ中断服务程序的入口地址  
 LDR PC, FIQ\_Addr

Reset\_Addr DCD Reset\_Handler ;默认连接下,复位异常服务函数名必须声明为Reset\_Handler,这是程序默认入口  
Undef\_Addr DCD Undef\_Handler  
SWI\_Addr DCD SWI\_Handler  
PAbt\_Addr DCD PAbt\_Handler  
DAbt\_Addr DCD DAbt\_Handler  
DCD 0 ; Reserved Address   
IRQ\_Addr DCD IRQ\_Handler  
FIQ\_Addr DCD FIQ\_Handler

Undef\_Handler B Undef\_Handler ;跳转到复位异常服务函数  
SWI\_Handler B SWI\_Handler ;一般情况下,由于PLC2100系列并不需要软件中断,预取指中止等异常,所以这些  
PAbt\_Handler B PAbt\_Handler ;异常服务程序只是原地循环  
DAbt\_Handler B DAbt\_Handler  
IRQ\_Handler B IRQ\_Handler  
FIQ\_Handler B FIQ\_Handler

; Reset Handler 程序复位后进入

EXPORT Reset\_Handler  ;声明外部符号,这个符号由keil MDK编译器提供,是程序的入口  
Reset\_Handler

; Setup External Memory Pins ;设置外部存储器引脚  
 IF :DEF:EXTERNAL\_MODE ;如果在keil编译器的Project-options-Asm-Define下键入EXTERNAL\_MODE,则执行  
 ;以下代码,EXTERNAL\_MODE表示从片外Flash Rom执行代码.  
 LDR R0, =PINSEL2  
LDR R1, =PINSEL2\_Val  
STR R1, \[R0\]  
ENDIF

; Setup External Memory Controller 
 IF EMC\_SETUP <> 0 ;如果EMC\_SETUP=1，则执行IF...ENDIF之间的代码. 
;当在Configuration Wizard(图形化配置启动代码,keil的一大特色),中,选中 
 ;External Memory Controller (EMC)时,EMC\_SETUP=1,否则该值为0. 
 LDR R0, =EMC\_BASE

IF BCFG0\_SETUP <> 0 
LDR R1, =BCFG0\_Val 
STR R1, \[R0, \#BCFG0\_OFS\] 
ENDIF

IF BCFG1\_SETUP <> 0 
LDR R1, =BCFG1\_Val 
STR R1, \[R0, \#BCFG1\_OFS\] 
ENDIF

IF BCFG2\_SETUP <> 0 
LDR R1, =BCFG2\_Val 
STR R1, \[R0, \#BCFG2\_OFS\] 
ENDIF

IF BCFG3\_SETUP <> 0 
LDR R1, =BCFG3\_Val 
STR R1, \[R0, \#BCFG3\_OFS\] 
ENDIF

ENDIF ; EMC\_SETUP

; Setup VPBDIV 
 IF VPBDIV\_SETUP <> 0 
LDR R0, =VPBDIV 
LDR R1, =VPBDIV\_Val 
STR R1, \[R0\] 
ENDIF

; Setup PLL 
 IF PLL\_SETUP <> 0 
LDR R0, =PLL\_BASE ;指向PLL控制器第一个寄存器地址,即PLLCON(PLL控制寄存器) 
;PLL\_BASE+PLLCON\_OFS=PLLCON(PLL控制寄存器) 
;PLL\_BASE+PLLCFG\_OFS=PLLCFG(PLL配置寄存器) 
;PLL\_BASE+PLLFEED\_OFS=PLLFEED(PLL馈送寄存器) 
;PLL\_BASE+PLLSTAT\_OFS=PLLSTAT(PLL状态寄存器) 
 MOV R1, \#0xAA ;馈送序列 
 MOV R2, \#0x55

; Configure and Enable PLL  
 MOV R3, \#PLLCFG\_Val ;写入PLL配置寄存器中的值  
  
STR R3, \[R0, \#PLLCFG\_OFS\] ;PLL配置寄存器:PLLCFG  
 ;bit\[4:0\] bit\[6:5\] bit7  
; | | |  
; | | - 保留  
 ; | -- PSEL\[1:0\]:PLL分频器值  
 ; --- MSEL\[4:0\]: PLL倍频值  
MOV R3, \#PLLCON\_PLLE  ;PLL使能值  
STR R3, \[R0, \#PLLCON\_OFS\] ;PLL控制寄存器:PLLCON  
;bit0 bit1 bit\[7:2\]  
; | | |  
; | | - 保留  
 ; | -- PLLC: PLL连接.当PLLE和PLLC都为1且在有效的PLL馈送后,将PLL  
; | 作为时钟源连接到lpc211x,否则,cpu直接用振荡器时钟.  
; --- PLL使能.当该为为1并且有效的PLL馈送之后,该位将激活PLL并锁定到指定频率  
 STR R1, \[R0, \#PLLFEED\_OFS\] ;PLL馈送寄存器:PLLFEED  
STR R2, \[R0, \#PLLFEED\_OFS\] ; bit\[7:0\]  
; |  
; -将正确的序列馈送到该寄存器,才能使PLL配置和控制寄存器的更改生效.

; Wait until PLL Locked  
PLL\_Loop LDR R3, \[R0, \#PLLSTAT\_OFS\] ;读PLL状态寄存器(PLLSTAT)的值  
 ;bit\[4:0\] bit\[6:5\] bit7 bit8 bit9 bit10 bit\[15:11\]  
; | | | | | | |  
; | | | | | | - 保留  
 ; | | | | | - PLOCK:为1时,PLL锁定  
 ; | | | | | 到指定的频率  
 ; | | | | -- PLLC:读出PLL连接位的值  
 ; | | | --- PLLE:读出的PLL使能位状态值  
 ; | | ---- 保留  
 ; | ----- PSEL\[1:0\]:读出的PLL分频器值  
 ; ------ MSEL\[4:0\]:读出的PLL倍频器值  
ANDS R3, R3, \#PLLSTAT\_PLOCK ;后缀\-s更新标志位：N, Z, C, V  
; | | | |  
; | | | -  溢出  
 ; | | -- 进位或借位或扩展  
 ; | --- 零  
 ; ---- 负或小于  
 BEQ PLL\_Loop ;为零则转

; Switch to PLL Clock  
 MOV R3, \#(PLLCON\_PLLE:OR:PLLCON\_PLLC) ;PLL使能,连接使能  
 STR R3, \[R0, \#PLLCON\_OFS\]  
STR R1, \[R0, \#PLLFEED\_OFS\] ;馈送序列  
 STR R2, \[R0, \#PLLFEED\_OFS\]  
ENDIF ; PLL\_SETUP

; Setup MAM 设置MAM(存储器加速模块) 
 IF MAM\_SETUP <> 0 ;当在Configuration Wizard(图形化配置启动代)中选中MAM Setup,则MAM\_SETUP=1 
 LDR R0, =MAM\_BASE ;MAM基地址,为0xE01F C000 
 MOV R1, \#MAMTIM\_Val ;MAM取指周期,周立功公司出版的一本书中建议:若系统时钟低于20MHZ,不用使用 
 ;MAM;当系统时钟在20~40MHZ时,建议Flash访问时间设定为2个处理器周期;当系统 
 ;周期大于40MHZ时,建议使用3个处理器周期 
 ;该值会根据Configuration Wizard(图形化配置启动代)中MAM timing选择而变化 
 STR R1, \[R0, \#MAMTIM\_OFS\] ;将R1值送入MAM定时寄存器:MAMTIM 
; bit\[2:0\] bit\[7:3\] 
; | | 
; | - 保留 
 ; -- MAM取指周期设定,这几位决定MAM Flash取指操作的时间: 
; 000=0：保留 
 ; 001=1：MAM取指周期为1个处理器时钟 
 ; 010=2：MAM取指周期为2个处理器时钟 
 ; ... ... 
; xxx=n: MAM取指周期为n个处理器时钟(n=3,4,5,6,7) 
 MOV R1, \#MAMCR\_Val ;MAM模式控制值(0~2) 
;该值会根据Configuration Wizard(图形化配置启动代)中MAM Control选择而改变 
 STR R1, \[R0, \#MAMCR\_OFS\] ;将R1值送入MAM控制寄存器:MAMCR 
; bit\[1:0\] bit\[7:2\] 
; | | 
; | - 保留,不要向其写1 
; -- MAM模式控制位,决定了MAM的操作模式 
 ; 00：MAM被禁止 
 ; 01：MAM部分使能 
 ; 10：MAM功能完全使能 
 ; 11：保留 
 ENDIF ; MAM\_SETUP

; Memory Mapping (when Interrupt Vectors are in RAM) 存储器映射  
MEMMAP EQU 0xE01FC040 ; Memory Mapping Control  
 IF :DEF:REMAP ;如果在keil编译器的Project-options-Asm-Define下键入MEMAP,则执行以下代码,  
;REMAP表示在某些设备上执行存储映射  
 LDR R0, =MEMMAP  
IF :DEF:EXTMEM\_MODE ;判断是否从片外Flash ROM执行代码  
 MOV R1, \#3  
ELIF :DEF:RAM\_MODE ;判断是否从RAM执行代码  
 MOV R1, \#2 ;MEMMAP=0x02即可从RAM执行代码  
 ELSE  
MOV R1, \#1  
ENDIF  
STR R1, \[R0\]  
ENDIF

; Initialise Interrupt System 初始化一些中断信息,  
; ...

; Setup Stack for each mode

LDR R0, =Stack\_Top

; Enter Undefined Instruction Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_UND:OR:I\_Bit:OR:F\_Bit  
MOV SP, R0  
SUB R0, R0, \#UND\_Stack\_Size

; Enter Abort Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_ABT:OR:I\_Bit:OR:F\_Bit  
MOV SP, R0  
SUB R0, R0, \#ABT\_Stack\_Size

; Enter FIQ Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_FIQ:OR:I\_Bit:OR:F\_Bit  
MOV SP, R0  
SUB R0, R0, \#FIQ\_Stack\_Size

; Enter IRQ Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_IRQ:OR:I\_Bit:OR:F\_Bit  
MOV SP, R0  
SUB R0, R0, \#IRQ\_Stack\_Size

; Enter Supervisor Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_SVC:OR:I\_Bit:OR:F\_Bit  
MOV SP, R0  
SUB R0, R0, \#SVC\_Stack\_Size

; Enter User Mode and set its Stack Pointer  
 MSR CPSR\_c, \#Mode\_USR  
IF :DEF:\_\_MICROLIB

EXPORT \_\_initial\_sp

ELSE

MOV SP, R0  
SUB SL, SP, \#USR\_Stack\_Size  ;SL指的是R10

ENDIF

; Enter the C code

IMPORT \_\_main  
LDR R0, =\_\_main  
BX R0

IF :DEF:\_\_MICROLIB

EXPORT \_\_heap\_base  
EXPORT \_\_heap\_limit

ELSE  
; User Initial Stack & Heap  
 AREA |.text|, CODE, READONLY

IMPORT \_\_use\_two\_region\_memory  
EXPORT \_\_user\_initial\_stackheap  
\_\_user\_initial\_stackheap

LDR R0, = Heap\_Mem  
LDR R1, =(Stack\_Mem + USR\_Stack\_Size)  
LDR R2, = (Heap\_Mem + Heap\_Size)  
LDR R3, = Stack\_Mem  
BX LR  
ENDIF

END

写在最后: 自己想在工作之余写一写MDK的应用,从启动代码、项目配置、下载调试到它自带的模拟仿真器的使用等等，只是没想到一个启动代码写下来已经让我感觉写出一个条理清晰的文章是多么的难，而且感觉这个csdn博客的编辑器太难操作，要插入图片要费很大的力气。到最后好不容易编写完成，点击“发表文章”，可半天没有反应，一着急点了刷新，所写的东西竟然没有了一大半，幸亏自己备份的及时，才保住了辛苦几天的东西。嗯嗯...以后我尽量做成pdf格式的，这样子效率太低了。

想给自己重新起个网名，现在都工作了，再延续大学的网名“小瓶盖”好像有点不好：自己明明已经不小了。哈，只是，那个我还在大学的时候，那些日子我和我的一大群的同学们过的自在快活，那时候我们一起上课,一起吃饭,一起去自习室,一起联网打游戏...最难忘的是大四的最后，我们做好毕业设计后，天天聚在宿舍玩dota，我和小强，蝈蝈和冬瓜，买饭都是逮到谁让谁捎，经常会有人提着几袋子饭盒出现在宿舍楼与食堂的路上。那时候小强玩dato很厉害，我跟在他屁股后头蹭蹭经验拣拣人头，经常把蝈蝈和冬瓜哥打的稀里哗啦，...好怀念。

大四往前推一年，我大三临近结束，正要准备大学生电子竞赛，高中的一位同学突然成了我的女友，在高中的时候，我个子还矮矮的，所以每次排位都在她后面一排，而且离得很近，三年下来，我们很熟。我自己是个不爱表达的人，但我很珍惜这份感情。有一天我们聊天，她看到我以前的网名，说不太好听。我说要不你给我想一个，她想想，说：就叫“小瓶盖”吧。然后，我就有了这个网名。现在，她过的应该还好吧，感觉好久好久没有联系，我知道自己实在无趣的很，所以也愿意以朋友的名义，看着她，走进该有的幸福。只是，我的网名，却一直没有变。转眼间离开大学快三个月了，大强、蝈蝈还有他老婆去了北航，小弟、2松，冬瓜、党员，南哥也都有各自的工作，离开了大学，离开了他（她）们，突然觉得心中空荡荡的，所以我想用我平时的时间，胡乱的记录一下，就算是不让自己有什么空闲的时间去想那些我永远不可能忘记的事和人。

以后的网名，就叫做“瓶盖”吧，我这个反应迟钝的人，对于一些曾经的事情，终究，还是不能放下。

前一段时间，在网上遇到一个小学弟，他告诉我，学校已经开学了。

[0_1282906648YKwP.gif]: /images/20220709/23042027536343b7a9a664cc18788c68.png
[0_12829067619aRz.gif]: /images/20220709/473cb381170b4774a4b75f10b7048e5a.png
[0_1282907058hmOe.gif]: /images/20220709/007266570a4948f4abfbe7745173c7ee.png
[0_128290723262oD.gif]: /images/20220709/91f95bcdc0b4430bba439ff31cf0e805.png
[0_1282908696gEao.gif]: /images/20220709/db69ca666fab4c8ebabc82179307f1bb.png
[0_12829094955VeU.gif]: /images/20220709/8108cdd099da4ba4a30861d66fc80006.png