oracle数字转换成人民币大写

迷南。 2022-05-17 05:09 283阅读 0赞

网上找了好几篇博客，测试或多或少有问题，以下已验证可以使用。

create or replace function cux\_convert\_cny(p\_num in number default null)    
      return nvarchar2 is    
        
      Result      nvarchar2(100); --返回字符串    
      num\_round   nvarchar2(100) := to\_char(abs(round(p\_num, 2))); --转换数字为小数点后2位的字符(正数)    
      num\_left    nvarchar2(100); --小数点左边的数字    
      num\_right   nvarchar2(2); --小数点右边的数字    
      str1        nchar(10) := '零壹贰参肆伍陆柒捌玖'; --数字大写    
      str2        nchar(16) := '元拾佰仟万拾佰仟亿拾佰仟万拾佰仟'; --数字位数(从低至高)    
      num\_pre     number(1) := 1; --前一位上的数字    
      num\_current number(1); --当前位上的数字    
      num\_count   number := 0; --当前数字位数    
        
    begin    
      if p\_num is null then    
        return null;    
      end if; --转换数字为null时返回null    
        
      select to\_char(nvl(substr(to\_char(num\_round),    
                                1,    
                                decode(instr(to\_char(num\_round), '.'),    
                                       0,    
                                       length(num\_round),    
                                       instr(to\_char(num\_round), '.') - 1)),    
                         0))    
        into num\_left    
        from dual; --取得小数点左边的数字    
      select substr(to\_char(num\_round),    
                    decode(instr(to\_char(num\_round), '.'),    
                           0,    
                           length(num\_round) + 1,    
                           instr(to\_char(num\_round), '.') + 1),    
                    2)    
        into num\_right    
        from dual; --取得小数点右边的数字    
        
      if length(num\_left) > 16 then    
        return '\*\*\*\*\*\*\*\*\*\*';    
      end if; --数字整数部分超过16位时    
        
      --采用从低至高的算法，先处理小数点右边的数字    
      if length(num\_right) = 2 then    
        if to\_number(substr(num\_right, 1, 1)) = 0 then    
          result := '零' ||    
                    substr(str1, to\_number(substr(num\_right, 2, 1)) + 1, 1) || '分';    
        else    
          result := substr(str1, to\_number(substr(num\_right, 1, 1)) + 1, 1) || '角' ||    
                    substr(str1, to\_number(substr(num\_right, 2, 1)) + 1, 1) || '分';    
        end if;    
      elsif length(num\_right) = 1 then    
        result := substr(str1, to\_number(substr(num\_right, 1, 1)) + 1, 1) || '角整';    
      else    
        result := '整';    
      end if;    
      --再处理小数点左边的数字    
      for i in reverse 1 .. length(num\_left) loop    
        --(从低至高)    
        num\_count   := num\_count + 1; --当前数字位数    
        num\_current := to\_number(substr(num\_left, i, 1)); --当前位上的数字    
        if num\_current > 0 then    
          --当前位上数字不为0按正常处理    
          result := substr(str1, num\_current + 1, 1) ||    
                    substr(str2, num\_count, 1) || result;    
        else    
          --当前位上数字为0时    
          if mod(num\_count - 1, 4) = 0 then    
            --当前位是元、万或亿时    
            result  := substr(str2, num\_count, 1) || result;    
            num\_pre := 0; --元、万,亿前不准加零    
          end if;    
          if num\_pre > 0 or length(num\_left) = 1 then    
            --上一位数字不为0或只有个位时    
            result := substr(str1, num\_current + 1, 1) || result;    
          end if;    
        end if;    
        num\_pre := num\_current;    
      end loop;    
        
      if p\_num < 0 then    
        --转换数字是负数时    
        result := '负' || result;    
      end if;    
        
      return Result;    
        
    exception    
      when others then    
        raise\_application\_error(-20001, '数字转换大写出现错误！' || sqlerrm);    
    end;