34. LotusScript中的错误处理程序

拼搏现实的明天。 2022-01-14 03:59 227阅读 0赞

错误处理程序是所有严肃的程序的必要部分。但是在Lotus Notes开发中，很多程序员编写LotusScript代码时，并没有写专门的错误处理代码的习惯。这能够行得通，主要是因为LotusScript程序是嵌入在Notes客户端中执行的，出现错误时，客户端会报错，退出代码的执行，而不会崩溃。而用其他单独运行的语言开发时，很多错误处理程序就是简单将错误信息或者对用户更友好的解释显示出来，并让程序继续运行（没有它们，程序就会退出。）还有一个原因是，没有错误处理程序，LotusScript调试器迅速运行到出错的那一行；反之，则要程序员自己观察错误是由哪一行引起的。

尽管如此，在很多情况下，为LotusScript代码编写错误处理的部分仍然是必需的。有时候我们需要控制错误出现时的情况：给用户友好的提示，引导他们如何操作；根据不同的错误类型，做出调整或者继续运行程序的其余部分；记录错误信息到日志中等等。最后一种情况在服务器端运行的程序中尤为普遍。

大多数情况下，LotusScript中的错误处理程序和下面的代码类似：

Public Function Run()
    	On Error GoTo EH
    	'Run...
    	Exit Function 
    EH:
    	MsgBox "Error(" & Err() & "): " & Error() & " at line " & Erl() & " in function Run."
    	'Other possible actions.
    	Exit Function  
    End Function

它们的公共部分就是给出一个详细的错误信息，由错误号、对错误的描述、错误发生的代码行数和所在的函数名，以便程序员快速定位和排除错误。需要注意的是函数Erl()，它返回出错的代码行数。如果被调用的函数没有错误处理代码，错误将上升到调用的函数，如果此函数也没有捕获错误，该错误将继续上升，直到在某个函数里被处理，或者导致程序中断。在这个“冒泡”的过程中，位于调用堆栈中某一级的函数里的错误处理代码若使用Erl()，得到的代码行数将是在此函数中调用冒出错误的函数的语句所在的行数，而不是错误最初发生的语句的行数。另一方面，若错误处理代码调用其他自定义的函数，再于其内计算Erl()，返回的行数不会受影响。另外值得一提的是Erl()函数在脚本库的上下文里，给出的是出错代码在整个脚本库里的行号；在一个自定义类的上下文里，给出的是出错代码在整个类里的行号。Designer 8.5引入全新的基于Eclipse的LotusScript编辑器后，Erl()报出的行号一度不准确，和实际的错误行号相差2，以至于一些开发者退回使用老版本的编辑器。到版本9，这个问题已被修复。

每次都重复这样的代码当然繁琐无味。自然希望写一个通用的函数，之后每次要处理错误时调用即可。要这样做，唯一的问题就在于，如何在这个函数中给出出错的函数的名称，即上面的Run。幸好，LotusScript里有一个有用的函数GetThreadInfo()，可以返回很多正在运行当前LotusScript脚本的线程的信息，其中就包括，调用当前函数的模块和函数的名称。有了这个方便，我们的错误处理函数就可以写作如下：

%REM
    	Description: Common error handler. Return the detailed error message.
    %END REM
    Public Function GetErrorMsg() As String
    	Dim msg As String
    	'LSI_THREAD_CALLMODULE=11, LSI_THREAD_CALLPROC=10
    	msg = GetThreadInfo(11) & ">" & Getthreadinfo(10) & ": " & _
    	"Error(" & Err() & "): " & Error() & " at line "& Erl()
    	GetErrorMsg=msg  
    End Function

这个错误处理函数只返回一个详细描述错误的信息，而没有任何进一步的动作，就是为了给调用者最大的灵活性，可以将它打印出来，也可以写入日志。现在，我们上面的Run()函数就可以改写成：

Public Function Run()
    	On Error GoTo EH
    	'Run...
    	Exit Function 
    EH:
    	MsgBox GetErrorMsg()
    	'Other possible actions.
    	Exit Function  
    End Function