09-CMD_编程高级技巧

旧城等待， 2022-01-06 22:34 217阅读 0赞

DOS 编程高级技巧

## 一, 交互界面设计 ##

@echo off
    cls 
    title  终极多功能修复 
    :menu 
    cls 
    color 0A 
    echo. 
    echo                 ============================== 
    echo                  请选择要进行的操作，然后按回车 
    echo                 ============================== 
    echo. 
    echo              1. 网络修复及上网相关设置,修复IE, 自定义屏蔽网站 
    echo. 
    echo              2. 病毒专杀工具，端口关闭工具,关闭自动播放 
    echo. 
    echo              3. 清除所有多余的自启动项目，修复系统错误 
    echo. 
    echo              4. 清理系统垃圾,提高启动速度 
    echo. 
    echo              Q.退出 
    echo. 
    echo. 
    :cho 
    set choice= 
    set /p choice=           请选择 : 
    IF NOT "%choice%"=="" SET choice=%choice:~0,1% 
    if /i "%choice%"=="1" goto ip 
    if /i "%choice%"=="2" goto setsave 
    if /i "%choice%"=="3" goto kaiji 
    if /i "%choice%"=="4" goto clean 
    if /i "%choice%"=="Q" goto endd 
    echo 选择无效，请重新输入 
    echo. 
    goto cho

## 二, IF...ELSE...条件语句 ##

DOS 条件语句主要有以下形式  
IF \[NOT\] ERRORLEVEL number command  
IF \[NOT\] string1==string2 command  
IF \[NOT\] EXIST filename command  
增强用法：  
IF \[/I\] string1 compare-op string2 command  
/I :  
不区分大小写了!  
compare-op:  
EQU - 等于  
NEQ - 不等于  
LSS - 小于  
LEQ - 小于或等于  
GTR - 大于  
GEQ - 大于或等于  
  
上面的command命令都可以用小括号来使用多条命令的组合，包括 else 子句，  
组合命令中可以嵌套使用条件或循环命令。  
例如 :  
IF EXIST filename (  
del filename  
) ELSE (  
echo filename missing  
)  
也可写成：  
if exist filename (del filename) else (echo filename missing)  
但这种写法不适合命令太多或嵌套命令的使用。

## 三, 循环语句 ##

1, 指定循环次数  
格式:  
FOR /L %variable IN (start,step,end) DO command \[command-parameters\]  
组合命令:  
for /L %variable in (start, step, end) do (  
commond1  
commond2  
)  
注意:  
在MS-DOS中, 引用变量-> %variable  
在bat文件中,引用变量-> %%variable  
  
  
2, 对某集合执行循环语句  
格式:  
FOR %%variable IN (set) DO command \[command-parameters\]  
说明:  
%%variable : 单一字母,如%%i  
(set) : 指定 一 个/组 文件.可使用通配符.  
commond : 对每个文件执行的命令.可使用组合命令.  
参数:  
FOR命令不同参数及用法,请参看前面for的详解  
  
  
3, 条件循环  
循环结构,可以用FOR来实现,  
但是,整个循环被当作一条命令语句，涉及到变量延迟的问题.  
而, 用 GOTO 与 条件判断, DOS可以实现条件循环.  
举例:

@echo off
            :: 控制循环次数
            set count=0
            set /p maxTimes=请输入循环次数:
            echo ==============循环执行开始==============
            echo.
            :continue
                :: 增加1
                set /a count+=1
                echo 第 %count% 次循环
                :: 如果 count 小于 20 则继续循环
                if %count% LSS %maxTimes% goto continue
            echo ==============循环执行完毕==============
            echo.
            pause

## 四, 子程序 ##

概念:  
在批处理程序中可以调用外部可运行程序，  
比如 exe 程序， 也可调用其他批处理程序，  
这些也可以看作子程序，但是不够方便，  
如果被调用的程序很多，就显得不够简明了，很繁琐。  
在windowsXP 中，批处理可以调用本程序中的一个程序段，  
相当于子程序，这些子程序一般放在主程序后面。  
格式:  
1, 调用  
CALL :label arguments  
2, 子程序语法  
:label  
command-1  
command-2  
......  
command-n  
goto :eof  
注意:  
(1)在子程序段中, 参数 %0 <=> :label  
(2)子过程一般放在最后  
(3)主程序最后要加上exit或者跳转语句,避免误入子过程  
(4)子程序和主程序中的变量都是全局变量,作用范围都是整个批处理程序  
(5)传至子程序的参数在 call 语句中指定，在子程序中用%1、%2至%9的形式调用  
(6)子程序返回主程序的数据只需在调用结束后直接引用就可以了,当然也可以指定返回变量  
举例:  
(1)通过变量获取子程序返回的值

@echo off
            call :sub return inputValue
            echo 子程序返回值: %return%
            pause
            goto :eof
            :: 子程序
            :sub
                echo 第0个参数 = "%0"
                set %1=%2
            goto :eof

(2)求多个整数相加

@echo off
            set sum=0
            call :sub sum %*
            echo sum = %sum%
            pause
            goto :eof
            :: 子程序
            :sub    
                set /a %1=%1+%2
                :: shift %3 to %2, %4 to %3, etc. and leave %0 and %1 unaffected
                shift /2
                :: 如果移位后的参数没有值,即未指定该参数
                if not "%2"=="" goto sub
            goto :eof        
            d:\cmd\06>4_2.bat 1 1 1 1 1 1 1 1 1 1
            sum = 10

## 五, 用 FTP 命令实现自动下载 ##

ftp 是常用的下载工具，ftp 界面中有 40多个常用命令，自己去学习，不介绍了。  
这里介绍如何用 dos 命令行调用ftp 命令，实现 ftp 自动登录，并上传下载，并自动退出 ftp 程序。  
其实可以将 ftp 命令组合保存为一个文本文件，然后用以下命令调用即可。  
ftp -n -s:\[\[drive:\]path\]filename  
上面的filename 为ftp 命令文件，包括登录 IP 地址，用户名、密码、操作命令等  
例：  
open 90.52.8.3 ＃打开 ip  
user iware ＃用户为 iware  
password8848 ＃密码  
bin ＃二进制传输模式  
prompt  
cd tmp1 ＃切换至 iware 用户下的 tmp1 目录  
pwd  
lcd d:\\download ＃本地目录  
mget \* ＃下载 tmp1 目录下的所有文件  
bye ＃退出 ftp

## 六、用7-ZIP 实现命令行压缩和解压功能 ##

语法格式：（详细情况见 7-zip 帮助文件，看得头晕可以跳过，用到再学）  
7z <command> \[<switch>...\] <base\_archive\_name> \[<arguments>...\]  
7z.exe 的每个命令都有不同的参数<switch>, 请看帮助文件  
<base\_archive\_name>为压缩包名称  
<arguments>为文件名称，支持通配符或文件列表  
其中，7z 是至命令行压缩解压程序 7z.exe ，<command>是7z.exe 包含的命令，列举如下：  
a ： Adds files to archive. 添加至压缩包  
a 命令可用参数：  
\-i (Include)  
\-m (Method)  
\-p (Set Password)  
\-r (Recurse)  
\-sfx (create SFX)  
\-si (use StdIn)  
\-so (use StdOut)  
\-ssw (Compress shared files)  
\-t (Type of archive)  
\-u (Update)  
\-v (Volumes)  
\-w (Working Dir)  
\-x (Exclude)  
b： Benchmark  
d： Deletes files from archive. 从压缩包中删除文件  
d 命令可用参数：  
\-i (Include)  
\-m (Method)  
\-p (Set Password)  
\-r (Recurse)  
\-u (Update)  
\-w (Working Dir)  
\-x (Exclude)  
e ： Extract 解压文件至当前目录或指定目录  
e 命令可用参数：  
\-ai (Include archives)  
\-an (Disable parsing of archive\_name)  
\-ao (Overwrite mode)  
\-ax (Exclude archives)  
\-i (Include)  
\-o (Set Output Directory)  
\-p (Set Password)  
\-r (Recurse)  
\-so (use StdOut)  
\-x (Exclude)  
\-y (Assume Yes on all queries)  
l： Lists contents of archive.  
t： Test  
u： Update  
x： eXtract with full paths 用文件的完整路径解压至当前目录或指定目录  
x 命令可用参数：  
\-ai (Include archives)  
\-an (Disable parsing of archive\_name)  
\-ao (Overwrite mode)  
\-ax (Exclude archives)  
\-i (Include)  
\-o (Set Output Directory)  
\-p (Set Password)  
\-r (Recurse)  
\-so (use StdOut)  
\-x (Exclude)  
\-y (Assume Yes on all queries)

## 七, 调用VBScript程序 ##

使用 Windows 脚本宿主，可以在命令提示符下运行脚本。CScript.exe 提供了用于设置脚本属性的命令行开  
关。  
  
用法：CScript 脚本名称 \[ 脚本选项...\] \[ 脚本参数...\]  
选项：  
//B 批模式：不显示脚本错误及提示信息  
//D 启用 Active Debugging  
//E:engine 使用执行脚本的引擎  
//H:CScript 将默认的脚本宿主改为 CScript.exe  
//H:WScript 将默认的脚本宿主改为 WScript.exe （默认）  
//I 交互模式（默认，与 //B 相对)  
//Job:xxxx 执行一个 WSF 工作  
//Logo 显示徽标（默认）  
//Nologo 不显示徽标：执行时不显示标志  
//S 为该用户保存当前命令行选项  
//T:nn 超时设定秒：允许脚本运行的最长时间  
//X 在调试器中执行脚本  
//U 用 Unicode 表示来自控制台的重定向 I/O  
  
“脚本名称”是带有扩展名和必需的路径信息的脚本文件名称，如 d:\\admin\\vbscripts\\chart.vbs 。  
“脚本选项和参数”将传递给脚本。脚本参数前面有一个斜杠 (/)。每个参数都是可选的；但不能在未指定  
脚本名称的情况下指定脚本选项。如果未指定参数，则 CScript 将显示 CScript 语法和有效的宿主参数。

## 八, 将批处理转化为可执行文件 ##

概述:  
由于批处理文件是一种文本文件，任何人都可以对其进行随便编辑，  
不小心就会把里面的命令破坏掉，所以如果将其转换成.com 格式的可执行文件，  
不仅执行效率会大大提高，而且不会破坏原来的功能，更能将优先级提到最高。  
Bat2Com/Bat2Exe 就可以完成这个转换工作。  
小知识：  
在 DOS 环境下，可执行文件的优先级由高到低依次为.com>.exe>.bat>.cmd ，  
即如果在同一目录下存在文件名相同的这四类文件，  
当只键入文件名时，DOS 执行的是 name.com，  
如果需要执行其他三个文件，则必须指定文件的全名，如 name.bat 。  
Bat2Com:  
这是一个只有 5.43K 大小的免费绿色工具，可以运行在纯 DOS 或DOS 窗口的命令行中，  
用法：Bat2Com FileName  
这样就会在同一目录下生成一个名为 FileNme.com 的可执行文件，  
执行的效果和原来的.bat 文件一样。  
举例:  
1.bat  
@echo off  
echo hello bat2com  
pause  
(1) 将bat2com.exe移到当前目录  
(2) bat2com 1.bat  
(3) 将生成的1.COM 改名 为 1.exe  
(4) 双击1.exe (其实1.COM也可以双击运行)

## 九, 时间延迟 ##

概念:  
执行一条命令后延迟一段时间再进行下一条命令.  
举例:  
(1) 利用 ping 命令延迟

@echo off
            echo 延时前: %time%
            ping /n 3 127.0.0.1 >nul
            echo 延迟后: %time%
            pause

说明:  
ping /n 3 : ping num 次  
>nul : 屏蔽命令的输出  
(2) 利用 for 命令延迟

@echo off
            echo 延迟前: %time%
            for /L %%i in (1, 1, 5000) do echo %%i>nul
            echo 延迟后: %time%
            pause

说明:  
利用一个计次循环并屏蔽它所显示的内容来达到延时的目的  
(3) 利用vbs 延迟函数，精确度毫秒，误差1000 毫秒内

@echo off
            echo 延迟前: %time%
            call :delay 5000
            echo 延迟后: %time%
            pause
            ::exit
            goto :eof
            :: 创建vbs脚本,使用完后删除
            :delay
                echo WScript.Sleep %1>delay.vbs
                CScript //B delay.vbs
                del delay.vbs
            goto :eof

说明:  
1, 创建delay.vbs文件 耗费1000毫秒时间以内  
2, 脚本执行时间 5000 ms  
(4) 仅用批处理命令实现任意时间延迟，精确度10毫秒，误差50毫秒内

@echo off
        set /p delay=please input expected delay time(millisecond):
        set TotalTime=0
        set NowTime=%time%
    
        echo start time : %NowTime%
    
        call :delay_continue
    
        echo end   time : %time%
    
        pause
        goto :eof
    
        :delay_continue
        :: echo NowTime = %NowTime%
        ::  读取起始时间的分钟数
        ::  如果 分钟为 02, 则 102-100 = 2分钟
        set /a minute1=1%NowTime:~3,2%-100
        :: echo minute1 = %minute1%
    
        ::  将起始时间的秒数转为毫秒 
        ::set /a second1=1%NowTime:~-5,2%-100
        ::echo second1 = [%second1%]
        ::set /a millisecond1=1%NowTime:~-2%0-1000
        ::echo millisecond1 = [%millisecond1%]
        set /a millisecond1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
        :: echo millisecond1 = %millisecond1%
    
        set NowTime=%time%
        ::  读取现在时间的分钟数 
        set /a minute2=1%NowTime:~3,2%-100 
        ::echo minute2 = %minute2%
        ::  将现在时间的秒数转为毫秒 
        set /a millisecond2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
        ::echo millisecond2 = %millisecond2%
    
        :: 每循环一次, 计算耗费的时间
        set /a ConsumedTime=(%minute2%-%minute1%+60)%%60*60000+%millisecond2%-%millisecond1%
    
        :: 累加 程序运行耗费的时间
        set /a TotalTime+=%ConsumedTime%
        ::echo TotalTime = %TotalTime%
    
        :: 如果程序运行的总时间 小于 期望的延迟时间, 则继续运行程序.
        if %TotalTime% lss %delay% goto delay_continue
    
        goto :eof

## 十, 模拟进度条 ##

@echo off 
        ::mode con cols=113 lines=15 &color 9f 
        ::cls 
        echo. 
        echo  application is initing. . .  
        echo. 
        echo  ┌──────────────────────────────────────┐ 
        set/p=  ■<nul 
        for /L %%i in (1 1 38) do set /p a= ■<nul&ping /n 1 127.0.0.1>nul 
        echo   100%% 
        echo  └──────────────────────────────────────┘ 
        pause

:: set /p a= ■<nul , 只显示提示信息"■", 且不换行, 也不需要输入  
:: 因此可以使 "■" 在同一行 逐个输出.  
:: ping /n 1 127.0.0.1>nul 消耗的时间, 是输出每个"■"的时间间隔.

## 十一, 特殊字符的输入及应用 ##

## 十二, 随机数(%random%)的应用技巧 ##

概念:  
%RANDOM% 系统变量 返回 0 到 32767 之间的任意十进制数字。  
由 Cmd.exe 生成。  
2 的15次方等于 32768 ，上面的0～32767 实际就是 15位二进制数的范围。  
获取 100 以内的随机数呢，将%RANDOM%按100 进行求余运算即可  
举例:  
(1) 生成5个100以内的随机数

d:\cmd\06>type 12.bat
        @echo off
        setLocal enableDelayedExpansion
        for /L %%i in (1, 1, 5) do (
            set /a randomNum=!random!%%100
            echo random number%%i: !randomNum!
        )
        pause
        d:\cmd\06>12.bat
        random number1: 8
        random number2: 3
        random number3: 62
        random number4: 99
        random number5: 9

(2) 生成给定位数的随机密码  
思路:1, 将 26个英文字母或 10数字以及其它特殊字符组成一个字符串  
2, 随机抽取其中的若干字符。  
A) 简单的实现

@echo off 
        call :randomPassword 5 pass1 pass2 
        echo %pass1% %pass2%  
    
        pause 
        ::exit 
    
        :randomPassword 
        ::--------- 生成随机密码 
        ::---------%1 为密码长度，%2及以后为返回变量名称 
        ::---------for 命令最多只能区分 31个字段 
            @echo off 
            set password_len=%1 
            if not defined password_len goto :eof 
            if %password_len% lss 1 goto :eof 
            set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z 
            set return=
            set num=0
            :randomPassword1
                set /a num+=1
                set /a numof=%random%%%26+1
                for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
                if %num% lss %password_len% goto randomPassword1
            if not "%2"=="" set %2=%return%
            shift /2
            if not "%2"=="" goto randomPassword
        goto :eof
        B) 优化
        @echo off
        call :randomPassword 6 pass1 pass2 pass3
        echo %pass1% %pass2% %pass3%
        pause 
        ::exit 
        :randomPassword
        ::--------- 生成随机密码 
        ::---------%1 为密码长度，%2及以后为返回变量名称 
        ::---------goto 循环、变量嵌套、命令嵌套 
            @echo off 
            if "%1"=="" goto :eof
            if %1 lss 1 goto :eof 
            set password_len=%1 
            set return=
            set wordset=abcdefghijklmnopqrstuvwxyz023456789_
            ::--------------------------- 循环  
            :randomPassword1 
                set /a numof=%random%%%36
                :: call, 以命令嵌套 实现 变量嵌套
                call set return=%return%%%wordset:~%numof%,1%%
                set /a password_len-=1
                if %password_len% gtr 0 goto randomPassword1
            ::--------------------------- 循环  
            if not "%2"=="" set %2=%return%
            shift /2
            if not "%2"=="" goto randomPassword
        goto :eof

## 十三, 变量嵌套 与 命令嵌套 ##

和其它编程语言相比，dos 功能显得相对简单，  
要实现比较复杂的功能，需要充分运用各种技巧，变量嵌套与命令嵌套就是此类技巧之一。  
  
  
先复习一下前面的“字符串截取”的关键内容：  
\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
截取功能统一语法格式为：%a:~\[m\[,n\]\]%  
\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
方括号 表示可选，  
% 为变量标识符，  
a 为变量名，不可少，  
冒号 用于分隔变量名和说明部分，  
符号～ 可以简单理解为“偏移”即可，  
m 为偏移量（缺省为 0），  
n 为截取长度（缺省为全部）。  
百分号如果需要当成单一字符，必须写成%%  
以上是dos 变量处理的通用格式，如果其中的 m 、n 为变量，那么这种情况就是变量嵌套了。  
比如  
设变量 word为“abcdefghij”，变量 num 为“123456789 ”  
e = %word:~4,1%  
4 = %num:~3,1%，  
写成组合形式如下：  
%word:~%num:~3,1%,1% // error  
%word:~(%num:~3,1%),1% // error  
那么，怎么实现这种变量嵌套呢？这就必须结合命令嵌套。  
什么是命令嵌套呢？  
简单的说，首先用一条 DOS 命令生成一个字符串，而这个字符串是另一条 DOS 命令，  
用call 语句调用字符串将其执行，从而得到最终结果。  
例：用call 语句实现命令嵌套,将字符串的一部分当做命令来执行

@echo off 
        set str=0123echo commondString 
        echo src string: %str% 
        echo get the string commond: %str:~4% 
        echo run the substring commond 
        call %str:~4% 
        pause