PLSQL学习之基础

逃离我推掉我的手 2022-01-07 02:53 504阅读 0赞

# **PLSQL介绍** #

**PLSQL是Oracle对SQL99的一种扩展**，基本每一种数据库都会对SQL进行扩展，Oracle对SQL的扩展就叫做PLSQL...

SQL99是什么

*  （1）**是操作所有关系型数据库的规则**
 *  （2）是第四代语言
 *  （3）**是一种结构化查询语言**
 *  （4）只需发出合法合理的命令，就有对应的结果显示

SQL的特点

*  （1）**交互性强，非过程化**
 *  （2）数据库操纵能力强，只需发送命令，无需关注如何实现
 *  （3）多表操作时，自动导航简单，例如：
    
        select emp.empno,emp.sal,dept.dname
        from emp,dept
        where emp.deptno = dept.deptno

*  （4）容易调试，错误提示，直接了当
 *  （5）\*\*SQL强调结果\*\*

**PLSQL是什么**

\- 是专用于Oracle服务器，在SQL基础之上，\*\*添加了一些过程化控制语句，叫PLSQL\*\*  
\- 过程化包括有：类型定义，判断，循环，游标，异常或例外处理。。。  
\- \*\*PLSQL强调过程\*\*

**为什么要用PLSQL**

\- 因为SQL是第四代命令式语言，\*\*无法显示处理过程化的业务，所以得用一个过程化程序设计语言来弥补SQL的不足之处\*\*，  
\- SQL和PLSQL不是替代关系，是弥补关系

\#\# PLSQL语法 \#\#

declare和exception都是可以省略的，\`begin和end;/\`是不能省略的。  
\`\`\`sql

[declare]
              变量声明;
          变量声明;
         begin
              DML/TCL操作;
          DML/TCL操作;
         [exception]
              例外处理;
          例外处理;
         end;
         /

在PLSQL程序中：**；号表示每条语句的结束，/表示整个PLSQL程序结束**

PLSQL与SQL执行有什么不同：

*  （1）SQL是单条执行的
 *  （2）PLSQL是整体执行的，不能单条执行，整个PLSQL结束用/，其中每条语句结束用；号

--------------------

**PLSQL变量**

既然PLSQL是注重过程的，那么写过程的程序就肯定有基本的语法，首先我们来介绍PLSQL的变量

PLSQL的变量有4种

*  **number**
 *  **varchar2**
 *  **与列名类型相同**
 *  与整个表的列类型相同

写一个PLSQL程序，输出"hello world"字符串，语法：dbms\_output.put\_line('需要输出的字符串');

begin
        --向SQLPLUS客户端工具输出字符串
        dbms_output.put_line('hello 你好');
    end;
    /

注意：  
**dbms\_output是oracle中的一个输出对象  
put\_line是上述对象的一个方法，用于输出一个字符串自动换行**

设置显示PLSQL程序的执行结果，默认情况下，不显示PLSQL程序的执行结果，语法：set serveroutput on/off;  
set serveroutput on;

使用基本类型变量,常量和注释，求10+100的和

declare
        --定义变量
        mysum number(3) := 0;
        tip varchar2(10) := '结果是';
    begin
        /*业务算法*/   
        mysum := 10 + 100;
        /*输出到控制器*/
        dbms_output.put_line(tip || mysum);
    end;
    /

输出7369号员工姓名和工资，格式如下：7369号员工的姓名是SMITH,薪水是800，语法：使用表名.字段%type

declare
        --定义二个变量，分别装姓名和工资
        pename emp.ename%type;
        psal   emp.sal%type;
    begin  
        --SQL语句
        --select ename,sal from emp where empno = 7369;
        --PLSQL语句，将ename的值放入pename变量中，sal的值放入psal变量中    
        select ename,sal into pename,psal from emp where empno = 7369;
        --输出
        dbms_output.put_line('7369号员工的姓名是'||pename||',薪水是'||psal);    
    end;
    /

输出7788号员工姓名和工资，格式如下：7788号员工的姓名是SMITH,薪水是3000，语法：使用表名%rowtype

declare
        emp_record emp%rowtype;
    begin
        select * into emp_record from emp where empno = 7788;
        dbms_output.put_line('7788号员工的姓名是'||emp_record.ename||',薪水是'||emp_record.sal);
    end;
    /

何时使用%type，何时使用%rowtype？

*  当定义变量时，**该变量的类型与表中某字段的类型相同时，可以使用%type**
 *  当定义变量时，该变量与整个表结构完全相同时，可以使用%rowtype，此时通过变量名.字段名，可以取值变量中对应的值
 *  项目中，常用%type

--------------------

## **判断体** ##

值得注意的是：**eslif**并没有写错的，它是少了一个e的  
使用if-else-end if显示今天星期几，是"工作日"还是"休息日"

declare
        pday varchar2(10);
    begin
        select to_char(sysdate,'day') into pday from dual;
        dbms_output.put_line('今天是'||pday);
        if pday in ('星期六','星期日') then
        dbms_output.put_line('休息日');
        else
        dbms_output.put_line('工作日');
        end if;
    end;
    /

从键盘接收值，使用if-elsif-else-end if显示"age<16"，"age<30"，"age<60"，"age<80"

declare
        age number(3) := &age;
    begin
        if age < 16 then
           dbms_output.put_line('你未成人');
        elsif age < 30 then
           dbms_output.put_line('你青年人');
        elsif age < 60 then
           dbms_output.put_line('你奋斗人');
        elsif age < 80 then 
           dbms_output.put_line('你享受人');
        else
           dbms_output.put_line('未完再继');
        end if;
    end;
    /

## **循环** ##

在PLSQL中，循环的语法有三种：

**WHILE循环：**

*  while后面跟的是循环条件，与java的差不多，LOOP和END LOOP是关键字\*\*

WHILE  total  <= 25000  
    LOOP
        total : = total + salary;
    END  LOOP;

**LOOP循环：**

*  exit后面的条件成立了才退出循环【有点绕】

Loop
       exit [when 条件成立];
       total:=total+salary;
    end loop;

**FOR循环：**

*  循环的递增只能是1，不能自定义步长

FOR   I   IN   1 . . 3  
    
    LOOP
    
    语句序列 ;
    
    END    LOOP ;

使用loop循环显示1-10

declare
        i number(2) := 1;
    begin
        loop
            --当i>10时，退出循环
            exit when i>10;
            --输出i的值
            dbms_output.put_line(i);
            --变量自加
            i := i + 1;  
        end loop;
    end;
    /

使用while循环显示1-10

declare
        i number(2) := 1;
    begin
        while i<11 
        loop
            dbms_output.put_line(i);
            i := i + 1;
        end loop;
    end;
    /

使用while循环，向emp表中插入999条记录

declare
        i number(4) := 1;
    begin 
        while( i < 1000 )
        loop
            insert into emp(empno,ename) values(i,'哈哈');
            i := i + 1;
        end loop;   
    end;
    /

使用while循环，从emp表中删除999条记录

declare
        i number(4) := 1;
    begin 
        while i<1000
        loop
            delete from emp where empno = i;
            i := i + 1;
        end loop;
    end;
    /

使用for循环显示20-30

declare
        i number(2) := 20;
    begin
        for i in 20 .. 30
        loop
            dbms_output.put_line(i);
        end loop;
    end;
    /

--------------------

**游标**

Oracle中的游标其实就是类似JDBC中的resultSet，**就是一个指针的概念**。

既然是类似与resultSet，那么**游标仅仅是在查询的时候有效的**。

**语法**

CURSOR  光标名  [ (参数名  数据类型[,参数名 数据类型]...)]
          IS  SELECT   语句；

--------------------

使用无参光标cursor，查询所有员工的姓名和工资【如果需要遍历多条记录时，使用光标cursor，无记录找到使用cemp%notfound】

declare
        --定义游标
        cursor cemp is select ename,sal from emp;
        --定义变量
        vename emp.ename%type;
        vsal   emp.sal%type;
    begin
        --打开游标，这时游标位于第一条记录之前
        open cemp;
        --循环
        loop
           --向下移动游标一次
           fetch cemp into vename,vsal; 
           --退出循环,当游标下移一次后，找不到记录时，则退出循环
           exit when cemp%notfound;
           --输出结果
           dbms_output.put_line(vename||'--------'||vsal);
        end loop;
        --关闭游标
        close cemp;
    end;
    /

使用带参光标cursor，查询10号部门的员工姓名和工资

declare
        cursor cemp(pdeptno emp.deptno%type) is select ename,sal from emp where deptno=pdeptno;
        pename emp.ename%type;
        psal emp.sal%type; 
    begin 
        open cemp(&deptno);
        loop
            fetch cemp into pename,psal;     
            exit when cemp%notfound;
            dbms_output.put_line(pename||'的薪水是'||psal);
        end loop;
        close cemp;
    end;
    /

使用无参光标cursor，真正给员工涨工资，ANALYST涨1000，MANAGER涨800，其它涨400，要求显示编号，姓名，职位，薪水

declare
        cursor cemp is select empno,ename,job,sal from emp;
        pempno emp.empno%type;
        pename emp.ename%type;
        pjob   emp.job%type;
        psal   emp.sal%type;
    begin
        open cemp;
        loop
            fetch cemp into pempno,pename,pjob,psal;
            --循环退出条件一定要写
            exit when cemp%notfound;
            if pjob='ANALYST' then
                update emp set sal = sal + 1000 where empno = pempno;
            elsif pjob='MANAGER' then
                update emp set sal = sal + 800 where empno = pempno;
            else 
            update emp set sal = sal + 400 where empno = pempno;
            end if;
        end loop;
        commit;
        close cemp;
    end;
    /

## **例外、异常** ##

我们在上面看PLSQL中的语法已经知道，有一个exception，这个在Oracle中称为例外，我们也可以简单看成就是Java中的异常。。。

**语法：**

在declare节中定义例外   
    out_of   exception ;
    
     在begin节中可行语句中抛出例外  
    raise out_of ；
    
     在exception节处理例外
    when out_of then …

使用oracle系统内置例外，演示除0例外【zero\_divide】

declare
        myresult number;
    begin
        myresult := 1/0;
        dbms_output.put_line(myresult);
    exception
        when zero_divide then 
         dbms_output.put_line('除数不能为0');
         delete from emp;  
    end;
    /

使用oracle系统内置例外，查询100号部门的员工姓名，演示没有找到数据【no\_data\_found】

declare
        pename varchar2(20);
    begin
        select ename into pename from emp where deptno = 100;
        dbms_output.put_line(pename);
    exception
        when NO_DATA_FOUND then 
         dbms_output.put_line('查无该部门员工');
         insert into emp(empno,ename) values(1111,'ERROR');
    end;
    /

作者：Java3y  
链接：http://www.imooc.com/article/25261  
来源：慕课网  
本文原创发布于慕课网 ，转载请注明出处，谢谢合作