机房收费--主界面（控件随窗体成比例改变）

妖狐艹你老母 2022-01-30 08:04 203阅读 0赞

机房收费系统的主界面是用MDI窗体做的，遇到的第一个问题就是无法在窗体上放Command和textbox等无对齐属性的控件，然后就需要用picturebox做容器存放这些无对齐属性的控件。但是当运行起来的时候，另一个问题就又出现了，子窗体不能显示出来，打开主窗体的时候，子窗体就潜水了。经过上网查资料，站在巨人的肩膀上，我了解到了一个方法：想让父窗体显示的同时，让其他的控件也正常的显示出来，不一定非要在MDI窗体上画控件，我们可以采取借鸡下蛋的方法，用一个窗体做容器，把这些控件放到窗体上，前提是要把窗体设置为子窗体，把其borderstype 设置为none，然后在MDI窗体加载的时候，子窗体也就同时加载出来，还不影响窗体上控件的显示：

Private Sub MDIForm_Load()
        Form1.Show
        Form1.Height = MDIForm1.ScaleHeight
        Form1.Width = MDIForm1.ScaleWidth
    End Sub

但是又会出现一个问题，就是点击主窗体的空白处，子窗体就会隐藏起来，而且点不出来，这时就需要这里就用到了API函数中的SetParent函数。首先在模块中声明SetParent函数：

Public Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long

然后在MDI主窗体的菜单中找到想要显示的窗体，在他的click事件中，编写代码就可以实现子窗体不再找不到：

'格式说明：setparent +要显示的子窗体.hwnd,MDI主窗体.hwnd
    Private Sub Registration_Click()
        frmregist.Show
        SetParent FrmRegist.hwnd,frmmain.hwnd
    End Sub

在这个时候我想起了一个之前学生系统就出现的问题，那就是窗体上的控件不随着窗体的改变而改变，这是不合理的，只有当调整窗体的大小时，其控件也跟着改变，这样的窗体才更加的符合规范。

Option Explicit
    Private FormOldWidth As Long            '保存窗体的原始宽度
    Private FormOldHeight As Long           '保存窗体的原始高度
    
    '在调用ResizeForm前先调用本函数
    Public Sub ResizeInit(FormName As Form)
        Dim Obj As Control
            FormOldWidth = FormName.ScaleWidth
            FormOldHeight = FormName.ScaleHeight
        On Error Resume Next
            For Each Obj In FormName
                Obj.Tag = Obj.Left & " " & Obj.Top & " " & Obj.Width & " " & Obj.Height & " "
            Next Obj
        On Error GoTo 0
    End Sub
    
    '按比例改变窗体内各控件的大小，在调用ReSizeForm前先调用ReSizeInit函数
    Public Sub ResizeForm(FormName As Form)
        Dim Pos(4) As Double
        Dim i As Long, TempPos As Long, StartPos As Long
        Dim Obj As Control
        Dim ScaleX As Double, ScaleY As Double
        
        ScaleX = FormName.ScaleWidth / FormOldWidth             '保存窗体宽度缩放比例
        ScaleY = FormName.ScaleHeight / FormOldHeight           '保存窗体高度缩放比例
        
        On Error Resume Next
        For Each Obj In FormName
            StartPos = 1
        For i = 0 To 4
            '读取控件的原始位置与大小
            TempPos = InStr(StartPos, Obj.Tag, " ", vbTextCompare)
            If TempPos > 0 Then
                Pos(i) = Mid(Obj.Tag, StartPos, TempPos - StartPos)
                StartPos = TempPos + 1
            Else
                Pos(i) = 0
            End If
            '根据控件的原始位置及窗体改变大小的比例对控件重新定位与改变大小
            Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX, Pos(3) * ScaleY
        Next i
        Next Obj
        On Error GoTo 0
    End Sub
    
    Private Sub Form_Load()
        Call ResizeInit(Me) '在程序装入时必须加入
    End Sub
    
    Private Sub Form_Resize()
        Call ResizeForm(Me) '确保窗体改变时控件随之改变
    End Sub

效果图如下：

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3FxXzM5MDcxNTk5_size_16_color_FFFFFF_t_70][]

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3FxXzM5MDcxNTk5_size_16_color_FFFFFF_t_70 1][]

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3FxXzM5MDcxNTk5_size_16_color_FFFFFF_t_70]: /images/20220130/af9cc9394ef84159a7d639cc46653f42.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3FxXzM5MDcxNTk5_size_16_color_FFFFFF_t_70 1]: /images/20220130/8438426776ec48efac42caf87ec51b19.png